gcc-runtime.inc 12 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309
  1. require gcc-configure-common.inc
  2. SUMMARY = "Runtime libraries from GCC"
  3. # Over-ride the LICENSE set by gcc-${PV}.inc to remove "& GPLv3"
  4. # All gcc-runtime packages are now covered by the runtime exception.
  5. LICENSE = "GPL-3.0-with-GCC-exception"
  6. CXXFLAGS:remove = "-fvisibility-inlines-hidden"
  7. EXTRA_OECONF_PATHS = "\
  8. --with-gxx-include-dir=${includedir}/c++/${BINV} \
  9. --with-sysroot=/not/exist \
  10. --with-build-sysroot=${STAGING_DIR_TARGET} \
  11. "
  12. EXTRA_OECONF:append:linuxstdbase = " --enable-clocale=gnu"
  13. EXTRA_OECONF:append = " --cache-file=${B}/config.cache"
  14. EXTRA_OECONF:append:libc-newlib = " --with-newlib --with-target-subdir"
  15. EXTRA_OECONF:append:libc-baremetal = " --with-target-subdir"
  16. # Disable ifuncs for libatomic on arm conflicts -march/-mcpu
  17. EXTRA_OECONF:append:arm = " libat_cv_have_ifunc=no "
  18. EXTRA_OECONF:append:armeb = " libat_cv_have_ifunc=no "
  19. DISABLE_STATIC:class-nativesdk ?= ""
  20. # Newlib does not support symbol versioning on libsdtcc++
  21. SYMVERS_CONF:libc-newlib = ""
  22. # Building with thumb enabled on armv6t fails
  23. ARM_INSTRUCTION_SET:armv6 = "arm"
  24. RUNTIMELIBITM = "libitm"
  25. RUNTIMELIBITM:arc = ""
  26. RUNTIMELIBITM:mipsarch = ""
  27. RUNTIMELIBITM:nios2 = ""
  28. RUNTIMELIBITM:microblaze = ""
  29. RUNTIMELIBITM:riscv32 = ""
  30. RUNTIMELIBITM:riscv64 = ""
  31. RUNTIMELIBSSP ?= ""
  32. RUNTIMELIBSSP:mingw32 ?= "libssp"
  33. RUNTIMETARGET = "${RUNTIMELIBSSP} libstdc++-v3 libgomp libatomic ${RUNTIMELIBITM} \
  34. ${@bb.utils.contains_any('FORTRAN', [',fortran',',f77'], 'libquadmath', '', d)} \
  35. "
  36. # Only build libstdc++ for newlib
  37. RUNTIMETARGET:libc-newlib = "libstdc++-v3"
  38. # libiberty
  39. # libgfortran needs separate recipe due to libquadmath dependency
  40. do_configure () {
  41. export CXX="${CXX} -nostdinc++ -L${WORKDIR}/dummylib"
  42. # libstdc++ isn't built yet so CXX would error not able to find it which breaks stdc++'s configure
  43. # tests. Create a dummy empty lib for the purposes of configure.
  44. mkdir -p ${WORKDIR}/dummylib
  45. ${CC} -x c /dev/null -c -o ${WORKDIR}/dummylib/dummylib.o
  46. ${AR} rcs ${WORKDIR}/dummylib/libstdc++.a ${WORKDIR}/dummylib/dummylib.o
  47. for d in libgcc ${RUNTIMETARGET}; do
  48. echo "Configuring $d"
  49. rm -rf ${B}/${TARGET_SYS}/$d/
  50. mkdir -p ${B}/${TARGET_SYS}/$d/
  51. cd ${B}/${TARGET_SYS}/$d/
  52. chmod a+x ${S}/$d/configure
  53. ${S}/$d/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
  54. if [ "$d" = "libgcc" ]; then
  55. (cd ${B}/${TARGET_SYS}/libgcc; oe_runmake enable-execute-stack.c unwind.h md-unwind-support.h sfp-machine.h gthr-default.h)
  56. fi
  57. done
  58. }
  59. EXTRACONFFUNCS += "extract_stashed_builddir"
  60. do_configure[depends] += "${COMPILERDEP}"
  61. do_compile () {
  62. for d in libgcc ${RUNTIMETARGET}; do
  63. cd ${B}/${TARGET_SYS}/$d/
  64. oe_runmake MULTIBUILDTOP=${B}/${TARGET_SYS}/$d/
  65. done
  66. }
  67. do_install () {
  68. for d in ${RUNTIMETARGET}; do
  69. cd ${B}/${TARGET_SYS}/$d/
  70. oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/${TARGET_SYS}/$d/ install
  71. done
  72. if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include ]; then
  73. install -d ${D}${libdir}/${TARGET_SYS}/${BINV}/include
  74. mv ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include/* ${D}${libdir}/${TARGET_SYS}/${BINV}/include
  75. rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include
  76. fi
  77. rm -rf ${D}${infodir}/libgomp.info ${D}${infodir}/dir
  78. rm -rf ${D}${infodir}/libitm.info ${D}${infodir}/dir
  79. rm -rf ${D}${infodir}/libquadmath.info ${D}${infodir}/dir
  80. if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude ]; then
  81. rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude
  82. fi
  83. if [ -d ${D}${infodir} ]; then
  84. rmdir --ignore-fail-on-non-empty -p ${D}${infodir}
  85. fi
  86. }
  87. do_install:append:class-target () {
  88. if [ "${TARGET_OS}" = "linux-gnuspe" ]; then
  89. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  90. fi
  91. if [ "${TARGET_OS}" = "linux-gnun32" ]; then
  92. if [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  93. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux
  94. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux/32
  95. elif [ "${MULTILIB_VARIANTS}" != "" ]; then
  96. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  97. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux/32
  98. else
  99. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  100. fi
  101. elif [ "${TARGET_OS}" = "linux-gnux32" ]; then
  102. if [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  103. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux
  104. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux/x32
  105. elif [ "${MULTILIB_VARIANTS}" != "" ]; then
  106. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  107. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux/32
  108. else
  109. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  110. fi
  111. elif [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  112. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}
  113. ln -s ../${TARGET_SYS}/bits ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}/bits
  114. ln -s ../${TARGET_SYS}/ext ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}/ext
  115. fi
  116. if [ "${TARGET_ARCH}" == "x86_64" -a "${MULTILIB_VARIANTS}" != "" ];then
  117. ln -sf ../${X86ARCH32}${TARGET_VENDOR}-${TARGET_OS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}/32
  118. fi
  119. if [ "${TCLIBC}" != "glibc" ]; then
  120. case "${TARGET_OS}" in
  121. "linux-musl" | "linux-*spe") extra_target_os="linux";;
  122. "linux-musleabi") extra_target_os="linux-gnueabi";;
  123. *) extra_target_os="linux";;
  124. esac
  125. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
  126. fi
  127. chown -R root:root ${D}
  128. }
  129. INHIBIT_DEFAULT_DEPS = "1"
  130. DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++ libgcc virtual/${MLPREFIX}libc"
  131. PROVIDES = "virtual/${TARGET_PREFIX}compilerlibs"
  132. BBCLASSEXTEND = "nativesdk"
  133. PACKAGES = "\
  134. ${PN}-dbg \
  135. libstdc++ \
  136. libstdc++-precompile-dev \
  137. libstdc++-dev \
  138. libstdc++-staticdev \
  139. libg2c \
  140. libg2c-dev \
  141. libssp \
  142. libssp-dev \
  143. libssp-staticdev \
  144. libquadmath \
  145. libquadmath-dev \
  146. libquadmath-staticdev \
  147. libgomp \
  148. libgomp-dev \
  149. libgomp-staticdev \
  150. libatomic \
  151. libatomic-dev \
  152. libatomic-staticdev \
  153. libitm \
  154. libitm-dev \
  155. libitm-staticdev \
  156. "
  157. # The base package doesn't exist, so we clear the recommends.
  158. RRECOMMENDS:${PN}-dbg = ""
  159. # include python debugging scripts
  160. FILES:${PN}-dbg += "\
  161. ${libdir}/libstdc++.*-gdb.py \
  162. ${datadir}/gcc-${BINV}/python/libstdcxx \
  163. "
  164. FILES:libg2c = "${target_libdir}/libg2c.so.*"
  165. SUMMARY:libg2c = "Companion runtime library for g77"
  166. FILES:libg2c-dev = "\
  167. ${libdir}/libg2c.so \
  168. ${libdir}/libg2c.a \
  169. ${libdir}/libfrtbegin.a \
  170. "
  171. SUMMARY:libg2c-dev = "Companion runtime library for g77 - development files"
  172. FILES:libstdc++ = "${libdir}/libstdc++.so.*"
  173. SUMMARY:libstdc++ = "GNU standard C++ library"
  174. FILES:libstdc++-dev = "\
  175. ${includedir}/c++/ \
  176. ${libdir}/libstdc++.so \
  177. ${libdir}/libstdc++*.la \
  178. ${libdir}/libsupc++.la \
  179. "
  180. SUMMARY:libstdc++-dev = "GNU standard C++ library - development files"
  181. FILES:libstdc++-staticdev = "\
  182. ${libdir}/libstdc++*.a \
  183. ${libdir}/libsupc++.a \
  184. "
  185. SUMMARY:libstdc++-staticdev = "GNU standard C++ library - static development files"
  186. FILES:libstdc++-precompile-dev = "${includedir}/c++/${TARGET_SYS}/bits/*.gch"
  187. SUMMARY:libstdc++-precompile-dev = "GNU standard C++ library - precompiled header files"
  188. FILES:libssp = "${libdir}/libssp.so.*"
  189. SUMMARY:libssp = "GNU stack smashing protection library"
  190. FILES:libssp-dev = "\
  191. ${libdir}/libssp*.so \
  192. ${libdir}/libssp*_nonshared.a \
  193. ${libdir}/libssp*.la \
  194. ${libdir}/${TARGET_SYS}/${BINV}/include/ssp \
  195. "
  196. SUMMARY:libssp-dev = "GNU stack smashing protection library - development files"
  197. FILES:libssp-staticdev = "${libdir}/libssp*.a"
  198. SUMMARY:libssp-staticdev = "GNU stack smashing protection library - static development files"
  199. FILES:libquadmath = "${libdir}/libquadmath*.so.*"
  200. SUMMARY:libquadmath = "GNU quad-precision math library"
  201. FILES:libquadmath-dev = "\
  202. ${libdir}/${TARGET_SYS}/${BINV}/include/quadmath* \
  203. ${libdir}/libquadmath*.so \
  204. ${libdir}/libquadmath.la \
  205. "
  206. SUMMARY:libquadmath-dev = "GNU quad-precision math library - development files"
  207. FILES:libquadmath-staticdev = "${libdir}/libquadmath.a"
  208. SUMMARY:libquadmath-staticdev = "GNU quad-precision math library - static development files"
  209. FILES:libgomp = "${libdir}/libgomp*${SOLIBS}"
  210. SUMMARY:libgomp = "GNU OpenMP parallel programming library"
  211. FILES:libgomp-dev = "\
  212. ${libdir}/libgomp*${SOLIBSDEV} \
  213. ${libdir}/libgomp*.la \
  214. ${libdir}/libgomp.spec \
  215. ${libdir}/${TARGET_SYS}/${BINV}/include/acc_prof.h \
  216. ${libdir}/${TARGET_SYS}/${BINV}/include/omp.h \
  217. ${libdir}/${TARGET_SYS}/${BINV}/include/openacc.h \
  218. "
  219. SUMMARY:libgomp-dev = "GNU OpenMP parallel programming library - development files"
  220. FILES:libgomp-staticdev = "${libdir}/libgomp*.a"
  221. SUMMARY:libgomp-staticdev = "GNU OpenMP parallel programming library - static development files"
  222. FILES:libatomic = "${libdir}/libatomic.so.*"
  223. SUMMARY:libatomic = "GNU C++11 atomics support library"
  224. FILES:libatomic-dev = "\
  225. ${libdir}/libatomic.so \
  226. ${libdir}/libatomic.la \
  227. "
  228. SUMMARY:libatomic-dev = "GNU C++11 atomics support library - development files"
  229. FILES:libatomic-staticdev = "${libdir}/libatomic.a"
  230. SUMMARY:libatomic-staticdev = "GNU C++11 atomics support library - static development files"
  231. FILES:libitm = "${libdir}/libitm.so.*"
  232. SUMMARY:libitm = "GNU transactional memory support library"
  233. FILES:libitm-dev = "\
  234. ${libdir}/libitm.so \
  235. ${libdir}/libitm.la \
  236. ${libdir}/libitm.spec \
  237. "
  238. SUMMARY:libitm-dev = "GNU transactional memory support library - development files"
  239. FILES:libitm-staticdev = "${libdir}/libitm.a"
  240. SUMMARY:libitm-staticdev = "GNU transactional memory support library - static development files"
  241. require gcc-testsuite.inc
  242. EXTRA_OEMAKE:prepend:task-check = "${PARALLEL_MAKE} "
  243. MAKE_CHECK_TARGETS ??= "check-gcc ${@" ".join("check-target-" + i for i in d.getVar("RUNTIMETARGET").split())}"
  244. # prettyprinters and xmethods require gdb tooling
  245. MAKE_CHECK_IGNORE ??= "prettyprinters.exp xmethods.exp"
  246. MAKE_CHECK_RUNTESTFLAGS ??= "${MAKE_CHECK_BOARDARGS} --ignore '${MAKE_CHECK_IGNORE}'"
  247. # specific host and target dependencies required for test suite running
  248. do_check[depends] += "dejagnu-native:do_populate_sysroot expect-native:do_populate_sysroot"
  249. do_check[depends] += "virtual/libc:do_populate_sysroot"
  250. # only depend on qemu if targeting linux user execution
  251. do_check[depends] += "${@'qemu-native:do_populate_sysroot' if "user" in d.getVar('TOOLCHAIN_TEST_TARGET') else ''}"
  252. # extend the recipe sysroot to include the built libraries (for qemu usermode)
  253. do_check[prefuncs] += "extend_recipe_sysroot"
  254. do_check[prefuncs] += "check_prepare"
  255. do_check[dirs] = "${WORKDIR}/dejagnu ${B}"
  256. do_check[nostamp] = "1"
  257. do_check() {
  258. export DEJAGNU="${WORKDIR}/dejagnu/site.exp"
  259. # HACK: this works around the configure setting CXX with -nostd* args
  260. sed -i 's#-nostdinc++ -L${WORKDIR}/dummylib##g' $(find ${B} -name testsuite_flags | head -1)
  261. if [ "${TOOLCHAIN_TEST_TARGET}" = "user" ]; then
  262. # qemu user has issues allocating large amounts of memory
  263. export G_SLICE=always-malloc
  264. # no test should need more that 10G of memory, this prevents tests like pthread7-rope from leaking memory
  265. ulimit -m 4194304
  266. ulimit -v 10485760
  267. fi
  268. oe_runmake -i ${MAKE_CHECK_TARGETS} RUNTESTFLAGS="${MAKE_CHECK_RUNTESTFLAGS}"
  269. }
  270. addtask check after do_compile do_populate_sysroot