linux-yocto-dev.bb 2.5 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354
  1. # This recipe tracks the linux-yocto-dev repository as its upstream source.
  2. # Since this tree is frequently updated, and periodically rebuilt, AUTOREV is
  3. # used to track its contents.
  4. #
  5. # This recipe is just like other linux-yocto variants, with the only difference
  6. # being that to avoid network access during initial parsing, static SRCREVs are
  7. # provided and overridden if the preferred kernel provider is linux-yocto-dev.
  8. #
  9. # To enable this recipe, set PREFERRED_PROVIDER_virtual/kernel = "linux-yocto-dev"
  10. inherit kernel
  11. require recipes-kernel/linux/linux-yocto.inc
  12. # for ncurses tests
  13. inherit pkgconfig
  14. # provide this .inc to set specific revisions
  15. include recipes-kernel/linux/linux-yocto-dev-revisions.inc
  16. KBRANCH = "standard/base"
  17. KMETA = "kernel-meta"
  18. SRC_URI = "git://git.yoctoproject.org/linux-yocto-dev.git;branch=${KBRANCH};name=machine \
  19. git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=master;destsuffix=${KMETA}"
  20. # Set default SRCREVs. Both the machine and meta SRCREVs are statically set
  21. # to the korg v3.7 tag, and hence prevent network access during parsing. If
  22. # linux-yocto-dev is the preferred provider, they will be overridden to
  23. # AUTOREV in following anonymous python routine and resolved when the
  24. # variables are finalized.
  25. SRCREV_machine ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
  26. SRCREV_meta ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
  27. LINUX_VERSION ?= "5.9-rc+"
  28. LINUX_VERSION_EXTENSION ?= "-yoctodev-${LINUX_KERNEL_TYPE}"
  29. PV = "${LINUX_VERSION}+git${SRCPV}"
  30. LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
  31. DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
  32. DEPENDS += "openssl-native util-linux-native"
  33. COMPATIBLE_MACHINE = "(qemuarm|qemux86|qemuppc|qemumips|qemumips64|qemux86-64|qemuriscv64)"
  34. KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
  35. # Functionality flags
  36. KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
  37. KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
  38. KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
  39. KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
  40. KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
  41. KERNEL_FEATURES_append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
  42. KERNEL_VERSION_SANITY_SKIP = "1"