git.inc 4.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137
  1. SUMMARY = "Distributed version control system"
  2. HOMEPAGE = "http://git-scm.com"
  3. SECTION = "console/utils"
  4. LICENSE = "GPLv2"
  5. DEPENDS = "openssl curl zlib expat"
  6. PROVIDES_append_class-native = " git-replacement-native"
  7. SRC_URI = "${KERNELORG_MIRROR}/software/scm/git/git-${PV}.tar.gz;name=tarball \
  8. ${KERNELORG_MIRROR}/software/scm/git/git-manpages-${PV}.tar.gz;name=manpages"
  9. S = "${WORKDIR}/git-${PV}"
  10. LIC_FILES_CHKSUM = "file://COPYING;md5=7c0d7ef03a7eb04ce795b0f60e68e7e1"
  11. CVE_PRODUCT = "git-scm:git"
  12. PACKAGECONFIG ??= ""
  13. PACKAGECONFIG[cvsserver] = ""
  14. PACKAGECONFIG[svn] = ""
  15. EXTRA_OECONF = "--with-perl=${STAGING_BINDIR_NATIVE}/perl-native/perl \
  16. --without-tcltk \
  17. --without-iconv \
  18. "
  19. EXTRA_OECONF_append_class-nativesdk = " --with-gitconfig=/etc/gitconfig "
  20. # Needs brokensep as this doesn't use automake
  21. inherit autotools-brokensep perlnative bash-completion
  22. EXTRA_OEMAKE = "NO_PYTHON=1 CFLAGS='${CFLAGS}' LDFLAGS='${LDFLAGS}'"
  23. EXTRA_OEMAKE += "'PERL_PATH=/usr/bin/env perl'"
  24. EXTRA_OEMAKE_append_class-native = " NO_CROSS_DIRECTORY_HARDLINKS=1"
  25. do_compile_prepend () {
  26. # Remove perl/perl.mak to fix the out-of-date perl.mak error
  27. # during rebuild
  28. rm -f perl/perl.mak
  29. }
  30. do_install () {
  31. oe_runmake install DESTDIR="${D}" bindir=${bindir} \
  32. template_dir=${datadir}/git-core/templates
  33. for section in man1 man5 man7; do
  34. install -d ${D}/${mandir}/$section
  35. install -t ${D}/${mandir}/$section ${WORKDIR}/$section/*
  36. done
  37. install -d ${D}/${datadir}/bash-completion/completions/
  38. install -m 644 ${S}/contrib/completion/git-completion.bash ${D}/${datadir}/bash-completion/completions/git
  39. }
  40. perl_native_fixup () {
  41. sed -i -e 's#${STAGING_BINDIR_NATIVE}/perl-native/#${bindir}/#' \
  42. -e 's#${libdir}/perl-native/#${libdir}/#' \
  43. ${@d.getVar("PERLTOOLS").replace(' /',d.getVar('D') + '/')}
  44. if [ ! "${@bb.utils.filter('PACKAGECONFIG', 'cvsserver', d)}" ]; then
  45. # Only install the git cvsserver command if explicitly requested
  46. # as it requires the DBI Perl module, which does not exist in
  47. # OE-Core.
  48. rm ${D}${libexecdir}/git-core/git-cvsserver \
  49. ${D}${bindir}/git-cvsserver
  50. fi
  51. if [ ! "${@bb.utils.filter('PACKAGECONFIG', 'svn', d)}" ]; then
  52. # Only install the git svn command and all Git::SVN Perl modules
  53. # if explicitly requested as they require the SVN::Core Perl
  54. # module, which does not exist in OE-Core.
  55. rm -r ${D}${libexecdir}/git-core/git-svn \
  56. ${D}${datadir}/perl5/Git/SVN*
  57. fi
  58. }
  59. REL_GIT_EXEC_PATH = "${@os.path.relpath(libexecdir, bindir)}/git-core"
  60. REL_GIT_TEMPLATE_DIR = "${@os.path.relpath(datadir, bindir)}/git-core/templates"
  61. do_install_append_class-target () {
  62. perl_native_fixup
  63. }
  64. do_install_append_class-native() {
  65. create_wrapper ${D}${bindir}/git \
  66. GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \
  67. GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR}
  68. }
  69. do_install_append_class-nativesdk() {
  70. create_wrapper ${D}${bindir}/git \
  71. GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \
  72. GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR}
  73. perl_native_fixup
  74. }
  75. FILES_${PN} += "${datadir}/git-core ${libexecdir}/git-core/"
  76. PERLTOOLS = " \
  77. ${bindir}/git-cvsserver \
  78. ${libexecdir}/git-core/git-add--interactive \
  79. ${libexecdir}/git-core/git-archimport \
  80. ${libexecdir}/git-core/git-cvsexportcommit \
  81. ${libexecdir}/git-core/git-cvsimport \
  82. ${libexecdir}/git-core/git-cvsserver \
  83. ${libexecdir}/git-core/git-send-email \
  84. ${libexecdir}/git-core/git-svn \
  85. ${libexecdir}/git-core/git-instaweb \
  86. ${datadir}/gitweb/gitweb.cgi \
  87. ${datadir}/git-core/templates/hooks/prepare-commit-msg.sample \
  88. ${datadir}/git-core/templates/hooks/pre-rebase.sample \
  89. ${datadir}/git-core/templates/hooks/fsmonitor-watchman.sample \
  90. "
  91. # Git tools requiring perl
  92. PACKAGES =+ "${PN}-perltools"
  93. FILES_${PN}-perltools += " \
  94. ${PERLTOOLS} \
  95. ${libdir}/perl \
  96. ${datadir}/perl5 \
  97. "
  98. RDEPENDS_${PN}-perltools = "${PN} perl perl-module-file-path findutils"
  99. # git-tk package with gitk and git-gui
  100. PACKAGES =+ "${PN}-tk"
  101. #RDEPENDS_${PN}-tk = "${PN} tk tcl"
  102. #EXTRA_OEMAKE = "TCL_PATH=${STAGING_BINDIR_CROSS}/tclsh"
  103. FILES_${PN}-tk = " \
  104. ${bindir}/gitk \
  105. ${datadir}/gitk \
  106. "
  107. PACKAGES =+ "gitweb"
  108. FILES_gitweb = "${datadir}/gitweb/"
  109. RDEPENDS_gitweb = "perl"
  110. BBCLASSEXTEND = "native nativesdk"