1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374 |
- SUMMARY = "Open Package Manager"
- SUMMARY_libopkg = "Open Package Manager library"
- SECTION = "base"
- HOMEPAGE = "http://code.google.com/p/opkg/"
- BUGTRACKER = "http://code.google.com/p/opkg/issues/list"
- LICENSE = "GPLv2+"
- LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
- file://src/opkg.c;beginline=4;endline=18;md5=d6200b0f2b41dee278aa5fad333eecae"
- DEPENDS = "libarchive"
- PE = "1"
- SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz \
- file://opkg.conf \
- file://0001-opkg_conf-create-opkg.lock-in-run-instead-of-var-run.patch \
- file://run-ptest \
- "
- SRC_URI[md5sum] = "86ec5eee9362aca0990994a402e077e9"
- SRC_URI[sha256sum] = "dda452854bc0cd1334f7ba18a66003d1c12a98600c894111b56919b1ea434718"
- # This needs to be before ptest inherit, otherwise all ptest files end packaged
- # in libopkg package if OPKGLIBDIR == libdir, because default
- # PTEST_PATH ?= "${libdir}/${BPN}/ptest"
- PACKAGES =+ "libopkg"
- inherit autotools pkgconfig ptest
- target_localstatedir := "${localstatedir}"
- OPKGLIBDIR ??= "${target_localstatedir}/lib"
- PACKAGECONFIG ??= "libsolv"
- PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,\
- gnupg gpgme libgpg-error,\
- ${@ "gnupg" if ("native" in d.getVar("PN")) else "gnupg-gpg"}\
- "
- PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
- PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
- PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
- PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
- PACKAGECONFIG[libsolv] = "--with-libsolv,--without-libsolv,libsolv"
- EXTRA_OECONF += " --disable-pathfinder"
- EXTRA_OECONF_class-native = "--localstatedir=/${@os.path.relpath('${localstatedir}', '${STAGING_DIR_NATIVE}')} --sysconfdir=/${@os.path.relpath('${sysconfdir}', '${STAGING_DIR_NATIVE}')}"
- do_install_append () {
- install -d ${D}${sysconfdir}/opkg
- install -m 0644 ${WORKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf
- echo "option lists_dir ${OPKGLIBDIR}/opkg/lists" >>${D}${sysconfdir}/opkg/opkg.conf
- # We need to create the lock directory
- install -d ${D}${OPKGLIBDIR}/opkg
- }
- do_install_ptest () {
- sed -i -e '/@echo $^/d' ${D}${PTEST_PATH}/tests/Makefile
- sed -i -e '/@PYTHONPATH=. $(PYTHON) $^/a\\t@if [ "$$?" != "0" ];then echo "FAIL:"$^;else echo "PASS:"$^;fi' ${D}${PTEST_PATH}/tests/Makefile
- }
- RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config libarchive"
- RDEPENDS_${PN}_class-native = ""
- RDEPENDS_${PN}_class-nativesdk = ""
- RDEPENDS_${PN}-ptest += "make binutils python3-core python3-compression"
- RREPLACES_${PN} = "opkg-nogpg opkg-collateral"
- RCONFLICTS_${PN} = "opkg-collateral"
- RPROVIDES_${PN} = "opkg-collateral"
- FILES_libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
- BBCLASSEXTEND = "native nativesdk"
- CONFFILES_${PN} = "${sysconfdir}/opkg/opkg.conf"
|