glew_2.2.0.bb 1.8 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344
  1. SUMMARY = "OpenGL extension loading library"
  2. DESCRIPTION = "The OpenGL Extension Wrangler Library (GLEW) is a cross-platform open-source C/C++ extension loading library."
  3. HOMEPAGE = "http://glew.sourceforge.net/"
  4. BUGTRACKER = "http://sourceforge.net/tracker/?group_id=67586"
  5. LICENSE = "MIT"
  6. LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=2ac251558de685c6b9478d89be3149c2"
  7. SRC_URI = "${SOURCEFORGE_MIRROR}/project/glew/glew/${PV}/glew-${PV}.tgz \
  8. file://no-strip.patch"
  9. SRC_URI[md5sum] = "3579164bccaef09e36c0af7f4fd5c7c7"
  10. SRC_URI[sha256sum] = "d4fc82893cfb00109578d0a1a2337fb8ca335b3ceccf97b97e5cc7f08e4353e1"
  11. UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/glew/files/glew"
  12. UPSTREAM_CHECK_REGEX = "/glew/(?P<pver>(\d+[\.\-_]*)+)/"
  13. inherit lib_package pkgconfig features_check
  14. REQUIRED_DISTRO_FEATURES = "opengl"
  15. PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'opengl', 'egl-gles2', d)}"
  16. # The opengl and egl-XXX options are exclusive, enable only one.
  17. PACKAGECONFIG[opengl] = "SYSTEM='linux',,virtual/libx11 virtual/libgl libglu libxext libxi libxmu,,,egl-gles2"
  18. PACKAGECONFIG[egl-gles2] = "SYSTEM='linux-egl' GLEW_NO_GLU='-DGLEW_NO_GLU' LDFLAGS.GL='-lEGL -lGLESv2',,virtual/egl virtual/libgles2,,,opengl"
  19. CFLAGS += "-D_GNU_SOURCE"
  20. # Override SYSTEM (via PACKAGECONFIG_CONFARGS) to avoid calling config.guess,
  21. # we're cross-compiling. Pass our CFLAGS via POPT as that's the optimisation
  22. # variable and safely overwritten.
  23. EXTRA_OEMAKE = "${PACKAGECONFIG_CONFARGS} \
  24. CC='${CC}' LD='${CC}' STRIP='' \
  25. LDFLAGS.EXTRA='${LDFLAGS}' \
  26. POPT='${CFLAGS}' \
  27. GLEW_PREFIX='${prefix}' BINDIR='${bindir}' \
  28. LIBDIR='${libdir}' INCDIR='${includedir}/GL' PKGDIR='${libdir}/pkgconfig'"
  29. do_compile() {
  30. oe_runmake
  31. }
  32. do_install() {
  33. oe_runmake 'DESTDIR=${D}' install.all
  34. }