gdk-pixbuf_2.40.0.bb 5.0 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132
  1. SUMMARY = "Image loading library for GTK+"
  2. DESCRIPTION = "The GDK Pixbuf library provides: Image loading and saving \
  3. facilities, fast scaling and compositing of pixbufs and Simple animation \
  4. loading (ie. animated GIFs)"
  5. HOMEPAGE = "https://wiki.gnome.org/Projects/GdkPixbuf"
  6. BUGTRACKER = "https://gitlab.gnome.org/GNOME/gdk-pixbuf/issues"
  7. LICENSE = "LGPLv2.1+"
  8. LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
  9. file://gdk-pixbuf/gdk-pixbuf.h;endline=26;md5=72b39da7cbdde2e665329fef618e1d6b \
  10. "
  11. SECTION = "libs"
  12. DEPENDS = "glib-2.0 gdk-pixbuf-native shared-mime-info"
  13. MAJ_VER = "${@oe.utils.trim_version("${PV}", 2)}"
  14. SRC_URI = "${GNOME_MIRROR}/${BPN}/${MAJ_VER}/${BPN}-${PV}.tar.xz \
  15. file://run-ptest \
  16. file://fatal-loader.patch \
  17. file://0001-Work-around-thumbnailer-cross-compile-failure.patch \
  18. file://0001-Fix-a-couple-of-decisions-around-cross-compilation.patch \
  19. file://0004-Do-not-run-tests-when-building.patch \
  20. file://0006-Build-thumbnailer-and-tests-also-in-cross-builds.patch \
  21. file://missing-test-data.patch \
  22. "
  23. SRC_URI_append_class-target = " \
  24. file://0003-target-only-Work-around-thumbnailer-cross-compile-fa.patch \
  25. "
  26. SRC_URI_append_class-nativesdk = " \
  27. file://0003-target-only-Work-around-thumbnailer-cross-compile-fa.patch \
  28. "
  29. SRC_URI[md5sum] = "05eb1ebc258ba905f1c8644ef49de064"
  30. SRC_URI[sha256sum] = "1582595099537ca8ff3b99c6804350b4c058bb8ad67411bbaae024ee7cead4e6"
  31. inherit meson pkgconfig gettext pixbufcache ptest-gnome upstream-version-is-even gobject-introspection gtk-doc lib_package
  32. GIR_MESON_OPTION = 'gir'
  33. LIBV = "2.10.0"
  34. GDK_PIXBUF_LOADERS ?= "png jpeg"
  35. PACKAGECONFIG = "${GDK_PIXBUF_LOADERS} \
  36. ${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)} \
  37. ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
  38. PACKAGECONFIG_class-native = "${GDK_PIXBUF_LOADERS}"
  39. PACKAGECONFIG[png] = "-Dpng=true,-Dpng=false,libpng"
  40. PACKAGECONFIG[jpeg] = "-Djpeg=true,-Djpeg=false,jpeg"
  41. PACKAGECONFIG[tiff] = "-Dtiff=true,-Dtiff=false,tiff"
  42. PACKAGECONFIG[jpeg2000] = "-Djasper=true,-Djasper=false,jasper"
  43. PACKAGECONFIG[tests] = "-Dinstalled_tests=true,-Dinstalled_tests=false"
  44. PACKAGECONFIG[x11] = "-Dx11=true,-Dx11=false,virtual/libx11"
  45. PACKAGES =+ "${PN}-xlib"
  46. # For GIO image type sniffing
  47. RDEPENDS_${PN} = "shared-mime-info"
  48. FILES_${PN}-xlib = "${libdir}/*pixbuf_xlib*${SOLIBS}"
  49. ALLOW_EMPTY_${PN}-xlib = "1"
  50. FILES_${PN} += "${libdir}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders"
  51. FILES_${PN}-bin += "${datadir}/thumbnailers/gdk-pixbuf-thumbnailer.thumbnailer"
  52. FILES_${PN}-dev += " \
  53. ${bindir}/gdk-pixbuf-csource \
  54. ${bindir}/gdk-pixbuf-pixdata \
  55. ${bindir}/gdk-pixbuf-print-mime-types \
  56. ${includedir}/* \
  57. ${libdir}/gdk-pixbuf-2.0/${LIBV}/loaders/*.la \
  58. "
  59. PACKAGES_DYNAMIC += "^gdk-pixbuf-loader-.*"
  60. PACKAGES_DYNAMIC_class-native = ""
  61. python populate_packages_prepend () {
  62. postinst_pixbufloader = d.getVar("postinst_pixbufloader")
  63. loaders_root = d.expand('${libdir}/gdk-pixbuf-2.0/${LIBV}/loaders')
  64. packages = ' '.join(do_split_packages(d, loaders_root, r'^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s'))
  65. d.setVar('PIXBUF_PACKAGES', packages)
  66. # The test suite exercises all the loaders, so ensure they are all
  67. # dependencies of the ptest package.
  68. d.appendVar("RDEPENDS_%s-ptest" % d.getVar('PN'), " " + packages)
  69. }
  70. do_install_append() {
  71. # Copy gdk-pixbuf-query-loaders into libdir so it is always available
  72. # in multilib builds.
  73. cp ${D}/${bindir}/gdk-pixbuf-query-loaders ${D}/${libdir}/gdk-pixbuf-2.0/
  74. }
  75. # Remove a bad fuzzing attempt that sporadically fails without a way to reproduce
  76. do_install_ptest() {
  77. rm ${D}/${datadir}/installed-tests/gdk-pixbuf/pixbuf-randomly-modified.test
  78. }
  79. do_install_append_class-native() {
  80. find ${D}${libdir} -name "libpixbufloader-*.la" -exec rm \{\} \;
  81. create_wrapper ${D}/${bindir}/gdk-pixbuf-csource \
  82. XDG_DATA_DIRS=${STAGING_DATADIR} \
  83. GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache
  84. create_wrapper ${D}/${bindir}/gdk-pixbuf-pixdata \
  85. XDG_DATA_DIRS=${STAGING_DATADIR} \
  86. GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache
  87. create_wrapper ${D}/${bindir}/gdk-pixbuf-print-mime-types \
  88. XDG_DATA_DIRS=${STAGING_DATADIR} \
  89. GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache
  90. create_wrapper ${D}/${libdir}/gdk-pixbuf-2.0/gdk-pixbuf-query-loaders \
  91. XDG_DATA_DIRS=${STAGING_DATADIR} \
  92. GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache \
  93. GDK_PIXBUF_MODULEDIR=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders
  94. create_wrapper ${D}/${bindir}/gdk-pixbuf-query-loaders \
  95. XDG_DATA_DIRS=${STAGING_DATADIR} \
  96. GDK_PIXBUF_MODULE_FILE=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders.cache \
  97. GDK_PIXBUF_MODULEDIR=${STAGING_LIBDIR_NATIVE}/gdk-pixbuf-2.0/${LIBV}/loaders
  98. }
  99. BBCLASSEXTEND = "native nativesdk"