gstreamer1.0-plugins-good_1.18.1.bb 3.5 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172
  1. require gstreamer1.0-plugins-common.inc
  2. SRC_URI = "https://gstreamer.freedesktop.org/src/gst-plugins-good/gst-plugins-good-${PV}.tar.xz \
  3. file://0001-qt-include-ext-qt-gstqtgl.h-instead-of-gst-gl-gstglf.patch \
  4. "
  5. SRC_URI[sha256sum] = "e210e91a5590ecb6accc9d06c949a58ca6897d8edb3b3d55828e424c624f626c"
  6. S = "${WORKDIR}/gst-plugins-good-${PV}"
  7. LICENSE = "GPLv2+ & LGPLv2.1+"
  8. LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
  9. file://gst/replaygain/rganalysis.c;beginline=1;endline=23;md5=b60ebefd5b2f5a8e0cab6bfee391a5fe"
  10. DEPENDS += "gstreamer1.0-plugins-base libcap zlib"
  11. RPROVIDES_${PN}-pulseaudio += "${PN}-pulse"
  12. RPROVIDES_${PN}-soup += "${PN}-souphttpsrc"
  13. PACKAGECONFIG ??= " \
  14. ${GSTREAMER_ORC} \
  15. ${@bb.utils.filter('DISTRO_FEATURES', 'pulseaudio x11', d)} \
  16. ${@bb.utils.contains('TUNE_FEATURES', 'm64', 'asm', '', d)} \
  17. bz2 cairo flac gdk-pixbuf gudev jpeg lame libpng mpg123 soup speex taglib v4l2 \
  18. "
  19. X11DEPENDS = "virtual/libx11 libsm libxrender libxfixes libxdamage"
  20. X11ENABLEOPTS = "-Dximagesrc=enabled -Dximagesrc-xshm=enabled -Dximagesrc-xfixes=enabled -Dximagesrc-xdamage=enabled"
  21. X11DISABLEOPTS = "-Dximagesrc=disabled -Dximagesrc-xshm=disabled -Dximagesrc-xfixes=disabled -Dximagesrc-xdamage=disabled"
  22. QT5WAYLANDDEPENDS = "${@bb.utils.contains("DISTRO_FEATURES", "wayland", "qtwayland", "", d)}"
  23. PACKAGECONFIG[asm] = "-Dasm=enabled,-Dasm=disabled,nasm-native"
  24. PACKAGECONFIG[bz2] = "-Dbz2=enabled,-Dbz2=disabled,bzip2"
  25. PACKAGECONFIG[cairo] = "-Dcairo=enabled,-Dcairo=disabled,cairo"
  26. PACKAGECONFIG[dv1394] = "-Ddv1394=enabled,-Ddv1394=disabled,libiec61883 libavc1394 libraw1394"
  27. PACKAGECONFIG[flac] = "-Dflac=enabled,-Dflac=disabled,flac"
  28. PACKAGECONFIG[gdk-pixbuf] = "-Dgdk-pixbuf=enabled,-Dgdk-pixbuf=disabled,gdk-pixbuf"
  29. PACKAGECONFIG[gtk] = "-Dgtk3=enabled,-Dgtk3=disabled,gtk+3"
  30. PACKAGECONFIG[gudev] = "-Dv4l2-gudev=enabled,-Dv4l2-gudev=disabled,libgudev"
  31. PACKAGECONFIG[jack] = "-Djack=enabled,-Djack=disabled,jack"
  32. PACKAGECONFIG[jpeg] = "-Djpeg=enabled,-Djpeg=disabled,jpeg"
  33. PACKAGECONFIG[lame] = "-Dlame=enabled,-Dlame=disabled,lame"
  34. PACKAGECONFIG[libpng] = "-Dpng=enabled,-Dpng=disabled,libpng"
  35. PACKAGECONFIG[libv4l2] = "-Dv4l2-libv4l2=enabled,-Dv4l2-libv4l2=disabled,v4l-utils"
  36. PACKAGECONFIG[mpg123] = "-Dmpg123=enabled,-Dmpg123=disabled,mpg123"
  37. PACKAGECONFIG[pulseaudio] = "-Dpulse=enabled,-Dpulse=disabled,pulseaudio"
  38. PACKAGECONFIG[qt5] = "-Dqt5=enabled,-Dqt5=disabled,qtbase qtdeclarative qtbase-native ${QT5WAYLANDDEPENDS}"
  39. PACKAGECONFIG[soup] = "-Dsoup=enabled,-Dsoup=disabled,libsoup-2.4"
  40. PACKAGECONFIG[speex] = "-Dspeex=enabled,-Dspeex=disabled,speex"
  41. PACKAGECONFIG[taglib] = "-Dtaglib=enabled,-Dtaglib=disabled,taglib"
  42. PACKAGECONFIG[v4l2] = "-Dv4l2=enabled -Dv4l2-probe=true,-Dv4l2=disabled -Dv4l2-probe=false"
  43. PACKAGECONFIG[vpx] = "-Dvpx=enabled,-Dvpx=disabled,libvpx"
  44. PACKAGECONFIG[wavpack] = "-Dwavpack=enabled,-Dwavpack=disabled,wavpack"
  45. PACKAGECONFIG[x11] = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}"
  46. EXTRA_OEMESON += " \
  47. -Ddoc=disabled \
  48. -Daalib=disabled \
  49. -Ddirectsound=disabled \
  50. -Ddv=disabled \
  51. -Dlibcaca=disabled \
  52. -Doss=enabled \
  53. -Doss4=disabled \
  54. -Dosxaudio=disabled \
  55. -Dosxvideo=disabled \
  56. -Drpicamsrc=disabled \
  57. -Dshout2=disabled \
  58. -Dtwolame=disabled \
  59. -Dwaveform=disabled \
  60. "
  61. FILES_${PN}-equalizer += "${datadir}/gstreamer-1.0/presets/*.prs"