gcc-runtime.inc 12 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310
  1. require gcc-configure-common.inc
  2. SUMMARY = "Runtime libraries from GCC"
  3. # Over-ride the LICENSE set by gcc-${PV}.inc to remove "& GPLv3"
  4. # All gcc-runtime packages are now covered by the runtime exception.
  5. LICENSE = "GPL-3.0-with-GCC-exception"
  6. CXXFLAGS:remove = "-fvisibility-inlines-hidden"
  7. EXTRA_OECONF_PATHS = "\
  8. --with-gxx-include-dir=${includedir}/c++/${BINV} \
  9. --with-sysroot=/not/exist \
  10. --with-build-sysroot=${STAGING_DIR_TARGET} \
  11. "
  12. EXTRA_OECONF:append:linuxstdbase = " --enable-clocale=gnu"
  13. EXTRA_OECONF:append = " --cache-file=${B}/config.cache"
  14. EXTRA_OECONF:append:libc-newlib = " --with-newlib --with-target-subdir"
  15. EXTRA_OECONF:append:libc-baremetal = " --with-target-subdir"
  16. # Disable ifuncs for libatomic on arm conflicts -march/-mcpu
  17. EXTRA_OECONF:append:arm = " libat_cv_have_ifunc=no "
  18. EXTRA_OECONF:append:armeb = " libat_cv_have_ifunc=no "
  19. DISABLE_STATIC:class-nativesdk ?= ""
  20. # Newlib does not support symbol versioning on libsdtcc++
  21. SYMVERS_CONF:libc-newlib = ""
  22. # Building with thumb enabled on armv6t fails
  23. ARM_INSTRUCTION_SET:armv6 = "arm"
  24. RUNTIMELIBITM = "libitm"
  25. RUNTIMELIBITM:arc = ""
  26. RUNTIMELIBITM:mipsarch = ""
  27. RUNTIMELIBITM:nios2 = ""
  28. RUNTIMELIBITM:microblaze = ""
  29. RUNTIMELIBITM:riscv32 = ""
  30. RUNTIMELIBITM:riscv64 = ""
  31. RUNTIMELIBITM:loongarch64 = ""
  32. RUNTIMELIBSSP ?= ""
  33. RUNTIMELIBSSP:mingw32 ?= "libssp"
  34. RUNTIMETARGET = "${RUNTIMELIBSSP} libstdc++-v3 libgomp libatomic ${RUNTIMELIBITM} \
  35. ${@bb.utils.contains_any('FORTRAN', [',fortran',',f77'], 'libquadmath', '', d)} \
  36. "
  37. # Only build libstdc++ for newlib
  38. RUNTIMETARGET:libc-newlib = "libstdc++-v3"
  39. # libiberty
  40. # libgfortran needs separate recipe due to libquadmath dependency
  41. do_configure () {
  42. export CXX="${CXX} -nostdinc++ -L${WORKDIR}/dummylib"
  43. # libstdc++ isn't built yet so CXX would error not able to find it which breaks stdc++'s configure
  44. # tests. Create a dummy empty lib for the purposes of configure.
  45. mkdir -p ${WORKDIR}/dummylib
  46. ${CC} -x c /dev/null -c -o ${WORKDIR}/dummylib/dummylib.o
  47. ${AR} rcs ${WORKDIR}/dummylib/libstdc++.a ${WORKDIR}/dummylib/dummylib.o
  48. for d in libgcc ${RUNTIMETARGET}; do
  49. echo "Configuring $d"
  50. rm -rf ${B}/${TARGET_SYS}/$d/
  51. mkdir -p ${B}/${TARGET_SYS}/$d/
  52. cd ${B}/${TARGET_SYS}/$d/
  53. chmod a+x ${S}/$d/configure
  54. ${S}/$d/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
  55. if [ "$d" = "libgcc" ]; then
  56. (cd ${B}/${TARGET_SYS}/libgcc; oe_runmake enable-execute-stack.c unwind.h md-unwind-support.h sfp-machine.h gthr-default.h)
  57. fi
  58. done
  59. }
  60. EXTRACONFFUNCS += "extract_stashed_builddir"
  61. do_configure[depends] += "${COMPILERDEP}"
  62. do_compile () {
  63. for d in libgcc ${RUNTIMETARGET}; do
  64. cd ${B}/${TARGET_SYS}/$d/
  65. oe_runmake MULTIBUILDTOP=${B}/${TARGET_SYS}/$d/
  66. done
  67. }
  68. do_install () {
  69. for d in ${RUNTIMETARGET}; do
  70. cd ${B}/${TARGET_SYS}/$d/
  71. oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/${TARGET_SYS}/$d/ install
  72. done
  73. if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include ]; then
  74. install -d ${D}${libdir}/${TARGET_SYS}/${BINV}/include
  75. mv ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include/* ${D}${libdir}/${TARGET_SYS}/${BINV}/include
  76. rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include
  77. fi
  78. rm -rf ${D}${infodir}/libgomp.info ${D}${infodir}/dir
  79. rm -rf ${D}${infodir}/libitm.info ${D}${infodir}/dir
  80. rm -rf ${D}${infodir}/libquadmath.info ${D}${infodir}/dir
  81. if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude ]; then
  82. rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude
  83. fi
  84. if [ -d ${D}${infodir} ]; then
  85. rmdir --ignore-fail-on-non-empty -p ${D}${infodir}
  86. fi
  87. }
  88. do_install:append:class-target () {
  89. if [ "${TARGET_OS}" = "linux-gnuspe" ]; then
  90. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  91. fi
  92. if [ "${TARGET_OS}" = "linux-gnun32" ]; then
  93. if [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  94. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux
  95. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux/32
  96. elif [ "${MULTILIB_VARIANTS}" != "" ]; then
  97. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  98. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux/32
  99. else
  100. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  101. fi
  102. elif [ "${TARGET_OS}" = "linux-gnux32" ]; then
  103. if [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  104. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux
  105. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux/x32
  106. elif [ "${MULTILIB_VARIANTS}" != "" ]; then
  107. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  108. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux/32
  109. else
  110. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  111. fi
  112. elif [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  113. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}
  114. ln -s ../${TARGET_SYS}/bits ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}/bits
  115. ln -s ../${TARGET_SYS}/ext ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}/ext
  116. fi
  117. if [ "${TARGET_ARCH}" = "x86_64" -a "${MULTILIB_VARIANTS}" != "" ];then
  118. ln -sf ../${X86ARCH32}${TARGET_VENDOR}-${TARGET_OS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}/32
  119. fi
  120. if [ "${TCLIBC}" != "glibc" ]; then
  121. case "${TARGET_OS}" in
  122. "linux-musl" | "linux-*spe") extra_target_os="linux";;
  123. "linux-musleabi") extra_target_os="linux-gnueabi";;
  124. *) extra_target_os="linux";;
  125. esac
  126. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
  127. fi
  128. chown -R root:root ${D}
  129. }
  130. INHIBIT_DEFAULT_DEPS = "1"
  131. DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++ libgcc virtual/${MLPREFIX}libc"
  132. PROVIDES = "virtual/${TARGET_PREFIX}compilerlibs"
  133. BBCLASSEXTEND = "nativesdk"
  134. PACKAGES = "\
  135. ${PN}-dbg \
  136. libstdc++ \
  137. libstdc++-precompile-dev \
  138. libstdc++-dev \
  139. libstdc++-staticdev \
  140. libg2c \
  141. libg2c-dev \
  142. libssp \
  143. libssp-dev \
  144. libssp-staticdev \
  145. libquadmath \
  146. libquadmath-dev \
  147. libquadmath-staticdev \
  148. libgomp \
  149. libgomp-dev \
  150. libgomp-staticdev \
  151. libatomic \
  152. libatomic-dev \
  153. libatomic-staticdev \
  154. libitm \
  155. libitm-dev \
  156. libitm-staticdev \
  157. "
  158. # The base package doesn't exist, so we clear the recommends.
  159. RRECOMMENDS:${PN}-dbg = ""
  160. # include python debugging scripts
  161. FILES:${PN}-dbg += "\
  162. ${libdir}/libstdc++.*-gdb.py \
  163. ${datadir}/gcc-${BINV}/python/libstdcxx \
  164. "
  165. FILES:libg2c = "${target_libdir}/libg2c.so.*"
  166. SUMMARY:libg2c = "Companion runtime library for g77"
  167. FILES:libg2c-dev = "\
  168. ${libdir}/libg2c.so \
  169. ${libdir}/libg2c.a \
  170. ${libdir}/libfrtbegin.a \
  171. "
  172. SUMMARY:libg2c-dev = "Companion runtime library for g77 - development files"
  173. FILES:libstdc++ = "${libdir}/libstdc++.so.*"
  174. SUMMARY:libstdc++ = "GNU standard C++ library"
  175. FILES:libstdc++-dev = "\
  176. ${includedir}/c++/ \
  177. ${libdir}/libstdc++.so \
  178. ${libdir}/libstdc++*.la \
  179. ${libdir}/libsupc++.la \
  180. "
  181. SUMMARY:libstdc++-dev = "GNU standard C++ library - development files"
  182. FILES:libstdc++-staticdev = "\
  183. ${libdir}/libstdc++*.a \
  184. ${libdir}/libsupc++.a \
  185. "
  186. SUMMARY:libstdc++-staticdev = "GNU standard C++ library - static development files"
  187. FILES:libstdc++-precompile-dev = "${includedir}/c++/${TARGET_SYS}/bits/*.gch"
  188. SUMMARY:libstdc++-precompile-dev = "GNU standard C++ library - precompiled header files"
  189. FILES:libssp = "${libdir}/libssp.so.*"
  190. SUMMARY:libssp = "GNU stack smashing protection library"
  191. FILES:libssp-dev = "\
  192. ${libdir}/libssp*.so \
  193. ${libdir}/libssp*_nonshared.a \
  194. ${libdir}/libssp*.la \
  195. ${libdir}/${TARGET_SYS}/${BINV}/include/ssp \
  196. "
  197. SUMMARY:libssp-dev = "GNU stack smashing protection library - development files"
  198. FILES:libssp-staticdev = "${libdir}/libssp*.a"
  199. SUMMARY:libssp-staticdev = "GNU stack smashing protection library - static development files"
  200. FILES:libquadmath = "${libdir}/libquadmath*.so.*"
  201. SUMMARY:libquadmath = "GNU quad-precision math library"
  202. FILES:libquadmath-dev = "\
  203. ${libdir}/${TARGET_SYS}/${BINV}/include/quadmath* \
  204. ${libdir}/libquadmath*.so \
  205. ${libdir}/libquadmath.la \
  206. "
  207. SUMMARY:libquadmath-dev = "GNU quad-precision math library - development files"
  208. FILES:libquadmath-staticdev = "${libdir}/libquadmath.a"
  209. SUMMARY:libquadmath-staticdev = "GNU quad-precision math library - static development files"
  210. FILES:libgomp = "${libdir}/libgomp*${SOLIBS}"
  211. SUMMARY:libgomp = "GNU OpenMP parallel programming library"
  212. FILES:libgomp-dev = "\
  213. ${libdir}/libgomp*${SOLIBSDEV} \
  214. ${libdir}/libgomp*.la \
  215. ${libdir}/libgomp.spec \
  216. ${libdir}/${TARGET_SYS}/${BINV}/include/acc_prof.h \
  217. ${libdir}/${TARGET_SYS}/${BINV}/include/omp.h \
  218. ${libdir}/${TARGET_SYS}/${BINV}/include/openacc.h \
  219. "
  220. SUMMARY:libgomp-dev = "GNU OpenMP parallel programming library - development files"
  221. FILES:libgomp-staticdev = "${libdir}/libgomp*.a"
  222. SUMMARY:libgomp-staticdev = "GNU OpenMP parallel programming library - static development files"
  223. FILES:libatomic = "${libdir}/libatomic.so.*"
  224. SUMMARY:libatomic = "GNU C++11 atomics support library"
  225. FILES:libatomic-dev = "\
  226. ${libdir}/libatomic.so \
  227. ${libdir}/libatomic.la \
  228. "
  229. SUMMARY:libatomic-dev = "GNU C++11 atomics support library - development files"
  230. FILES:libatomic-staticdev = "${libdir}/libatomic.a"
  231. SUMMARY:libatomic-staticdev = "GNU C++11 atomics support library - static development files"
  232. FILES:libitm = "${libdir}/libitm.so.*"
  233. SUMMARY:libitm = "GNU transactional memory support library"
  234. FILES:libitm-dev = "\
  235. ${libdir}/libitm.so \
  236. ${libdir}/libitm.la \
  237. ${libdir}/libitm.spec \
  238. "
  239. SUMMARY:libitm-dev = "GNU transactional memory support library - development files"
  240. FILES:libitm-staticdev = "${libdir}/libitm.a"
  241. SUMMARY:libitm-staticdev = "GNU transactional memory support library - static development files"
  242. require gcc-testsuite.inc
  243. EXTRA_OEMAKE:prepend:task-check = "${PARALLEL_MAKE} "
  244. MAKE_CHECK_TARGETS ??= "check-gcc ${@" ".join("check-target-" + i for i in d.getVar("RUNTIMETARGET").split())}"
  245. # prettyprinters and xmethods require gdb tooling
  246. MAKE_CHECK_IGNORE ??= "prettyprinters.exp xmethods.exp"
  247. MAKE_CHECK_RUNTESTFLAGS ??= "${MAKE_CHECK_BOARDARGS} --ignore '${MAKE_CHECK_IGNORE}'"
  248. # specific host and target dependencies required for test suite running
  249. do_check[depends] += "dejagnu-native:do_populate_sysroot expect-native:do_populate_sysroot"
  250. do_check[depends] += "virtual/libc:do_populate_sysroot"
  251. # only depend on qemu if targeting linux user execution
  252. do_check[depends] += "${@'qemu-native:do_populate_sysroot' if "user" in d.getVar('TOOLCHAIN_TEST_TARGET') else ''}"
  253. # extend the recipe sysroot to include the built libraries (for qemu usermode)
  254. do_check[prefuncs] += "extend_recipe_sysroot"
  255. do_check[prefuncs] += "check_prepare"
  256. do_check[dirs] = "${WORKDIR}/dejagnu ${B}"
  257. do_check[nostamp] = "1"
  258. do_check() {
  259. export DEJAGNU="${WORKDIR}/dejagnu/site.exp"
  260. # HACK: this works around the configure setting CXX with -nostd* args
  261. sed -i 's#-nostdinc++ -L${WORKDIR}/dummylib##g' $(find ${B} -name testsuite_flags | head -1)
  262. if [ "${TOOLCHAIN_TEST_TARGET}" = "user" ]; then
  263. # qemu user has issues allocating large amounts of memory
  264. export G_SLICE=always-malloc
  265. # no test should need more that 10G of memory, this prevents tests like pthread7-rope from leaking memory
  266. ulimit -m 4194304
  267. ulimit -v 10485760
  268. fi
  269. oe_runmake -i ${MAKE_CHECK_TARGETS} RUNTESTFLAGS="${MAKE_CHECK_RUNTESTFLAGS}"
  270. }
  271. addtask check after do_compile do_populate_sysroot