dtc-parser.y 10 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538
  1. /*
  2. * (C) Copyright David Gibson <dwg@au1.ibm.com>, IBM Corporation. 2005.
  3. *
  4. *
  5. * This program is free software; you can redistribute it and/or
  6. * modify it under the terms of the GNU General Public License as
  7. * published by the Free Software Foundation; either version 2 of the
  8. * License, or (at your option) any later version.
  9. *
  10. * This program is distributed in the hope that it will be useful,
  11. * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13. * General Public License for more details.
  14. *
  15. * You should have received a copy of the GNU General Public License
  16. * along with this program; if not, write to the Free Software
  17. * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  18. * USA
  19. */
  20. %{
  21. #include <stdio.h>
  22. #include <inttypes.h>
  23. #include "dtc.h"
  24. #include "srcpos.h"
  25. extern int yylex(void);
  26. extern void yyerror(char const *s);
  27. #define ERROR(loc, ...) \
  28. do { \
  29. srcpos_error((loc), "Error", __VA_ARGS__); \
  30. treesource_error = true; \
  31. } while (0)
  32. extern struct dt_info *parser_output;
  33. extern bool treesource_error;
  34. %}
  35. %union {
  36. char *propnodename;
  37. char *labelref;
  38. uint8_t byte;
  39. struct data data;
  40. struct {
  41. struct data data;
  42. int bits;
  43. } array;
  44. struct property *prop;
  45. struct property *proplist;
  46. struct node *node;
  47. struct node *nodelist;
  48. struct reserve_info *re;
  49. uint64_t integer;
  50. unsigned int flags;
  51. }
  52. %token DT_V1
  53. %token DT_PLUGIN
  54. %token DT_MEMRESERVE
  55. %token DT_LSHIFT DT_RSHIFT DT_LE DT_GE DT_EQ DT_NE DT_AND DT_OR
  56. %token DT_BITS
  57. %token DT_DEL_PROP
  58. %token DT_DEL_NODE
  59. %token <propnodename> DT_PROPNODENAME
  60. %token <integer> DT_LITERAL
  61. %token <integer> DT_CHAR_LITERAL
  62. %token <byte> DT_BYTE
  63. %token <data> DT_STRING
  64. %token <labelref> DT_LABEL
  65. %token <labelref> DT_REF
  66. %token DT_INCBIN
  67. %type <data> propdata
  68. %type <data> propdataprefix
  69. %type <flags> header
  70. %type <flags> headers
  71. %type <re> memreserve
  72. %type <re> memreserves
  73. %type <array> arrayprefix
  74. %type <data> bytestring
  75. %type <prop> propdef
  76. %type <proplist> proplist
  77. %type <node> devicetree
  78. %type <node> nodedef
  79. %type <node> subnode
  80. %type <nodelist> subnodes
  81. %type <integer> integer_prim
  82. %type <integer> integer_unary
  83. %type <integer> integer_mul
  84. %type <integer> integer_add
  85. %type <integer> integer_shift
  86. %type <integer> integer_rela
  87. %type <integer> integer_eq
  88. %type <integer> integer_bitand
  89. %type <integer> integer_bitxor
  90. %type <integer> integer_bitor
  91. %type <integer> integer_and
  92. %type <integer> integer_or
  93. %type <integer> integer_trinary
  94. %type <integer> integer_expr
  95. %%
  96. sourcefile:
  97. headers memreserves devicetree
  98. {
  99. parser_output = build_dt_info($1, $2, $3,
  100. guess_boot_cpuid($3));
  101. }
  102. ;
  103. header:
  104. DT_V1 ';'
  105. {
  106. $$ = DTSF_V1;
  107. }
  108. | DT_V1 ';' DT_PLUGIN ';'
  109. {
  110. $$ = DTSF_V1 | DTSF_PLUGIN;
  111. }
  112. ;
  113. headers:
  114. header
  115. | header headers
  116. {
  117. if ($2 != $1)
  118. ERROR(&@2, "Header flags don't match earlier ones");
  119. $$ = $1;
  120. }
  121. ;
  122. memreserves:
  123. /* empty */
  124. {
  125. $$ = NULL;
  126. }
  127. | memreserve memreserves
  128. {
  129. $$ = chain_reserve_entry($1, $2);
  130. }
  131. ;
  132. memreserve:
  133. DT_MEMRESERVE integer_prim integer_prim ';'
  134. {
  135. $$ = build_reserve_entry($2, $3);
  136. }
  137. | DT_LABEL memreserve
  138. {
  139. add_label(&$2->labels, $1);
  140. $$ = $2;
  141. }
  142. ;
  143. devicetree:
  144. '/' nodedef
  145. {
  146. $$ = name_node($2, "");
  147. }
  148. | devicetree '/' nodedef
  149. {
  150. $$ = merge_nodes($1, $3);
  151. }
  152. | DT_REF nodedef
  153. {
  154. /*
  155. * We rely on the rule being always:
  156. * versioninfo plugindecl memreserves devicetree
  157. * so $-1 is what we want (plugindecl)
  158. */
  159. if (!($<flags>-1 & DTSF_PLUGIN))
  160. ERROR(&@2, "Label or path %s not found", $1);
  161. $$ = add_orphan_node(name_node(build_node(NULL, NULL), ""), $2, $1);
  162. }
  163. | devicetree DT_LABEL DT_REF nodedef
  164. {
  165. struct node *target = get_node_by_ref($1, $3);
  166. if (target) {
  167. add_label(&target->labels, $2);
  168. merge_nodes(target, $4);
  169. } else
  170. ERROR(&@3, "Label or path %s not found", $3);
  171. $$ = $1;
  172. }
  173. | devicetree DT_REF nodedef
  174. {
  175. struct node *target = get_node_by_ref($1, $2);
  176. if (target) {
  177. merge_nodes(target, $3);
  178. } else {
  179. /*
  180. * We rely on the rule being always:
  181. * versioninfo plugindecl memreserves devicetree
  182. * so $-1 is what we want (plugindecl)
  183. */
  184. if ($<flags>-1 & DTSF_PLUGIN)
  185. add_orphan_node($1, $3, $2);
  186. else
  187. ERROR(&@2, "Label or path %s not found", $2);
  188. }
  189. $$ = $1;
  190. }
  191. | devicetree DT_DEL_NODE DT_REF ';'
  192. {
  193. struct node *target = get_node_by_ref($1, $3);
  194. if (target)
  195. delete_node(target);
  196. else
  197. ERROR(&@3, "Label or path %s not found", $3);
  198. $$ = $1;
  199. }
  200. ;
  201. nodedef:
  202. '{' proplist subnodes '}' ';'
  203. {
  204. $$ = build_node($2, $3);
  205. }
  206. ;
  207. proplist:
  208. /* empty */
  209. {
  210. $$ = NULL;
  211. }
  212. | proplist propdef
  213. {
  214. $$ = chain_property($2, $1);
  215. }
  216. ;
  217. propdef:
  218. DT_PROPNODENAME '=' propdata ';'
  219. {
  220. $$ = build_property($1, $3);
  221. }
  222. | DT_PROPNODENAME ';'
  223. {
  224. $$ = build_property($1, empty_data);
  225. }
  226. | DT_DEL_PROP DT_PROPNODENAME ';'
  227. {
  228. $$ = build_property_delete($2);
  229. }
  230. | DT_LABEL propdef
  231. {
  232. add_label(&$2->labels, $1);
  233. $$ = $2;
  234. }
  235. ;
  236. propdata:
  237. propdataprefix DT_STRING
  238. {
  239. $$ = data_merge($1, $2);
  240. }
  241. | propdataprefix arrayprefix '>'
  242. {
  243. $$ = data_merge($1, $2.data);
  244. }
  245. | propdataprefix '[' bytestring ']'
  246. {
  247. $$ = data_merge($1, $3);
  248. }
  249. | propdataprefix DT_REF
  250. {
  251. $$ = data_add_marker($1, REF_PATH, $2);
  252. }
  253. | propdataprefix DT_INCBIN '(' DT_STRING ',' integer_prim ',' integer_prim ')'
  254. {
  255. FILE *f = srcfile_relative_open($4.val, NULL);
  256. struct data d;
  257. if ($6 != 0)
  258. if (fseek(f, $6, SEEK_SET) != 0)
  259. die("Couldn't seek to offset %llu in \"%s\": %s",
  260. (unsigned long long)$6, $4.val,
  261. strerror(errno));
  262. d = data_copy_file(f, $8);
  263. $$ = data_merge($1, d);
  264. fclose(f);
  265. }
  266. | propdataprefix DT_INCBIN '(' DT_STRING ')'
  267. {
  268. FILE *f = srcfile_relative_open($4.val, NULL);
  269. struct data d = empty_data;
  270. d = data_copy_file(f, -1);
  271. $$ = data_merge($1, d);
  272. fclose(f);
  273. }
  274. | propdata DT_LABEL
  275. {
  276. $$ = data_add_marker($1, LABEL, $2);
  277. }
  278. ;
  279. propdataprefix:
  280. /* empty */
  281. {
  282. $$ = empty_data;
  283. }
  284. | propdata ','
  285. {
  286. $$ = $1;
  287. }
  288. | propdataprefix DT_LABEL
  289. {
  290. $$ = data_add_marker($1, LABEL, $2);
  291. }
  292. ;
  293. arrayprefix:
  294. DT_BITS DT_LITERAL '<'
  295. {
  296. unsigned long long bits;
  297. bits = $2;
  298. if ((bits != 8) && (bits != 16) &&
  299. (bits != 32) && (bits != 64)) {
  300. ERROR(&@2, "Array elements must be"
  301. " 8, 16, 32 or 64-bits");
  302. bits = 32;
  303. }
  304. $$.data = empty_data;
  305. $$.bits = bits;
  306. }
  307. | '<'
  308. {
  309. $$.data = empty_data;
  310. $$.bits = 32;
  311. }
  312. | arrayprefix integer_prim
  313. {
  314. if ($1.bits < 64) {
  315. uint64_t mask = (1ULL << $1.bits) - 1;
  316. /*
  317. * Bits above mask must either be all zero
  318. * (positive within range of mask) or all one
  319. * (negative and sign-extended). The second
  320. * condition is true if when we set all bits
  321. * within the mask to one (i.e. | in the
  322. * mask), all bits are one.
  323. */
  324. if (($2 > mask) && (($2 | mask) != -1ULL))
  325. ERROR(&@2, "Value out of range for"
  326. " %d-bit array element", $1.bits);
  327. }
  328. $$.data = data_append_integer($1.data, $2, $1.bits);
  329. }
  330. | arrayprefix DT_REF
  331. {
  332. uint64_t val = ~0ULL >> (64 - $1.bits);
  333. if ($1.bits == 32)
  334. $1.data = data_add_marker($1.data,
  335. REF_PHANDLE,
  336. $2);
  337. else
  338. ERROR(&@2, "References are only allowed in "
  339. "arrays with 32-bit elements.");
  340. $$.data = data_append_integer($1.data, val, $1.bits);
  341. }
  342. | arrayprefix DT_LABEL
  343. {
  344. $$.data = data_add_marker($1.data, LABEL, $2);
  345. }
  346. ;
  347. integer_prim:
  348. DT_LITERAL
  349. | DT_CHAR_LITERAL
  350. | '(' integer_expr ')'
  351. {
  352. $$ = $2;
  353. }
  354. ;
  355. integer_expr:
  356. integer_trinary
  357. ;
  358. integer_trinary:
  359. integer_or
  360. | integer_or '?' integer_expr ':' integer_trinary { $$ = $1 ? $3 : $5; }
  361. ;
  362. integer_or:
  363. integer_and
  364. | integer_or DT_OR integer_and { $$ = $1 || $3; }
  365. ;
  366. integer_and:
  367. integer_bitor
  368. | integer_and DT_AND integer_bitor { $$ = $1 && $3; }
  369. ;
  370. integer_bitor:
  371. integer_bitxor
  372. | integer_bitor '|' integer_bitxor { $$ = $1 | $3; }
  373. ;
  374. integer_bitxor:
  375. integer_bitand
  376. | integer_bitxor '^' integer_bitand { $$ = $1 ^ $3; }
  377. ;
  378. integer_bitand:
  379. integer_eq
  380. | integer_bitand '&' integer_eq { $$ = $1 & $3; }
  381. ;
  382. integer_eq:
  383. integer_rela
  384. | integer_eq DT_EQ integer_rela { $$ = $1 == $3; }
  385. | integer_eq DT_NE integer_rela { $$ = $1 != $3; }
  386. ;
  387. integer_rela:
  388. integer_shift
  389. | integer_rela '<' integer_shift { $$ = $1 < $3; }
  390. | integer_rela '>' integer_shift { $$ = $1 > $3; }
  391. | integer_rela DT_LE integer_shift { $$ = $1 <= $3; }
  392. | integer_rela DT_GE integer_shift { $$ = $1 >= $3; }
  393. ;
  394. integer_shift:
  395. integer_shift DT_LSHIFT integer_add { $$ = $1 << $3; }
  396. | integer_shift DT_RSHIFT integer_add { $$ = $1 >> $3; }
  397. | integer_add
  398. ;
  399. integer_add:
  400. integer_add '+' integer_mul { $$ = $1 + $3; }
  401. | integer_add '-' integer_mul { $$ = $1 - $3; }
  402. | integer_mul
  403. ;
  404. integer_mul:
  405. integer_mul '*' integer_unary { $$ = $1 * $3; }
  406. | integer_mul '/' integer_unary
  407. {
  408. if ($3 != 0) {
  409. $$ = $1 / $3;
  410. } else {
  411. ERROR(&@$, "Division by zero");
  412. $$ = 0;
  413. }
  414. }
  415. | integer_mul '%' integer_unary
  416. {
  417. if ($3 != 0) {
  418. $$ = $1 % $3;
  419. } else {
  420. ERROR(&@$, "Division by zero");
  421. $$ = 0;
  422. }
  423. }
  424. | integer_unary
  425. ;
  426. integer_unary:
  427. integer_prim
  428. | '-' integer_unary { $$ = -$2; }
  429. | '~' integer_unary { $$ = ~$2; }
  430. | '!' integer_unary { $$ = !$2; }
  431. ;
  432. bytestring:
  433. /* empty */
  434. {
  435. $$ = empty_data;
  436. }
  437. | bytestring DT_BYTE
  438. {
  439. $$ = data_append_byte($1, $2);
  440. }
  441. | bytestring DT_LABEL
  442. {
  443. $$ = data_add_marker($1, LABEL, $2);
  444. }
  445. ;
  446. subnodes:
  447. /* empty */
  448. {
  449. $$ = NULL;
  450. }
  451. | subnode subnodes
  452. {
  453. $$ = chain_node($1, $2);
  454. }
  455. | subnode propdef
  456. {
  457. ERROR(&@2, "Properties must precede subnodes");
  458. YYERROR;
  459. }
  460. ;
  461. subnode:
  462. DT_PROPNODENAME nodedef
  463. {
  464. $$ = name_node($2, $1);
  465. }
  466. | DT_DEL_NODE DT_PROPNODENAME ';'
  467. {
  468. $$ = name_node(build_node_delete(), $2);
  469. }
  470. | DT_LABEL subnode
  471. {
  472. add_label(&$2->labels, $1);
  473. $$ = $2;
  474. }
  475. ;
  476. %%
  477. void yyerror(char const *s)
  478. {
  479. ERROR(&yylloc, "%s", s);
  480. }