keymaps_1.0.bb 1.4 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950
  1. SUMMARY = "Keyboard maps"
  2. DESCRIPTION = "Keymaps and initscript to set the keymap on bootup."
  3. SECTION = "base"
  4. RDEPENDS_${PN} = "kbd"
  5. LICENSE = "GPLv2"
  6. LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
  7. PACKAGE_ARCH = "${MACHINE_ARCH}"
  8. PR = "r31"
  9. INHIBIT_DEFAULT_DEPS = "1"
  10. # As the recipe doesn't inherit systemd.bbclass, we need to set this variable
  11. # manually to avoid unnecessary postinst/preinst generated.
  12. python __anonymous() {
  13. if not bb.utils.contains('DISTRO_FEATURES', 'sysvinit', True, False, d):
  14. d.setVar("INHIBIT_UPDATERCD_BBCLASS", "1")
  15. }
  16. inherit update-rc.d
  17. SRC_URI = "file://keymap.sh \
  18. file://GPLv2.patch"
  19. INITSCRIPT_NAME = "keymap.sh"
  20. INITSCRIPT_PARAMS = "start 01 S ."
  21. S = "${WORKDIR}"
  22. do_install () {
  23. # Only install the script if 'sysvinit' is in DISTRO_FEATURES
  24. # THe ulitity this script provides could be achieved by systemd-vconsole-setup.service
  25. if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','true','false',d)}; then
  26. install -d ${D}${sysconfdir}/init.d/
  27. install -m 0755 ${WORKDIR}/keymap.sh ${D}${sysconfdir}/init.d/
  28. fi
  29. }
  30. PACKAGE_WRITE_DEPS_append = " ${@bb.utils.contains('DISTRO_FEATURES','systemd sysvinit','systemd-systemctl-native','',d)}"
  31. pkg_postinst_${PN} () {
  32. if ${@bb.utils.contains('DISTRO_FEATURES','systemd sysvinit','true','false',d)}; then
  33. if [ -n "$D" ]; then
  34. OPTS="--root=$D"
  35. fi
  36. systemctl $OPTS mask keymap.service
  37. fi
  38. }
  39. ALLOW_EMPTY_${PN} = "1"