strace_5.9.bb 2.0 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556
  1. SUMMARY = "System call tracing tool"
  2. HOMEPAGE = "http://strace.io"
  3. SECTION = "console/utils"
  4. LICENSE = "LGPL-2.1+ & GPL-2+"
  5. LIC_FILES_CHKSUM = "file://COPYING;md5=c756d9d5dabc27663df64f0bf492166c"
  6. SRC_URI = "https://strace.io/files/${PV}/strace-${PV}.tar.xz \
  7. file://disable-git-version-gen.patch \
  8. file://update-gawk-paths.patch \
  9. file://Makefile-ptest.patch \
  10. file://run-ptest \
  11. file://mips-SIGEMT.patch \
  12. file://0001-caps-abbrev.awk-fix-gawk-s-path.patch \
  13. file://ptest-spacesave.patch \
  14. file://uintptr_t.patch \
  15. file://0001-strace-fix-reproducibilty-issues.patch \
  16. file://0001-xlat-Mark-IPPROTO_MAX-last-in-IPPROTO_-constants.patch \
  17. "
  18. SRC_URI[sha256sum] = "39473eb8465546c3e940fb663cb381eba5613160c7302794699d194a4d5d66d9"
  19. inherit autotools ptest
  20. PACKAGECONFIG_class-target ??= "\
  21. ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \
  22. "
  23. PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
  24. PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
  25. EXTRA_OECONF += "--enable-mpers=no --disable-gcc-Werror"
  26. CFLAGS_append_libc-musl = " -Dsigcontext_struct=sigcontext"
  27. TESTDIR = "tests"
  28. PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
  29. do_install_append() {
  30. # We don't ship strace-graph here because it needs perl
  31. rm ${D}${bindir}/strace-graph
  32. }
  33. do_compile_ptest() {
  34. oe_runmake -C ${TESTDIR} buildtest-TESTS
  35. }
  36. do_install_ptest() {
  37. oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
  38. install -m 755 ${S}/test-driver ${D}${PTEST_PATH}
  39. install -m 644 ${B}/config.h ${D}${PTEST_PATH}
  40. sed -i -e '/^src/s/strace.*[1-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
  41. }
  42. RDEPENDS_${PN}-ptest += "make coreutils grep gawk sed"
  43. BBCLASSEXTEND = "native"
  44. TOOLCHAIN = "gcc"