CMakeLists.txt 29 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880
  1. cmake_minimum_required(VERSION 2.8.0)
  2. project(harfbuzz)
  3. enable_testing()
  4. ## Limit framework build to Xcode generator
  5. if (BUILD_FRAMEWORK)
  6. # for a framework build on macOS, use:
  7. # cmake -DBUILD_FRAMEWORK=ON -Bbuild -H. -GXcode && cmake --build build
  8. if (NOT "${CMAKE_GENERATOR}" STREQUAL "Xcode")
  9. message(FATAL_ERROR
  10. "You should use Xcode generator with BUILD_FRAMEWORK enabled")
  11. endif ()
  12. set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_64_BIT)")
  13. set (CMAKE_MACOSX_RPATH ON)
  14. set (BUILD_SHARED_LIBS ON)
  15. endif ()
  16. ## Disallow in-source builds, as CMake generated make files can collide with autotools ones
  17. if (NOT MSVC AND "${PROJECT_BINARY_DIR}" STREQUAL "${PROJECT_SOURCE_DIR}")
  18. message(FATAL_ERROR
  19. "
  20. In-source builds are not permitted! Make a separate folder for"
  21. " building, e.g.,"
  22. "
  23. mkdir build; cd build; cmake .."
  24. "
  25. Before that, remove the files created by this failed run with"
  26. "
  27. rm -rf CMakeCache.txt CMakeFiles")
  28. endif ()
  29. ## HarfBuzz build configurations
  30. option(HB_HAVE_FREETYPE "Enable freetype interop helpers" OFF)
  31. option(HB_HAVE_GRAPHITE2 "Enable Graphite2 complementary shaper" OFF)
  32. option(HB_HAVE_GLIB "Enable glib unicode functions" OFF)
  33. option(HB_HAVE_ICU "Enable icu unicode functions" OFF)
  34. if (APPLE)
  35. option(HB_HAVE_CORETEXT "Enable CoreText shaper backend on macOS" ON)
  36. set (CMAKE_MACOSX_RPATH ON)
  37. endif ()
  38. if (WIN32)
  39. option(HB_HAVE_UNISCRIBE "Enable Uniscribe shaper backend on Windows" OFF)
  40. option(HB_HAVE_DIRECTWRITE "Enable DirectWrite shaper backend on Windows" OFF)
  41. endif ()
  42. option(HB_BUILD_UTILS "Build harfbuzz utils, needs cairo, freetype, and glib properly be installed" OFF)
  43. if (HB_BUILD_UTILS)
  44. set (HB_HAVE_GLIB ON)
  45. set (HB_HAVE_FREETYPE ON)
  46. endif ()
  47. option(HB_BUILD_SUBSET "Build harfbuzz-subset" ON)
  48. option(HB_BUILD_TESTS "Build harfbuzz tests" ON)
  49. option(HB_HAVE_GOBJECT "Enable GObject Bindings" OFF)
  50. if (HB_HAVE_GOBJECT)
  51. set (HB_HAVE_GLIB ON)
  52. endif ()
  53. option(HB_HAVE_INTROSPECTION "Enable building introspection (.gir/.typelib) files" OFF)
  54. if (HB_HAVE_INTROSPECTION)
  55. set (HB_HAVE_GOBJECT ON)
  56. set (HB_HAVE_GLIB ON)
  57. endif ()
  58. option(HB_CHECK OFF "Do a configuration suitable for testing (shared library and enable all options)")
  59. if (HB_CHECK)
  60. set (BUILD_SHARED_LIBS ON)
  61. set (HB_BUILD_UTILS ON)
  62. set (HB_HAVE_ICU)
  63. set (HB_HAVE_GLIB ON)
  64. #set (HB_HAVE_GOBJECT ON)
  65. #set (HB_HAVE_INTROSPECTION ON)
  66. set (HB_HAVE_FREETYPE ON)
  67. set (HB_HAVE_GRAPHITE2 ON)
  68. if (WIN32)
  69. set (HB_HAVE_UNISCRIBE ON)
  70. set (HB_HAVE_DIRECTWRITE ON)
  71. elseif (APPLE)
  72. set (HB_HAVE_CORETEXT ON)
  73. endif ()
  74. endif ()
  75. include_directories(AFTER
  76. ${PROJECT_SOURCE_DIR}/src
  77. ${PROJECT_BINARY_DIR}/src
  78. )
  79. add_definitions(-DHAVE_FALLBACK)
  80. # We need PYTHON_EXECUTABLE to be set for running the tests...
  81. include (FindPythonInterp)
  82. ## Functions and headers
  83. include (CheckFunctionExists)
  84. include (CheckIncludeFile)
  85. macro (check_funcs) # Similar to AC_CHECK_FUNCS of autotools
  86. foreach (func_name ${ARGN})
  87. string(TOUPPER ${func_name} definition_to_add)
  88. check_function_exists(${func_name} HAVE_${definition_to_add})
  89. if (${HAVE_${definition_to_add}})
  90. add_definitions(-DHAVE_${definition_to_add})
  91. endif ()
  92. endforeach ()
  93. endmacro ()
  94. if (UNIX)
  95. list(APPEND CMAKE_REQUIRED_LIBRARIES m)
  96. endif ()
  97. check_funcs(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l round)
  98. check_include_file(unistd.h HAVE_UNISTD_H)
  99. if (${HAVE_UNISTD_H})
  100. add_definitions(-DHAVE_UNISTD_H)
  101. endif ()
  102. check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  103. if (${HAVE_SYS_MMAN_H})
  104. add_definitions(-DHAVE_SYS_MMAN_H)
  105. endif ()
  106. check_include_file(xlocale.h HAVE_XLOCALE_H)
  107. if (${HAVE_XLOCALE_H})
  108. add_definitions(-DHAVE_XLOCALE_H)
  109. endif ()
  110. check_include_file(stdbool.h HAVE_STDBOOL_H)
  111. if (${HAVE_STDBOOL_H})
  112. add_definitions(-DHAVE_STDBOOL_H)
  113. endif ()
  114. if (MSVC)
  115. add_definitions(-wd4244 -wd4267 -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  116. endif ()
  117. ## Detect if we are running inside a distribution or regular repository folder
  118. # if (EXISTS "${PROJECT_SOURCE_DIR}/ChangeLog")
  119. # # perhaps we are on dist directory
  120. # set (IN_HB_DIST TRUE)
  121. # #set (HB_VERSION_H "${PROJECT_SOURCE_DIR}/src/hb-version.h")
  122. # endif ()
  123. ## Extract variables from Makefile files
  124. function (extract_make_variable variable makefile_source)
  125. string(REGEX MATCH "${variable} = ([^$]+)\\$" temp ${makefile_source})
  126. string(REGEX MATCHALL "[^ \n\t\\]+" listVar ${CMAKE_MATCH_1})
  127. set (${variable} ${listVar} PARENT_SCOPE)
  128. endfunction ()
  129. # http://stackoverflow.com/a/27630120
  130. function (add_prefix_to_list var prefix)
  131. set (listVar "")
  132. foreach (f ${${var}})
  133. list(APPEND listVar "${prefix}${f}")
  134. endforeach ()
  135. set (${var} "${listVar}" PARENT_SCOPE)
  136. endfunction ()
  137. file(READ ${PROJECT_SOURCE_DIR}/src/Makefile.sources SRCSOURCES)
  138. file(READ ${PROJECT_SOURCE_DIR}/util/Makefile.sources UTILSOURCES)
  139. extract_make_variable(HB_BASE_sources ${SRCSOURCES})
  140. add_prefix_to_list(HB_BASE_sources "${PROJECT_SOURCE_DIR}/src/")
  141. extract_make_variable(HB_BASE_headers ${SRCSOURCES})
  142. add_prefix_to_list(HB_BASE_headers "${PROJECT_SOURCE_DIR}/src/")
  143. extract_make_variable(HB_FALLBACK_sources ${SRCSOURCES})
  144. add_prefix_to_list(HB_FALLBACK_sources "${PROJECT_SOURCE_DIR}/src/")
  145. extract_make_variable(HB_SUBSET_sources ${SRCSOURCES})
  146. add_prefix_to_list(HB_SUBSET_sources "${PROJECT_SOURCE_DIR}/src/")
  147. extract_make_variable(HB_SUBSET_headers ${SRCSOURCES})
  148. add_prefix_to_list(HB_SUBSET_headers "${PROJECT_SOURCE_DIR}/src/")
  149. extract_make_variable(HB_BASE_RAGEL_GENERATED_sources ${SRCSOURCES})
  150. #if (IN_HB_DIST)
  151. add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
  152. #else ()
  153. # add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
  154. #endif ()
  155. extract_make_variable(HB_VIEW_sources ${UTILSOURCES})
  156. add_prefix_to_list(HB_VIEW_sources "${PROJECT_SOURCE_DIR}/util/")
  157. extract_make_variable(HB_SHAPE_sources ${UTILSOURCES})
  158. add_prefix_to_list(HB_SHAPE_sources "${PROJECT_SOURCE_DIR}/util/")
  159. extract_make_variable(HB_SUBSET_CLI_sources ${UTILSOURCES})
  160. add_prefix_to_list(HB_SUBSET_CLI_sources "${PROJECT_SOURCE_DIR}/util/")
  161. extract_make_variable(HB_OT_SHAPE_CLOSURE_sources ${UTILSOURCES})
  162. add_prefix_to_list(HB_OT_SHAPE_CLOSURE_sources "${PROJECT_SOURCE_DIR}/util/")
  163. file(READ configure.ac CONFIGUREAC)
  164. string(REGEX MATCH "\\[(([0-9]+)\\.([0-9]+)\\.([0-9]+))\\]" HB_VERSION_MATCH ${CONFIGUREAC})
  165. set (HB_VERSION ${CMAKE_MATCH_1})
  166. set (HB_VERSION_MAJOR ${CMAKE_MATCH_2})
  167. set (HB_VERSION_MINOR ${CMAKE_MATCH_3})
  168. set (HB_VERSION_MICRO ${CMAKE_MATCH_4})
  169. ## Define ragel tasks
  170. # if (NOT IN_HB_DIST)
  171. # foreach (ragel_output IN ITEMS ${HB_BASE_RAGEL_GENERATED_sources})
  172. # string(REGEX MATCH "([^/]+)\\.hh" temp ${ragel_output})
  173. # set (target_name ${CMAKE_MATCH_1})
  174. # add_custom_command(OUTPUT ${ragel_output}
  175. # COMMAND ${RAGEL} -G2 -o ${ragel_output} ${PROJECT_SOURCE_DIR}/src/${target_name}.rl -I ${PROJECT_SOURCE_DIR} ${ARGN}
  176. # DEPENDS ${PROJECT_SOURCE_DIR}/src/${target_name}.rl
  177. # )
  178. # add_custom_target(harfbuzz_${target_name} DEPENDS ${PROJECT_BINARY_DIR}/src/${target_name})
  179. # endforeach ()
  180. # mark_as_advanced(RAGEL)
  181. # endif ()
  182. ## Generate hb-version.h
  183. # if (NOT IN_HB_DIST)
  184. # set (HB_VERSION_H_IN "${PROJECT_SOURCE_DIR}/src/hb-version.h.in")
  185. # set (HB_VERSION_H "${PROJECT_BINARY_DIR}/src/hb-version.h")
  186. # set_source_files_properties("${HB_VERSION_H}" PROPERTIES GENERATED true)
  187. # configure_file("${HB_VERSION_H_IN}" "${HB_VERSION_H}.tmp" @ONLY)
  188. # execute_process(COMMAND "${CMAKE_COMMAND}" -E copy_if_different
  189. # "${HB_VERSION_H}.tmp"
  190. # "${HB_VERSION_H}"
  191. # )
  192. # file(REMOVE "${HB_VERSION_H}.tmp")
  193. # endif ()
  194. ## Define sources and headers of the project
  195. set (project_sources
  196. ${HB_BASE_sources}
  197. ${HB_BASE_RAGEL_GENERATED_sources}
  198. ${HB_FALLBACK_sources}
  199. )
  200. set (subset_project_sources
  201. ${HB_SUBSET_sources}
  202. )
  203. set (project_extra_sources)
  204. set (project_headers
  205. #${HB_VERSION_H}
  206. ${HB_BASE_headers}
  207. )
  208. set (subset_project_headers
  209. ${HB_SUBSET_headers}
  210. )
  211. ## Find and include needed header folders and libraries
  212. if (HB_HAVE_FREETYPE)
  213. include (FindFreetype)
  214. if (NOT FREETYPE_FOUND)
  215. message(FATAL_ERROR "HB_HAVE_FREETYPE was set, but we failed to find it. Maybe add a CMAKE_PREFIX_PATH= to your Freetype2 install prefix")
  216. endif ()
  217. list(APPEND THIRD_PARTY_LIBS ${FREETYPE_LIBRARIES})
  218. include_directories(AFTER ${FREETYPE_INCLUDE_DIRS})
  219. add_definitions(-DHAVE_FREETYPE=1)
  220. list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-ft.cc)
  221. list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-ft.h)
  222. # So check_funcs can find its headers
  223. set (CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${FREETYPE_INCLUDE_DIRS})
  224. set (CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${FREETYPE_LIBRARIES})
  225. check_funcs(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
  226. endif ()
  227. if (HB_HAVE_GRAPHITE2)
  228. add_definitions(-DHAVE_GRAPHITE2)
  229. find_path(GRAPHITE2_INCLUDE_DIR graphite2/Font.h)
  230. find_library(GRAPHITE2_LIBRARY graphite2)
  231. include_directories(${GRAPHITE2_INCLUDE_DIR})
  232. list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-graphite2.cc)
  233. list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-graphite2.h)
  234. list(APPEND THIRD_PARTY_LIBS ${GRAPHITE2_LIBRARY})
  235. mark_as_advanced(GRAPHITE2_INCLUDE_DIR GRAPHITE2_LIBRARY)
  236. endif ()
  237. if (HB_HAVE_GLIB)
  238. add_definitions(-DHAVE_GLIB)
  239. # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindGLIB.cmake
  240. find_package(PkgConfig)
  241. pkg_check_modules(PC_GLIB QUIET glib-2.0)
  242. find_library(GLIB_LIBRARIES NAMES glib-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
  243. find_path(GLIBCONFIG_INCLUDE_DIR NAMES glibconfig.h HINTS ${PC_LIBDIR} ${PC_LIBRARY_DIRS} ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0/include)
  244. find_path(GLIB_INCLUDE_DIR NAMES glib.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
  245. include_directories(${GLIBCONFIG_INCLUDE_DIR} ${GLIB_INCLUDE_DIR})
  246. list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-glib.cc)
  247. list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-glib.h)
  248. list(APPEND THIRD_PARTY_LIBS ${GLIB_LIBRARIES})
  249. mark_as_advanced(GLIB_LIBRARIES GLIBCONFIG_INCLUDE_DIR GLIB_INCLUDE_DIR)
  250. endif ()
  251. if (HB_HAVE_ICU)
  252. add_definitions(-DHAVE_ICU)
  253. # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindICU.cmake
  254. find_package(PkgConfig)
  255. pkg_check_modules(PC_ICU QUIET icu-uc)
  256. find_path(ICU_INCLUDE_DIR NAMES unicode/utypes.h HINTS ${PC_ICU_INCLUDE_DIRS} ${PC_ICU_INCLUDEDIR})
  257. find_library(ICU_LIBRARY NAMES libicuuc cygicuuc cygicuuc32 icuuc HINTS ${PC_ICU_LIBRARY_DIRS} ${PC_ICU_LIBDIR})
  258. include_directories(${ICU_INCLUDE_DIR})
  259. list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-icu.cc)
  260. list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
  261. list(APPEND THIRD_PARTY_LIBS ${ICU_LIBRARY})
  262. mark_as_advanced(ICU_INCLUDE_DIR ICU_LIBRARY)
  263. endif ()
  264. if (APPLE AND HB_HAVE_CORETEXT)
  265. # Apple Advanced Typography
  266. add_definitions(-DHAVE_CORETEXT)
  267. list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-coretext.cc)
  268. list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-coretext.h)
  269. if (HB_IOS)
  270. find_library(COREFOUNDATION CoreFoundation)
  271. if (COREFOUNDATION)
  272. list(APPEND THIRD_PARTY_LIBS ${COREFOUNDATION})
  273. endif ()
  274. mark_as_advanced(COREFOUNDATION)
  275. find_library(CORETEXT CoreText)
  276. if (CORETEXT)
  277. list(APPEND THIRD_PARTY_LIBS ${CORETEXT})
  278. endif ()
  279. mark_as_advanced(CORETEXT)
  280. find_library(COREGRAPHICS CoreGraphics)
  281. if (COREGRAPHICS)
  282. list(APPEND THIRD_PARTY_LIBS ${COREGRAPHICS})
  283. endif ()
  284. mark_as_advanced(COREGRAPHICS)
  285. else ()
  286. find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices)
  287. if (APPLICATION_SERVICES_FRAMEWORK)
  288. list(APPEND THIRD_PARTY_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
  289. endif ()
  290. mark_as_advanced(APPLICATION_SERVICES_FRAMEWORK)
  291. endif ()
  292. endif ()
  293. if (WIN32 AND HB_HAVE_UNISCRIBE)
  294. add_definitions(-DHAVE_UNISCRIBE)
  295. list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.cc)
  296. list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.h)
  297. list(APPEND THIRD_PARTY_LIBS usp10 gdi32 rpcrt4)
  298. endif ()
  299. if (WIN32 AND HB_HAVE_DIRECTWRITE)
  300. add_definitions(-DHAVE_DIRECTWRITE)
  301. list(APPEND project_sources ${PROJECT_SOURCE_DIR}/src/hb-directwrite.cc)
  302. list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-directwrite.h)
  303. list(APPEND THIRD_PARTY_LIBS dwrite rpcrt4)
  304. endif ()
  305. if (HB_HAVE_GOBJECT)
  306. include (FindPerl)
  307. # Use the hints from glib-2.0.pc to find glib-mkenums
  308. find_package(PkgConfig)
  309. pkg_check_modules(PC_GLIB QUIET glib-2.0)
  310. find_program(GLIB_MKENUMS glib-mkenums
  311. HINTS ${PC_glib_mkenums}
  312. )
  313. set (GLIB_MKENUMS_CMD)
  314. if (WIN32 AND NOT MINGW)
  315. # In Visual Studio builds, shebang lines are not supported
  316. # in the standard cmd.exe shell that we use, so we need to
  317. # first determine whether glib-mkenums is a Python or PERL
  318. # script
  319. execute_process(COMMAND "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}" --version
  320. RESULT_VARIABLE GLIB_MKENUMS_PYTHON
  321. OUTPUT_QUIET ERROR_QUIET
  322. )
  323. if (GLIB_MKENUMS_PYTHON EQUAL 0)
  324. message("${GLIB_MKENUMS} is a Python script.")
  325. set (GLIB_MKENUMS_CMD "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}")
  326. else ()
  327. execute_process(COMMAND "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}" --version
  328. RESULT_VARIABLE GLIB_MKENUMS_PERL
  329. OUTPUT_QUIET ERROR_QUIET
  330. )
  331. if (GLIB_MKENUMS_PERL EQUAL 0)
  332. message("${GLIB_MKENUMS} is a PERL script.")
  333. set (GLIB_MKENUMS_CMD "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}")
  334. endif ()
  335. if (NOT GLIB_MKENUMS_PERL EQUAL 0 AND NOT GLIB_MKENUMS_PYTHON EQUAL 0)
  336. message(FATAL_ERROR "Unable to determine type of glib-mkenums script")
  337. endif ()
  338. endif ()
  339. else ()
  340. set (GLIB_MKENUMS_CMD "${GLIB_MKENUMS}")
  341. endif ()
  342. if (NOT GLIB_MKENUMS_CMD)
  343. message(FATAL_ERROR "HB_HAVE_GOBJECT was set, but we failed to find glib-mkenums, which is required")
  344. endif ()
  345. pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
  346. find_library(GOBJECT_LIBRARIES NAMES gobject-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
  347. find_path(GOBJECT_INCLUDE_DIR NAMES glib-object.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
  348. include_directories(${GOBJECTCONFIG_INCLUDE_DIR} ${GOBJECT_INCLUDE_DIR})
  349. mark_as_advanced(GOBJECT_LIBRARIES GOBJECT_INCLUDE_DIR)
  350. list(APPEND hb_gobject_sources ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.cc)
  351. list(APPEND hb_gobject_gen_sources
  352. ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
  353. )
  354. list(APPEND hb_gobject_structs_headers
  355. ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.h
  356. )
  357. list(APPEND hb_gobject_headers
  358. ${PROJECT_SOURCE_DIR}/src/hb-gobject.h
  359. ${hb_gobject_structs_headers}
  360. )
  361. list(APPEND hb_gobject_gen_headers
  362. ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
  363. )
  364. add_custom_command(
  365. OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
  366. COMMAND ${GLIB_MKENUMS_CMD}
  367. --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
  368. --identifier-prefix hb_
  369. --symbol-prefix hb_gobject
  370. ${hb_gobject_structs_headers}
  371. ${project_headers}
  372. > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp
  373. COMMAND "${CMAKE_COMMAND}"
  374. "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp"
  375. "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h"
  376. -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
  377. DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
  378. ${hb_gobject_header}
  379. ${project_headers}
  380. )
  381. add_custom_command(
  382. OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
  383. COMMAND ${GLIB_MKENUMS_CMD}
  384. --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
  385. --identifier-prefix hb_
  386. --symbol-prefix hb_gobject
  387. ${hb_gobject_header}
  388. ${project_headers}
  389. > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp
  390. COMMAND "${CMAKE_COMMAND}"
  391. "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp"
  392. "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc"
  393. -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
  394. DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
  395. ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
  396. ${hb_gobject_header}
  397. ${project_headers}
  398. )
  399. endif ()
  400. ## Atomic ops availability detection
  401. file(WRITE "${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c"
  402. " void memory_barrier (void) { __sync_synchronize (); }
  403. int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
  404. int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
  405. void mutex_unlock (int *m) { __sync_lock_release (m); }
  406. int main () { return 0; }
  407. ")
  408. try_compile(HB_HAVE_INTEL_ATOMIC_PRIMITIVES
  409. ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives
  410. ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c)
  411. if (HB_HAVE_INTEL_ATOMIC_PRIMITIVES)
  412. add_definitions(-DHAVE_INTEL_ATOMIC_PRIMITIVES)
  413. endif ()
  414. file(WRITE "${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c"
  415. " #include <atomic.h>
  416. /* This requires Solaris Studio 12.2 or newer: */
  417. #include <mbarrier.h>
  418. void memory_barrier (void) { __machine_rw_barrier (); }
  419. int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
  420. void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
  421. int main () { return 0; }
  422. ")
  423. try_compile(HB_HAVE_SOLARIS_ATOMIC_OPS
  424. ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops
  425. ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c)
  426. if (HB_HAVE_SOLARIS_ATOMIC_OPS)
  427. add_definitions(-DHAVE_SOLARIS_ATOMIC_OPS)
  428. endif ()
  429. ## Define harfbuzz library
  430. add_library(harfbuzz ${project_sources} ${project_extra_sources} ${project_headers})
  431. target_link_libraries(harfbuzz ${THIRD_PARTY_LIBS})
  432. ## Define harfbuzz-subset library
  433. if (HB_BUILD_SUBSET)
  434. add_library(harfbuzz-subset ${subset_project_sources} ${subset_project_headers})
  435. add_dependencies(harfbuzz-subset harfbuzz)
  436. target_link_libraries(harfbuzz-subset harfbuzz ${THIRD_PARTY_LIBS})
  437. if (BUILD_SHARED_LIBS)
  438. set_target_properties(harfbuzz harfbuzz-subset PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
  439. endif ()
  440. endif ()
  441. if (UNIX OR MINGW)
  442. # Make symbols link locally
  443. include (CheckCXXCompilerFlag)
  444. CHECK_CXX_COMPILER_FLAG(-Bsymbolic-functions CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
  445. if (CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
  446. link_libraries(-Bsymbolic-functions)
  447. endif ()
  448. if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  449. # Make sure we don't link to libstdc++
  450. set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti -fno-exceptions")
  451. set (CMAKE_CXX_IMPLICIT_LINK_LIBRARIES "m") # libm
  452. set (CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "")
  453. set_target_properties(harfbuzz PROPERTIES LINKER_LANGUAGE C)
  454. if (HB_BUILD_SUBSET)
  455. set_target_properties(harfbuzz-subset PROPERTIES LINKER_LANGUAGE C)
  456. endif ()
  457. # No threadsafe statics as we do it ourselves
  458. set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
  459. endif ()
  460. CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
  461. if (COMPILER_SUPPORTS_CXX11)
  462. set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
  463. else()
  464. message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
  465. endif()
  466. endif ()
  467. ## Define harfbuzz-gobject library
  468. if (HB_HAVE_GOBJECT)
  469. add_library(harfbuzz-gobject
  470. ${hb_gobject_sources}
  471. ${hb_gobject_gen_sources}
  472. ${hb_gobject_headers}
  473. ${hb_gobject_gen_headers}
  474. )
  475. include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}/src)
  476. add_dependencies(harfbuzz-gobject harfbuzz)
  477. target_link_libraries(harfbuzz-gobject harfbuzz ${GOBJECT_LIBRARIES} ${THIRD_PARTY_LIBS})
  478. if (BUILD_SHARED_LIBS)
  479. set_target_properties(harfbuzz-gobject PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
  480. endif ()
  481. endif ()
  482. if (BUILD_SHARED_LIBS AND WIN32 AND NOT MINGW)
  483. add_definitions("-DHB_DLL_EXPORT")
  484. endif ()
  485. # On Windows, g-ir-scanner requires a DLL build in order for it to work
  486. if (WIN32)
  487. if (NOT BUILD_SHARED_LIBS)
  488. message("Building introspection files on Windows requires BUILD_SHARED_LIBS to be enabled.")
  489. set (HB_HAVE_INTROSPECTION OFF)
  490. endif ()
  491. endif ()
  492. if (HB_HAVE_INTROSPECTION)
  493. find_package(PkgConfig)
  494. pkg_check_modules(PC_GI QUIET gobject-introspection-1.0)
  495. find_program(G_IR_SCANNER g-ir-scanner
  496. HINTS ${PC_g_ir_scanner}
  497. )
  498. find_program(G_IR_COMPILER g-ir-compiler
  499. HINTS ${PC_g_ir_compiler}
  500. )
  501. if (WIN32 AND NOT MINGW)
  502. # Note that since we already enable HB_HAVE_GOBJECT
  503. # we would already have PYTHON_EXECUTABLE handy
  504. set (G_IR_SCANNER_CMD "${PYTHON_EXECUTABLE}" "${G_IR_SCANNER}")
  505. else ()
  506. set (G_IR_SCANNER_CMD "${G_IR_SCANNER}")
  507. endif ()
  508. # We need to account for the varying output directories
  509. # when we build using Visual Studio projects
  510. if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
  511. set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
  512. else ()
  513. set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
  514. endif ()
  515. # Get the CFlags that we used to build HarfBuzz/HarfBuzz-GObject
  516. set (hb_defines_cflags "")
  517. foreach (hb_cflag ${hb_cflags})
  518. list(APPEND hb_defines_cflags "-D${hb_cflag}")
  519. endforeach (hb_cflag)
  520. # Get the other dependent libraries we used to build HarfBuzz/HarfBuzz-GObject
  521. set (extra_libs "")
  522. foreach (extra_lib ${THIRD_PARTY_LIBS})
  523. # We don't want the .lib extension here...
  524. string(REPLACE ".lib" "" extra_lib_stripped "${extra_lib}")
  525. list(APPEND extra_libs "--extra-library=${extra_lib_stripped}")
  526. endforeach ()
  527. set (introspected_sources)
  528. foreach (f
  529. ${project_headers}
  530. ${project_sources}
  531. ${hb_gobject_gen_sources}
  532. ${hb_gobject_gen_headers}
  533. ${hb_gobject_sources}
  534. ${hb_gobject_headers}
  535. )
  536. if (WIN32)
  537. # Nasty issue: We need to make drive letters lower case,
  538. # otherwise g-ir-scanner won't like it and give us a bunch
  539. # of invalid items and unresolved types...
  540. STRING(SUBSTRING "${f}" 0 1 drive)
  541. STRING(SUBSTRING "${f}" 1 -1 path)
  542. if (drive MATCHES "[A-Z]")
  543. STRING(TOLOWER ${drive} drive_lower)
  544. list(APPEND introspected_sources "${drive_lower}${path}")
  545. else ()
  546. list(APPEND introspected_sources "${f}")
  547. endif ()
  548. else ()
  549. list(APPEND introspected_sources "${f}")
  550. endif ()
  551. endforeach ()
  552. file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list)
  553. foreach (s ${introspected_sources})
  554. file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list "${s}\n")
  555. endforeach ()
  556. # Finally, build the introspection files...
  557. add_custom_command(
  558. TARGET harfbuzz-gobject
  559. POST_BUILD
  560. COMMAND ${G_IR_SCANNER_CMD}
  561. --warn-all --no-libtool --verbose
  562. -n hb
  563. --namespace=HarfBuzz
  564. --nsversion=0.0
  565. --identifier-prefix=hb_
  566. --include GObject-2.0
  567. --pkg-export=harfbuzz
  568. --cflags-begin
  569. -I${PROJECT_SOURCE_DIR}/src
  570. -I${PROJECT_BINARY_DIR}/src
  571. ${hb_includedir_cflags}
  572. ${hb_defines_cflags}
  573. -DHB_H
  574. -DHB_H_IN
  575. -DHB_OT_H
  576. -DHB_OT_H_IN
  577. -DHB_AAT_H
  578. -DHB_AAT_H_IN
  579. -DHB_GOBJECT_H
  580. -DHB_GOBJECT_H_IN
  581. -DHB_EXTERN=
  582. --cflags-end
  583. --library=harfbuzz-gobject
  584. --library=harfbuzz
  585. -L${hb_libpath}
  586. ${extra_libs}
  587. --filelist ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
  588. -o ${hb_libpath}/HarfBuzz-0.0.gir
  589. DEPENDS harfbuzz-gobject harfbuzz ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
  590. )
  591. add_custom_command(
  592. TARGET harfbuzz-gobject
  593. POST_BUILD
  594. COMMAND "${G_IR_COMPILER}"
  595. --verbose --debug
  596. --includedir ${CMAKE_CURRENT_BINARY_DIR}
  597. ${hb_libpath}/HarfBuzz-0.0.gir
  598. -o ${hb_libpath}/HarfBuzz-0.0.typelib
  599. DEPENDS ${hb_libpath}/HarfBuzz-0.0.gir harfbuzz-gobject
  600. )
  601. endif ()
  602. ## Additional framework build configs
  603. if (BUILD_FRAMEWORK)
  604. set (CMAKE_MACOSX_RPATH ON)
  605. set_target_properties(harfbuzz PROPERTIES
  606. FRAMEWORK TRUE
  607. PUBLIC_HEADER "${project_headers}"
  608. XCODE_ATTRIBUTE_INSTALL_PATH "@rpath"
  609. )
  610. set (MACOSX_FRAMEWORK_IDENTIFIER "harfbuzz")
  611. set (MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${HB_VERSION}")
  612. set (MACOSX_FRAMEWORK_BUNDLE_VERSION "${HB_VERSION}")
  613. endif ()
  614. ## Additional harfbuzz build artifacts
  615. if (HB_BUILD_UTILS)
  616. # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindCairo.cmake
  617. find_package(PkgConfig)
  618. pkg_check_modules(PC_CAIRO QUIET cairo)
  619. find_path(CAIRO_INCLUDE_DIRS NAMES cairo.h HINTS ${PC_CAIRO_INCLUDEDIR} ${PC_CAIRO_INCLUDE_DIRS} PATH_SUFFIXES cairo)
  620. find_library(CAIRO_LIBRARIESNAMES cairo HINTS ${PC_CAIRO_LIBDIR} ${PC_CAIRO_LIBRARY_DIRS})
  621. add_definitions("-DPACKAGE_NAME=\"HarfBuzz\"")
  622. add_definitions("-DPACKAGE_VERSION=\"${HB_VERSION}\"")
  623. include_directories(${CAIRO_INCLUDE_DIRS})
  624. add_executable(hb-view ${HB_VIEW_sources})
  625. target_link_libraries(hb-view harfbuzz ${CAIRO_LIBRARIESNAMES})
  626. add_executable(hb-shape ${HB_SHAPE_sources})
  627. target_link_libraries(hb-shape harfbuzz)
  628. add_executable(hb-subset ${HB_SUBSET_CLI_sources})
  629. target_link_libraries(hb-subset harfbuzz harfbuzz-subset)
  630. add_executable(hb-ot-shape-closure ${HB_OT_SHAPE_CLOSURE_sources})
  631. target_link_libraries(hb-ot-shape-closure harfbuzz)
  632. mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIESNAMES)
  633. endif ()
  634. ## Install
  635. include (GNUInstallDirs)
  636. if (NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL)
  637. install(FILES ${project_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
  638. if (HB_HAVE_GOBJECT)
  639. install(FILES ${hb_gobject_headers} ${hb_gobject_gen_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
  640. endif ()
  641. endif ()
  642. if (NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
  643. install(TARGETS harfbuzz
  644. EXPORT harfbuzzConfig
  645. ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  646. LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  647. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  648. FRAMEWORK DESTINATION Library/Frameworks
  649. )
  650. install(EXPORT harfbuzzConfig
  651. NAMESPACE harfbuzz::
  652. DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/harfbuzz
  653. )
  654. if (HB_BUILD_UTILS)
  655. if (WIN32 AND BUILD_SHARED_LIBS)
  656. install(TARGETS harfbuzz-subset
  657. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  658. )
  659. endif ()
  660. install(TARGETS hb-view
  661. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  662. )
  663. install(TARGETS hb-subset
  664. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  665. )
  666. install(TARGETS hb-shape
  667. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  668. )
  669. install(TARGETS hb-ot-shape-closure
  670. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  671. )
  672. endif ()
  673. if (HB_HAVE_GOBJECT)
  674. install(TARGETS harfbuzz-gobject
  675. ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  676. LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  677. RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  678. )
  679. if (HB_HAVE_INTROSPECTION)
  680. if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
  681. set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
  682. else ()
  683. set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
  684. endif ()
  685. install(FILES "${hb_libpath}/HarfBuzz-0.0.gir"
  686. DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/gir-1.0
  687. )
  688. install(FILES "${hb_libpath}/HarfBuzz-0.0.typelib"
  689. DESTINATION ${CMAKE_INSTALL_LIBDIR}/girepository-1.0
  690. )
  691. endif ()
  692. endif ()
  693. endif ()
  694. if (HB_BUILD_TESTS)
  695. ## src/ executables
  696. foreach (prog main test test-gsub-would-substitute test-gpos-size-params test-buffer-serialize hb-ot-tag test-unicode-ranges)
  697. set (prog_name ${prog})
  698. if (${prog_name} STREQUAL "test")
  699. # test can not be used as a valid executable name on cmake, lets special case it
  700. set (prog_name test-test)
  701. endif ()
  702. add_executable(${prog_name} ${PROJECT_SOURCE_DIR}/src/${prog}.cc)
  703. target_link_libraries(${prog_name} harfbuzz ${THIRD_PARTY_LIBS})
  704. endforeach ()
  705. set_target_properties(hb-ot-tag PROPERTIES COMPILE_FLAGS "-DMAIN")
  706. ## Tests
  707. if (UNIX OR MINGW)
  708. if (BUILD_SHARED_LIBS)
  709. # generate harfbuzz.def after build completion
  710. add_custom_command(TARGET harfbuzz POST_BUILD
  711. COMMAND "${PYTHON_EXECUTABLE}" ${PROJECT_SOURCE_DIR}/src/gen-def.py ${PROJECT_BINARY_DIR}/harfbuzz.def ${project_headers}
  712. WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src)
  713. add_test(NAME check-static-inits.sh
  714. COMMAND ${PROJECT_SOURCE_DIR}/src/check-static-inits.sh
  715. WORKING_DIRECTORY ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/harfbuzz.dir/src # ugly hack
  716. )
  717. add_test(NAME check-libstdc++.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-libstdc++.sh)
  718. add_test(NAME check-symbols.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-symbols.sh)
  719. set_tests_properties(
  720. check-static-inits.sh check-libstdc++.sh check-symbols.sh
  721. PROPERTIES
  722. ENVIRONMENT "libs=.;srcdir=${PROJECT_SOURCE_DIR}/src"
  723. SKIP_RETURN_CODE 77)
  724. endif ()
  725. add_test(NAME check-c-linkage-decls.sh COMMAND ./check-c-linkage-decls.sh)
  726. add_test(NAME check-header-guards.sh COMMAND ./check-header-guards.sh)
  727. add_test(NAME check-externs.sh COMMAND ./check-externs.sh)
  728. add_test(NAME check-includes.sh COMMAND ./check-includes.sh)
  729. set_tests_properties(
  730. check-c-linkage-decls.sh check-header-guards.sh check-externs.sh check-includes.sh
  731. PROPERTIES
  732. WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src
  733. SKIP_RETURN_CODE 77)
  734. endif ()
  735. # Needs to come last so that variables defined above are passed to
  736. # subdirectories.
  737. add_subdirectory(test)
  738. endif ()