libcgroup_0.41.bb 1.9 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546
  1. SUMMARY = "Linux control group abstraction library"
  2. HOMEPAGE = "http://libcg.sourceforge.net/"
  3. DESCRIPTION = "libcgroup is a library that abstracts the control group file system \
  4. in Linux. Control groups allow you to limit, account and isolate resource usage \
  5. (CPU, memory, disk I/O, etc.) of groups of processes."
  6. SECTION = "libs"
  7. LICENSE = "LGPLv2.1"
  8. LIC_FILES_CHKSUM = "file://COPYING;md5=2d5025d4aa3495befef8f17206a5b0a1"
  9. inherit autotools pkgconfig
  10. DEPENDS = "bison-native flex-native"
  11. SRC_URI = "${SOURCEFORGE_MIRROR}/project/libcg/${BPN}/v0.41/${BPN}-${PV}.tar.bz2 \
  12. file://CVE-2018-14348.patch"
  13. SRC_URI_append_libc-musl = " file://musl-decls-compat.patch"
  14. SRC_URI[md5sum] = "3dea9d50b8a5b73ff0bf1cdcb210f63f"
  15. SRC_URI[sha256sum] = "e4e38bdc7ef70645ce33740ddcca051248d56b53283c0dc6d404e17706f6fb51"
  16. UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/libcg/files/libcgroup/"
  17. DEPENDS_append_libc-musl = " fts "
  18. EXTRA_OEMAKE_append_libc-musl = " LIBS=-lfts"
  19. PACKAGECONFIG = "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}"
  20. PACKAGECONFIG[pam] = "--enable-pam-module-dir=${base_libdir}/security --enable-pam=yes,--enable-pam=no,libpam"
  21. PACKAGES =+ "cgroups-pam-plugin"
  22. FILES_cgroups-pam-plugin = "${base_libdir}/security/pam_cgroup.so*"
  23. FILES_${PN}-dev += "${base_libdir}/security/*.la"
  24. do_install_append() {
  25. # Moving libcgroup to base_libdir
  26. if [ ! ${D}${libdir} -ef ${D}${base_libdir} ]; then
  27. mkdir -p ${D}/${base_libdir}/
  28. mv -f ${D}${libdir}/libcgroup.so.* ${D}${base_libdir}/
  29. rm -f ${D}${libdir}/libcgroup.so
  30. lnr ${D}${base_libdir}/libcgroup.so.1 ${D}${libdir}/libcgroup.so
  31. fi
  32. # pam modules in ${base_libdir}/security/ should be binary .so files, not symlinks.
  33. if [ -f ${D}${base_libdir}/security/pam_cgroup.so.0.0.0 ]; then
  34. mv -f ${D}${base_libdir}/security/pam_cgroup.so.0.0.0 ${D}${base_libdir}/security/pam_cgroup.so
  35. rm -f ${D}${base_libdir}/security/pam_cgroup.so.*
  36. fi
  37. }