zconf.y 16 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782
  1. %{
  2. /*
  3. * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
  4. * Released under the terms of the GNU GPL v2.0.
  5. */
  6. #include <ctype.h>
  7. #include <stdarg.h>
  8. #include <stdio.h>
  9. #include <stdlib.h>
  10. #include <string.h>
  11. #include <stdbool.h>
  12. #include "lkc.h"
  13. #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  14. #define PRINTD 0x0001
  15. #define DEBUG_PARSE 0x0002
  16. int cdebug = PRINTD;
  17. int yylex(void);
  18. static void yyerror(const char *err);
  19. static void zconfprint(const char *err, ...);
  20. static void zconf_error(const char *err, ...);
  21. static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  22. struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  23. static struct menu *current_menu, *current_entry;
  24. %}
  25. %expect 32
  26. %union
  27. {
  28. char *string;
  29. struct file *file;
  30. struct symbol *symbol;
  31. struct expr *expr;
  32. struct menu *menu;
  33. const struct kconf_id *id;
  34. }
  35. %token <id>T_MAINMENU
  36. %token <id>T_MENU
  37. %token <id>T_ENDMENU
  38. %token <id>T_SOURCE
  39. %token <id>T_CHOICE
  40. %token <id>T_ENDCHOICE
  41. %token <id>T_COMMENT
  42. %token <id>T_CONFIG
  43. %token <id>T_MENUCONFIG
  44. %token <id>T_HELP
  45. %token <string> T_HELPTEXT
  46. %token <id>T_IF
  47. %token <id>T_ENDIF
  48. %token <id>T_DEPENDS
  49. %token <id>T_OPTIONAL
  50. %token <id>T_PROMPT
  51. %token <id>T_TYPE
  52. %token <id>T_DEFAULT
  53. %token <id>T_SELECT
  54. %token <id>T_IMPLY
  55. %token <id>T_RANGE
  56. %token <id>T_VISIBLE
  57. %token <id>T_OPTION
  58. %token <id>T_ON
  59. %token <string> T_WORD
  60. %token <string> T_WORD_QUOTE
  61. %token T_UNEQUAL
  62. %token T_LESS
  63. %token T_LESS_EQUAL
  64. %token T_GREATER
  65. %token T_GREATER_EQUAL
  66. %token T_CLOSE_PAREN
  67. %token T_OPEN_PAREN
  68. %token T_EOL
  69. %left T_OR
  70. %left T_AND
  71. %left T_EQUAL T_UNEQUAL
  72. %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  73. %nonassoc T_NOT
  74. %type <string> prompt
  75. %type <symbol> nonconst_symbol
  76. %type <symbol> symbol
  77. %type <expr> expr
  78. %type <expr> if_expr
  79. %type <id> end
  80. %type <id> option_name
  81. %type <menu> if_entry menu_entry choice_entry
  82. %type <string> symbol_option_arg word_opt
  83. %destructor {
  84. fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  85. $$->file->name, $$->lineno);
  86. if (current_menu == $$)
  87. menu_end_menu();
  88. } if_entry menu_entry choice_entry
  89. %{
  90. /* Include kconf_id.c here so it can see the token constants. */
  91. #include "kconf_id.c"
  92. %}
  93. %%
  94. input: nl start | start;
  95. start: mainmenu_stmt stmt_list | no_mainmenu_stmt stmt_list;
  96. /* mainmenu entry */
  97. mainmenu_stmt: T_MAINMENU prompt nl
  98. {
  99. menu_add_prompt(P_MENU, $2, NULL);
  100. };
  101. /* Default main menu, if there's no mainmenu entry */
  102. no_mainmenu_stmt: /* empty */
  103. {
  104. /*
  105. * Hack: Keep the main menu title on the heap so we can safely free it
  106. * later regardless of whether it comes from the 'prompt' in
  107. * mainmenu_stmt or here
  108. */
  109. menu_add_prompt(P_MENU, xstrdup("Linux Kernel Configuration"), NULL);
  110. };
  111. stmt_list:
  112. /* empty */
  113. | stmt_list common_stmt
  114. | stmt_list choice_stmt
  115. | stmt_list menu_stmt
  116. | stmt_list end { zconf_error("unexpected end statement"); }
  117. | stmt_list T_WORD error T_EOL { zconf_error("unknown statement \"%s\"", $2); }
  118. | stmt_list option_name error T_EOL
  119. {
  120. zconf_error("unexpected option \"%s\"", $2->name);
  121. }
  122. | stmt_list error T_EOL { zconf_error("invalid statement"); }
  123. ;
  124. option_name:
  125. T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
  126. ;
  127. common_stmt:
  128. T_EOL
  129. | if_stmt
  130. | comment_stmt
  131. | config_stmt
  132. | menuconfig_stmt
  133. | source_stmt
  134. ;
  135. option_error:
  136. T_WORD error T_EOL { zconf_error("unknown option \"%s\"", $1); }
  137. | error T_EOL { zconf_error("invalid option"); }
  138. ;
  139. /* config/menuconfig entry */
  140. config_entry_start: T_CONFIG nonconst_symbol T_EOL
  141. {
  142. $2->flags |= SYMBOL_OPTIONAL;
  143. menu_add_entry($2);
  144. printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
  145. };
  146. config_stmt: config_entry_start config_option_list
  147. {
  148. printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
  149. };
  150. menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
  151. {
  152. $2->flags |= SYMBOL_OPTIONAL;
  153. menu_add_entry($2);
  154. printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
  155. };
  156. menuconfig_stmt: menuconfig_entry_start config_option_list
  157. {
  158. if (current_entry->prompt)
  159. current_entry->prompt->type = P_MENU;
  160. else
  161. zconfprint("warning: menuconfig statement without prompt");
  162. printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
  163. };
  164. config_option_list:
  165. /* empty */
  166. | config_option_list config_option
  167. | config_option_list symbol_option
  168. | config_option_list depends
  169. | config_option_list help
  170. | config_option_list option_error
  171. | config_option_list T_EOL
  172. ;
  173. config_option: T_TYPE prompt_stmt_opt T_EOL
  174. {
  175. menu_set_type($1->stype);
  176. printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
  177. zconf_curname(), zconf_lineno(),
  178. $1->stype);
  179. };
  180. config_option: T_PROMPT prompt if_expr T_EOL
  181. {
  182. menu_add_prompt(P_PROMPT, $2, $3);
  183. printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
  184. };
  185. config_option: T_DEFAULT expr if_expr T_EOL
  186. {
  187. menu_add_expr(P_DEFAULT, $2, $3);
  188. if ($1->stype != S_UNKNOWN)
  189. menu_set_type($1->stype);
  190. printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
  191. zconf_curname(), zconf_lineno(),
  192. $1->stype);
  193. };
  194. config_option: T_SELECT nonconst_symbol if_expr T_EOL
  195. {
  196. menu_add_symbol(P_SELECT, $2, $3);
  197. printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
  198. };
  199. config_option: T_IMPLY nonconst_symbol if_expr T_EOL
  200. {
  201. menu_add_symbol(P_IMPLY, $2, $3);
  202. printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
  203. };
  204. config_option: T_RANGE symbol symbol if_expr T_EOL
  205. {
  206. menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
  207. printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
  208. };
  209. symbol_option: T_OPTION symbol_option_list T_EOL
  210. ;
  211. symbol_option_list:
  212. /* empty */
  213. | symbol_option_list T_WORD symbol_option_arg
  214. {
  215. const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
  216. if (id && id->flags & TF_OPTION) {
  217. menu_add_option(id->token, $3);
  218. free($3);
  219. }
  220. else
  221. zconfprint("warning: ignoring unknown option %s", $2);
  222. free($2);
  223. };
  224. symbol_option_arg:
  225. /* empty */ { $$ = NULL; }
  226. | T_EQUAL prompt { $$ = $2; }
  227. ;
  228. /* choice entry */
  229. choice: T_CHOICE word_opt T_EOL
  230. {
  231. struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
  232. sym->flags |= SYMBOL_AUTO;
  233. menu_add_entry(sym);
  234. menu_add_expr(P_CHOICE, NULL, NULL);
  235. free($2);
  236. printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
  237. };
  238. choice_entry: choice choice_option_list
  239. {
  240. $$ = menu_add_menu();
  241. };
  242. choice_end: end
  243. {
  244. if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
  245. menu_end_menu();
  246. printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
  247. }
  248. };
  249. choice_stmt: choice_entry choice_block choice_end
  250. ;
  251. choice_option_list:
  252. /* empty */
  253. | choice_option_list choice_option
  254. | choice_option_list depends
  255. | choice_option_list help
  256. | choice_option_list T_EOL
  257. | choice_option_list option_error
  258. ;
  259. choice_option: T_PROMPT prompt if_expr T_EOL
  260. {
  261. menu_add_prompt(P_PROMPT, $2, $3);
  262. printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
  263. };
  264. choice_option: T_TYPE prompt_stmt_opt T_EOL
  265. {
  266. if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
  267. menu_set_type($1->stype);
  268. printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
  269. zconf_curname(), zconf_lineno(),
  270. $1->stype);
  271. } else
  272. YYERROR;
  273. };
  274. choice_option: T_OPTIONAL T_EOL
  275. {
  276. current_entry->sym->flags |= SYMBOL_OPTIONAL;
  277. printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
  278. };
  279. choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
  280. {
  281. if ($1->stype == S_UNKNOWN) {
  282. menu_add_symbol(P_DEFAULT, $2, $3);
  283. printd(DEBUG_PARSE, "%s:%d:default\n",
  284. zconf_curname(), zconf_lineno());
  285. } else
  286. YYERROR;
  287. };
  288. choice_block:
  289. /* empty */
  290. | choice_block common_stmt
  291. ;
  292. /* if entry */
  293. if_entry: T_IF expr nl
  294. {
  295. printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
  296. menu_add_entry(NULL);
  297. menu_add_dep($2);
  298. $$ = menu_add_menu();
  299. };
  300. if_end: end
  301. {
  302. if (zconf_endtoken($1, T_IF, T_ENDIF)) {
  303. menu_end_menu();
  304. printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
  305. }
  306. };
  307. if_stmt: if_entry if_block if_end
  308. ;
  309. if_block:
  310. /* empty */
  311. | if_block common_stmt
  312. | if_block menu_stmt
  313. | if_block choice_stmt
  314. ;
  315. /* menu entry */
  316. menu: T_MENU prompt T_EOL
  317. {
  318. menu_add_entry(NULL);
  319. menu_add_prompt(P_MENU, $2, NULL);
  320. printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
  321. };
  322. menu_entry: menu visibility_list depends_list
  323. {
  324. $$ = menu_add_menu();
  325. };
  326. menu_end: end
  327. {
  328. if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
  329. menu_end_menu();
  330. printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
  331. }
  332. };
  333. menu_stmt: menu_entry menu_block menu_end
  334. ;
  335. menu_block:
  336. /* empty */
  337. | menu_block common_stmt
  338. | menu_block menu_stmt
  339. | menu_block choice_stmt
  340. ;
  341. source_stmt: T_SOURCE prompt T_EOL
  342. {
  343. printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
  344. zconf_nextfile($2);
  345. free($2);
  346. };
  347. /* comment entry */
  348. comment: T_COMMENT prompt T_EOL
  349. {
  350. menu_add_entry(NULL);
  351. menu_add_prompt(P_COMMENT, $2, NULL);
  352. printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
  353. };
  354. comment_stmt: comment depends_list
  355. ;
  356. /* help option */
  357. help_start: T_HELP T_EOL
  358. {
  359. printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
  360. zconf_starthelp();
  361. };
  362. help: help_start T_HELPTEXT
  363. {
  364. if (current_entry->help) {
  365. free(current_entry->help);
  366. zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
  367. current_entry->sym->name ?: "<choice>");
  368. }
  369. /* Is the help text empty or all whitespace? */
  370. if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
  371. zconfprint("warning: '%s' defined with blank help text",
  372. current_entry->sym->name ?: "<choice>");
  373. current_entry->help = $2;
  374. };
  375. /* depends option */
  376. depends_list:
  377. /* empty */
  378. | depends_list depends
  379. | depends_list T_EOL
  380. | depends_list option_error
  381. ;
  382. depends: T_DEPENDS T_ON expr T_EOL
  383. {
  384. menu_add_dep($3);
  385. printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
  386. };
  387. /* visibility option */
  388. visibility_list:
  389. /* empty */
  390. | visibility_list visible
  391. | visibility_list T_EOL
  392. ;
  393. visible: T_VISIBLE if_expr
  394. {
  395. menu_add_visibility($2);
  396. };
  397. /* prompt statement */
  398. prompt_stmt_opt:
  399. /* empty */
  400. | prompt if_expr
  401. {
  402. menu_add_prompt(P_PROMPT, $1, $2);
  403. };
  404. prompt: T_WORD
  405. | T_WORD_QUOTE
  406. ;
  407. end: T_ENDMENU T_EOL { $$ = $1; }
  408. | T_ENDCHOICE T_EOL { $$ = $1; }
  409. | T_ENDIF T_EOL { $$ = $1; }
  410. ;
  411. nl:
  412. T_EOL
  413. | nl T_EOL
  414. ;
  415. if_expr: /* empty */ { $$ = NULL; }
  416. | T_IF expr { $$ = $2; }
  417. ;
  418. expr: symbol { $$ = expr_alloc_symbol($1); }
  419. | symbol T_LESS symbol { $$ = expr_alloc_comp(E_LTH, $1, $3); }
  420. | symbol T_LESS_EQUAL symbol { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
  421. | symbol T_GREATER symbol { $$ = expr_alloc_comp(E_GTH, $1, $3); }
  422. | symbol T_GREATER_EQUAL symbol { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
  423. | symbol T_EQUAL symbol { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
  424. | symbol T_UNEQUAL symbol { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
  425. | T_OPEN_PAREN expr T_CLOSE_PAREN { $$ = $2; }
  426. | T_NOT expr { $$ = expr_alloc_one(E_NOT, $2); }
  427. | expr T_OR expr { $$ = expr_alloc_two(E_OR, $1, $3); }
  428. | expr T_AND expr { $$ = expr_alloc_two(E_AND, $1, $3); }
  429. ;
  430. /* For symbol definitions, selects, etc., where quotes are not accepted */
  431. nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
  432. symbol: nonconst_symbol
  433. | T_WORD_QUOTE { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
  434. ;
  435. word_opt: /* empty */ { $$ = NULL; }
  436. | T_WORD
  437. %%
  438. void conf_parse(const char *name)
  439. {
  440. const char *tmp;
  441. struct symbol *sym;
  442. int i;
  443. zconf_initscan(name);
  444. sym_init();
  445. _menu_init();
  446. if (getenv("ZCONF_DEBUG"))
  447. yydebug = 1;
  448. yyparse();
  449. if (yynerrs)
  450. exit(1);
  451. if (!modules_sym)
  452. modules_sym = sym_find( "n" );
  453. tmp = rootmenu.prompt->text;
  454. rootmenu.prompt->text = _(rootmenu.prompt->text);
  455. rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
  456. free((char*)tmp);
  457. menu_finalize(&rootmenu);
  458. for_all_symbols(i, sym) {
  459. if (sym_check_deps(sym))
  460. yynerrs++;
  461. }
  462. if (yynerrs)
  463. exit(1);
  464. sym_set_change_count(1);
  465. }
  466. static const char *zconf_tokenname(int token)
  467. {
  468. switch (token) {
  469. case T_MENU: return "menu";
  470. case T_ENDMENU: return "endmenu";
  471. case T_CHOICE: return "choice";
  472. case T_ENDCHOICE: return "endchoice";
  473. case T_IF: return "if";
  474. case T_ENDIF: return "endif";
  475. case T_DEPENDS: return "depends";
  476. case T_VISIBLE: return "visible";
  477. }
  478. return "<token>";
  479. }
  480. static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
  481. {
  482. if (id->token != endtoken) {
  483. zconf_error("unexpected '%s' within %s block",
  484. id->name, zconf_tokenname(starttoken));
  485. yynerrs++;
  486. return false;
  487. }
  488. if (current_menu->file != current_file) {
  489. zconf_error("'%s' in different file than '%s'",
  490. id->name, zconf_tokenname(starttoken));
  491. fprintf(stderr, "%s:%d: location of the '%s'\n",
  492. current_menu->file->name, current_menu->lineno,
  493. zconf_tokenname(starttoken));
  494. yynerrs++;
  495. return false;
  496. }
  497. return true;
  498. }
  499. static void zconfprint(const char *err, ...)
  500. {
  501. va_list ap;
  502. fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
  503. va_start(ap, err);
  504. vfprintf(stderr, err, ap);
  505. va_end(ap);
  506. fprintf(stderr, "\n");
  507. }
  508. static void zconf_error(const char *err, ...)
  509. {
  510. va_list ap;
  511. yynerrs++;
  512. fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
  513. va_start(ap, err);
  514. vfprintf(stderr, err, ap);
  515. va_end(ap);
  516. fprintf(stderr, "\n");
  517. }
  518. static void yyerror(const char *err)
  519. {
  520. fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
  521. }
  522. static void print_quoted_string(FILE *out, const char *str)
  523. {
  524. const char *p;
  525. int len;
  526. putc('"', out);
  527. while ((p = strchr(str, '"'))) {
  528. len = p - str;
  529. if (len)
  530. fprintf(out, "%.*s", len, str);
  531. fputs("\\\"", out);
  532. str = p + 1;
  533. }
  534. fputs(str, out);
  535. putc('"', out);
  536. }
  537. static void print_symbol(FILE *out, struct menu *menu)
  538. {
  539. struct symbol *sym = menu->sym;
  540. struct property *prop;
  541. if (sym_is_choice(sym))
  542. fprintf(out, "\nchoice\n");
  543. else
  544. fprintf(out, "\nconfig %s\n", sym->name);
  545. switch (sym->type) {
  546. case S_BOOLEAN:
  547. fputs(" bool\n", out);
  548. break;
  549. case S_TRISTATE:
  550. fputs(" tristate\n", out);
  551. break;
  552. case S_STRING:
  553. fputs(" string\n", out);
  554. break;
  555. case S_INT:
  556. fputs(" integer\n", out);
  557. break;
  558. case S_HEX:
  559. fputs(" hex\n", out);
  560. break;
  561. default:
  562. fputs(" ???\n", out);
  563. break;
  564. }
  565. for (prop = sym->prop; prop; prop = prop->next) {
  566. if (prop->menu != menu)
  567. continue;
  568. switch (prop->type) {
  569. case P_PROMPT:
  570. fputs(" prompt ", out);
  571. print_quoted_string(out, prop->text);
  572. if (!expr_is_yes(prop->visible.expr)) {
  573. fputs(" if ", out);
  574. expr_fprint(prop->visible.expr, out);
  575. }
  576. fputc('\n', out);
  577. break;
  578. case P_DEFAULT:
  579. fputs( " default ", out);
  580. expr_fprint(prop->expr, out);
  581. if (!expr_is_yes(prop->visible.expr)) {
  582. fputs(" if ", out);
  583. expr_fprint(prop->visible.expr, out);
  584. }
  585. fputc('\n', out);
  586. break;
  587. case P_CHOICE:
  588. fputs(" #choice value\n", out);
  589. break;
  590. case P_SELECT:
  591. fputs( " select ", out);
  592. expr_fprint(prop->expr, out);
  593. fputc('\n', out);
  594. break;
  595. case P_IMPLY:
  596. fputs( " imply ", out);
  597. expr_fprint(prop->expr, out);
  598. fputc('\n', out);
  599. break;
  600. case P_RANGE:
  601. fputs( " range ", out);
  602. expr_fprint(prop->expr, out);
  603. fputc('\n', out);
  604. break;
  605. case P_MENU:
  606. fputs( " menu ", out);
  607. print_quoted_string(out, prop->text);
  608. fputc('\n', out);
  609. break;
  610. default:
  611. fprintf(out, " unknown prop %d!\n", prop->type);
  612. break;
  613. }
  614. }
  615. if (menu->help) {
  616. int len = strlen(menu->help);
  617. while (menu->help[--len] == '\n')
  618. menu->help[len] = 0;
  619. fprintf(out, " help\n%s\n", menu->help);
  620. }
  621. }
  622. void zconfdump(FILE *out)
  623. {
  624. struct property *prop;
  625. struct symbol *sym;
  626. struct menu *menu;
  627. menu = rootmenu.list;
  628. while (menu) {
  629. if ((sym = menu->sym))
  630. print_symbol(out, menu);
  631. else if ((prop = menu->prompt)) {
  632. switch (prop->type) {
  633. case P_COMMENT:
  634. fputs("\ncomment ", out);
  635. print_quoted_string(out, prop->text);
  636. fputs("\n", out);
  637. break;
  638. case P_MENU:
  639. fputs("\nmenu ", out);
  640. print_quoted_string(out, prop->text);
  641. fputs("\n", out);
  642. break;
  643. default:
  644. ;
  645. }
  646. if (!expr_is_yes(prop->visible.expr)) {
  647. fputs(" depends ", out);
  648. expr_fprint(prop->visible.expr, out);
  649. fputc('\n', out);
  650. }
  651. }
  652. if (menu->list)
  653. menu = menu->list;
  654. else if (menu->next)
  655. menu = menu->next;
  656. else while ((menu = menu->parent)) {
  657. if (menu->prompt && menu->prompt->type == P_MENU)
  658. fputs("\nendmenu\n", out);
  659. if (menu->next) {
  660. menu = menu->next;
  661. break;
  662. }
  663. }
  664. }
  665. }
  666. #include "zconf.lex.c"
  667. #include "util.c"
  668. #include "confdata.c"
  669. #include "expr.c"
  670. #include "symbol.c"
  671. #include "menu.c"