bitbake.conf 36 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908
  1. ##################################################################
  2. # Standard target filesystem paths.
  3. ##################################################################
  4. #
  5. # If changing these values, beware that native/cross/nativesdk bbclass
  6. # files may also need changes to keep in sync.
  7. #
  8. # Used by multilib code to change the library paths
  9. baselib = "${BASELIB}"
  10. baselib[vardepvalue] = "${baselib}"
  11. BASELIB = "lib"
  12. BASELIB_powerpc64 = "lib64"
  13. BASELIB_powerpc64le = "lib64"
  14. # Path prefixes
  15. export base_prefix = ""
  16. export prefix = "/usr"
  17. export exec_prefix = "${prefix}"
  18. root_prefix = "${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '${exec_prefix}', '${base_prefix}', d)}"
  19. # Base paths
  20. export base_bindir = "${root_prefix}/bin"
  21. export base_sbindir = "${root_prefix}/sbin"
  22. export base_libdir = "${root_prefix}/${baselib}"
  23. export nonarch_base_libdir = "${root_prefix}/lib"
  24. # Architecture independent paths
  25. export sysconfdir = "${base_prefix}/etc"
  26. export servicedir = "${base_prefix}/srv"
  27. export sharedstatedir = "${base_prefix}/com"
  28. export localstatedir = "${base_prefix}/var"
  29. export datadir = "${prefix}/share"
  30. export infodir = "${datadir}/info"
  31. export mandir = "${datadir}/man"
  32. export docdir = "${datadir}/doc"
  33. export systemd_unitdir = "${nonarch_base_libdir}/systemd"
  34. export systemd_system_unitdir = "${nonarch_base_libdir}/systemd/system"
  35. export nonarch_libdir = "${exec_prefix}/lib"
  36. export systemd_user_unitdir = "${nonarch_libdir}/systemd/user"
  37. # Architecture dependent paths
  38. export bindir = "${exec_prefix}/bin"
  39. export sbindir = "${exec_prefix}/sbin"
  40. export libdir = "${exec_prefix}/${baselib}"
  41. export libexecdir = "${exec_prefix}/libexec"
  42. export includedir = "${exec_prefix}/include"
  43. export oldincludedir = "${exec_prefix}/include"
  44. localedir = "${libdir}/locale"
  45. # Linkage between native/cross/nativesdk layouts
  46. base_bindir_native = "/bin"
  47. base_sbindir_native = "/sbin"
  48. sysconfdir_native = "/etc"
  49. prefix_native = "/usr"
  50. bindir_native = "${prefix_native}/bin"
  51. sbindir_native = "${prefix_native}/sbin"
  52. includedir_native = "${prefix_native}/include"
  53. libdir_native = "${prefix_native}/lib"
  54. libexecdir_native = "${prefix_native}/libexec"
  55. base_libdir_native = "/lib"
  56. datadir_native = "${prefix_native}/share"
  57. bindir_cross = "/bin"
  58. bindir_crossscripts = "${bindir}/crossscripts"
  59. prefix_nativesdk = "/usr"
  60. bindir_nativesdk = "${prefix_nativesdk}/bin"
  61. sbindir_nativesdk = "${prefix_nativesdk}/sbin"
  62. base_bindir_nativesdk = "/bin"
  63. base_sbindir_nativesdk = "/sbin"
  64. includedir_nativesdk = "${prefix_nativesdk}/include"
  65. libdir_nativesdk = "${prefix_nativesdk}/lib"
  66. base_libdir_nativesdk = "/lib"
  67. localstatedir_nativesdk = "/var"
  68. #
  69. # Cross recipes need to know about the target layout
  70. # := is used carefully here
  71. #
  72. target_datadir := "${datadir}"
  73. # Used to find env/perl/python
  74. USRBINPATH = "${bindir}"
  75. USRBINPATH_class-native = "/usr/bin"
  76. USRBINPATH_class-nativesdk = "/usr/bin"
  77. # Root home directory
  78. ROOT_HOME ??= "/home/root"
  79. # If set to boolean true ('yes', 'y', 'true', 't', '1'), /var/log links to /var/volatile/log.
  80. # If set to boolean false ('no', 'n', 'false', 'f', '0'), /var/log is on persistent storage.
  81. VOLATILE_LOG_DIR ?= "yes"
  82. ##################################################################
  83. # Architecture-dependent build variables.
  84. ##################################################################
  85. # Immediate expansion since there is no point in repeatedly calling
  86. # os.uname() throughout parsing
  87. BUILD_ARCH := "${@os.uname()[4]}"
  88. BUILD_OS := "${@os.uname()[0].lower()}"
  89. BUILD_VENDOR = ""
  90. BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  91. BUILD_PREFIX = ""
  92. BUILD_CC_ARCH = ""
  93. BUILD_LD_ARCH = ""
  94. BUILD_AS_ARCH = ""
  95. BUILD_EXEEXT = ""
  96. HOST_ARCH = "${TARGET_ARCH}"
  97. HOST_OS = "${TARGET_OS}"
  98. HOST_VENDOR = "${TARGET_VENDOR}"
  99. HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
  100. HOST_PREFIX = "${TARGET_PREFIX}"
  101. HOST_CC_ARCH = "${TARGET_CC_ARCH}"
  102. HOST_LD_ARCH = "${TARGET_LD_ARCH}"
  103. HOST_AS_ARCH = "${TARGET_AS_ARCH}"
  104. HOST_EXEEXT = ""
  105. TUNE_ARCH ??= "INVALID"
  106. TUNE_CCARGS ??= ""
  107. TUNE_CCARGS[vardepvalue] = "${TUNE_CCARGS}"
  108. TUNE_LDARGS ??= ""
  109. TUNE_ASARGS ??= ""
  110. TUNE_FEATURES ??= "${TUNE_FEATURES_tune-${DEFAULTTUNE}}"
  111. LIBCEXTENSION ??= ""
  112. ABIEXTENSION ??= ""
  113. USE_NLS ??= "yes"
  114. SDKUSE_NLS ??= "yes"
  115. TARGET_ARCH = "${TUNE_ARCH}"
  116. TARGET_OS = "linux${LIBCEXTENSION}${ABIEXTENSION}"
  117. TARGET_VENDOR = "-oe"
  118. TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  119. TARGET_PREFIX = "${TARGET_SYS}-"
  120. TARGET_CC_ARCH = "${TUNE_CCARGS}"
  121. TARGET_LD_ARCH = "${TUNE_LDARGS}"
  122. TARGET_AS_ARCH = "${TUNE_ASARGS}"
  123. SDKMACHINE ??= "x86_64"
  124. SDK_OS = "${BUILD_OS}"
  125. SDK_VENDOR = "-oesdk"
  126. SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}-${SDK_OS}"
  127. SDK_PREFIX = "${SDK_SYS}-"
  128. SDK_CC_ARCH = "${BUILD_CC_ARCH}"
  129. SDKPKGSUFFIX = "nativesdk"
  130. SDK_PACKAGE_ARCHS = "all any noarch ${SDK_ARCH}-${SDKPKGSUFFIX}"
  131. SDK_LD_ARCH = "${BUILD_LD_ARCH}"
  132. SDK_AS_ARCH = "${BUILD_AS_ARCH}"
  133. TUNE_PKGARCH ??= ""
  134. PACKAGE_ARCH ??= "${TUNE_PKGARCH}"
  135. MACHINE_ARCH = "${@[d.getVar('TUNE_PKGARCH'), d.getVar('MACHINE')][bool(d.getVar('MACHINE'))].replace('-', '_')}"
  136. PACKAGE_EXTRA_ARCHS ??= "${PACKAGE_EXTRA_ARCHS_tune-${DEFAULTTUNE}}"
  137. PACKAGE_ARCHS = "all any noarch ${PACKAGE_EXTRA_ARCHS} ${MACHINE_ARCH}"
  138. # MACHINE_ARCH shouldn't be included here as a variable dependency
  139. # since machine specific packages are handled using multimachine
  140. PACKAGE_ARCHS[vardepsexclude] = "MACHINE_ARCH"
  141. MULTIMACH_TARGET_SYS = "${PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  142. ##################################################################
  143. # Date/time variables.
  144. ##################################################################
  145. DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
  146. TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
  147. DATETIME = "${DATE}${TIME}"
  148. ##################################################################
  149. # Openembedded Software Prerequisites.
  150. ##################################################################
  151. # python-native should be here but python relies on building
  152. # its own in staging
  153. ASSUME_PROVIDED = "\
  154. bzip2-native \
  155. chrpath-native \
  156. file-native \
  157. findutils-native \
  158. gawk-native \
  159. git-native \
  160. grep-native \
  161. diffstat-native \
  162. patch-native \
  163. libgcc-native \
  164. hostperl-runtime-native \
  165. hostpython-runtime-native \
  166. tar-native \
  167. virtual/libintl-native \
  168. virtual/libiconv-native \
  169. virtual/crypt-native \
  170. texinfo-native \
  171. bash-native \
  172. sed-native \
  173. wget-native \
  174. "
  175. # gzip-native should be listed above?
  176. ##################################################################
  177. # Package default variables.
  178. ##################################################################
  179. PN = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[0] or 'defaultpkgname'}"
  180. PV = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[1] or '1.0'}"
  181. PR = "${@bb.parse.vars_from_file(d.getVar('FILE', False),d)[2] or 'r0'}"
  182. PE = ""
  183. PF = "${PN}-${EXTENDPE}${PV}-${PR}"
  184. EXTENDPE = "${@['','${PE}_'][int(d.getVar('PE') or 0) > 0]}"
  185. P = "${PN}-${PV}"
  186. PRSERV_PV_AUTOINC = "AUTOINC"
  187. PRAUTO = ""
  188. EXTENDPRAUTO = "${@['.${PRAUTO}', ''][not d.getVar('PRAUTO')]}"
  189. PRAUTOINX = "${PF}"
  190. PKGV ?= "${PV}"
  191. PKGR ?= "${PR}${EXTENDPRAUTO}"
  192. PKGE ?= "${@['','${PE}'][int(d.getVar('PE') or 0) > 0]}"
  193. EXTENDPKGEVER = "${@['','${PKGE}:'][d.getVar('PKGE').strip() != '']}"
  194. EXTENDPKGV ?= "${EXTENDPKGEVER}${PKGV}-${PKGR}"
  195. # Base package name
  196. # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
  197. # otherwise it is the same as PN and P
  198. SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -crosssdk -cross-canadian"
  199. BPN = "${@oe.utils.prune_suffix(d.getVar('PN'), d.getVar('SPECIAL_PKGSUFFIX').split(), d)}"
  200. BP = "${BPN}-${PV}"
  201. # Package info.
  202. SECTION = "base"
  203. PRIORITY = "optional"
  204. SUMMARY ?= "${PN} version ${PV}-${PR}"
  205. DESCRIPTION ?= "${SUMMARY}."
  206. # The following two are commented out because they result in a recursive
  207. # definition of the variable in some corner cases. These are left in
  208. # to illustrate the intended behavior.
  209. #SUMMARY_${PN} ?= "${SUMMARY}"
  210. #DESCRIPTION_${PN} ?= "${DESCRIPTION}"
  211. SUMMARY_${PN}-src ?= "${SUMMARY} - Source files"
  212. DESCRIPTION_${PN}-src ?= "${DESCRIPTION} \
  213. This package contains sources for debugging purposes."
  214. SUMMARY_${PN}-dbg ?= "${SUMMARY} - Debugging files"
  215. DESCRIPTION_${PN}-dbg ?= "${DESCRIPTION} \
  216. This package contains ELF symbols and related sources for debugging purposes."
  217. SUMMARY_${PN}-dev ?= "${SUMMARY} - Development files"
  218. DESCRIPTION_${PN}-dev ?= "${DESCRIPTION} \
  219. This package contains symbolic links, header files, and \
  220. related items necessary for software development."
  221. SUMMARY_${PN}-staticdev ?= "${SUMMARY} - Development files (Static Libraries)"
  222. DESCRIPTION_${PN}-staticdev ?= "${DESCRIPTION} \
  223. This package contains static libraries for software development."
  224. SUMMARY_${PN}-doc ?= "${SUMMARY} - Documentation files"
  225. DESCRIPTION_${PN}-doc ?= "${DESCRIPTION} \
  226. This package contains documentation."
  227. LICENSE ??= "INVALID"
  228. MAINTAINER = "OE-Core Developers <openembedded-core@lists.openembedded.org>"
  229. HOMEPAGE = ""
  230. # Package dependencies and provides.
  231. # Ensure that -dev packages recommend the corresponding -dev packages of their
  232. # deps, and the same for -dbg.
  233. DEPCHAIN_PRE = ""
  234. DEPCHAIN_POST = "-dev -dbg"
  235. DEPENDS = ""
  236. RDEPENDS = ""
  237. PROVIDES = ""
  238. PROVIDES_prepend = "${PN} "
  239. RPROVIDES = ""
  240. MULTI_PROVIDER_WHITELIST = "virtual/libintl virtual/libintl-native virtual/nativesdk-libintl virtual/xserver virtual/update-alternatives-native virtual/update-alternatives"
  241. SOLIBS = ".so.*"
  242. SOLIBS_darwin = ".dylib"
  243. SOLIBSDEV = ".so"
  244. # Due to the ordering of PACKAGES and the naming of the dev symlinks on darwin,
  245. # we can't make the symlinks end up in the -dev packages easily at this point. This hack
  246. # at least means builds aren't completely broken and symlinks don't take up much space.
  247. SOLIBSDEV_darwin = ".dylibbroken"
  248. PACKAGE_DEBUG_SPLIT_STYLE ?= "debug-with-srcpkg"
  249. PACKAGE_BEFORE_PN ?= ""
  250. PACKAGES = "${PN}-src ${PN}-dbg ${PN}-staticdev ${PN}-dev ${PN}-doc ${PN}-locale ${PACKAGE_BEFORE_PN} ${PN}"
  251. PACKAGES_DYNAMIC = "^${PN}-locale-.*"
  252. FILES = ""
  253. FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
  254. ${sysconfdir} ${sharedstatedir} ${localstatedir} \
  255. ${base_bindir}/* ${base_sbindir}/* \
  256. ${base_libdir}/*${SOLIBS} \
  257. ${base_prefix}/lib/udev ${prefix}/lib/udev \
  258. ${base_libdir}/udev ${libdir}/udev \
  259. ${datadir}/${BPN} ${libdir}/${BPN}/* \
  260. ${datadir}/pixmaps ${datadir}/applications \
  261. ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
  262. ${libdir}/bonobo/servers"
  263. FILES_${PN}-bin = "${bindir}/* ${sbindir}/*"
  264. FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
  265. ${datadir}/gnome/help"
  266. SECTION_${PN}-doc = "doc"
  267. FILES_SOLIBSDEV ?= "${base_libdir}/lib*${SOLIBSDEV} ${libdir}/lib*${SOLIBSDEV}"
  268. FILES_${PN}-dev = "${includedir} ${FILES_SOLIBSDEV} ${libdir}/*.la \
  269. ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
  270. ${datadir}/aclocal ${base_libdir}/*.o \
  271. ${libdir}/${BPN}/*.la ${base_libdir}/*.la \
  272. ${libdir}/cmake ${datadir}/cmake"
  273. SECTION_${PN}-dev = "devel"
  274. ALLOW_EMPTY_${PN}-dev = "1"
  275. RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPKGV})"
  276. FILES_${PN}-staticdev = "${libdir}/*.a ${base_libdir}/*.a ${libdir}/${BPN}/*.a"
  277. SECTION_${PN}-staticdev = "devel"
  278. RDEPENDS_${PN}-staticdev = "${PN}-dev (= ${EXTENDPKGV})"
  279. FILES_${PN}-dbg = "/usr/lib/debug /usr/lib/debug-static /usr/src/debug"
  280. SECTION_${PN}-dbg = "devel"
  281. ALLOW_EMPTY_${PN}-dbg = "1"
  282. # The files list for source packages are dynamically set based on
  283. # PACKAGE_DEBUG_SPLIT_STYLE
  284. FILES_${PN}-src = ""
  285. SECTION_${PN}-src = "devel"
  286. FILES_${PN}-locale = "${datadir}/locale"
  287. # File manifest
  288. FILE_DIRNAME = "${@os.path.dirname(d.getVar('FILE', False))}"
  289. # FILESPATH is set in base.bbclass
  290. #FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/${BP}:${FILE_DIRNAME}/${BPN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
  291. # This default was only used for checking
  292. FILESEXTRAPATHS ?= "__default:"
  293. # The default list of fs-perms files to process. If the list is empty only
  294. # the builtin definitions will be used. Builtin definitions included:
  295. # base_prefix, prefix, exec_prefix, base_bindir, base_sbindir, base_libdir,
  296. # datadir, sysconfdir, servicedir, sharedstatedir, localstatedir, infodir,
  297. # mandir, docdir, bindir, sbindir, libexecdir, libdir, includedir and
  298. # oldincludedir
  299. FILESYSTEM_PERMS_TABLES ?= "${@'files/fs-perms.txt' if oe.types.boolean(d.getVar('VOLATILE_LOG_DIR')) else 'files/fs-perms-persistent-log.txt'}"
  300. ##################################################################
  301. # General work and output directories for the build system.
  302. ##################################################################
  303. TCMODE ?= "default"
  304. TCLIBC ?= "glibc"
  305. TMPDIR ?= "${TOPDIR}/tmp"
  306. CACHE = "${TMPDIR}/cache/${TCMODE}-${TCLIBC}${@['', '/' + str(d.getVar('MACHINE'))][bool(d.getVar('MACHINE'))]}${@['', '/' + str(d.getVar('SDKMACHINE'))][bool(d.getVar('SDKMACHINE'))]}"
  307. # The persistent cache should be shared by all builds
  308. PERSISTENT_DIR = "${TOPDIR}/cache"
  309. LOG_DIR = "${TMPDIR}/log"
  310. STAMPS_DIR ?= "${TMPDIR}/stamps"
  311. STAMP = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
  312. STAMPCLEAN = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/*-*"
  313. BASE_WORKDIR ?= "${TMPDIR}/work"
  314. WORKDIR = "${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
  315. T = "${WORKDIR}/temp"
  316. D = "${WORKDIR}/image"
  317. S = "${WORKDIR}/${BP}"
  318. B = "${S}"
  319. STAGING_DIR = "${TMPDIR}/sysroots"
  320. COMPONENTS_DIR = "${STAGING_DIR}-components"
  321. RECIPE_SYSROOT = "${WORKDIR}/recipe-sysroot"
  322. RECIPE_SYSROOT_NATIVE = "${WORKDIR}/recipe-sysroot-native"
  323. STAGING_DIR_NATIVE = "${RECIPE_SYSROOT_NATIVE}"
  324. STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
  325. STAGING_BINDIR_CROSS = "${STAGING_BINDIR}/crossscripts"
  326. STAGING_BINDIR_TOOLCHAIN = "${STAGING_DIR_NATIVE}${bindir_native}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  327. STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
  328. STAGING_LIBEXECDIR_NATIVE = "${STAGING_DIR_NATIVE}${libexecdir_native}"
  329. STAGING_BASE_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${base_libdir_native}"
  330. STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
  331. STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
  332. STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
  333. STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
  334. STAGING_DIR_HOST = "${RECIPE_SYSROOT}"
  335. STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
  336. STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
  337. STAGING_LIBEXECDIR = "${STAGING_DIR_HOST}${libexecdir}"
  338. STAGING_BASELIBDIR = "${STAGING_DIR_HOST}${base_libdir}"
  339. STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
  340. STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
  341. STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
  342. STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
  343. STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
  344. STAGING_DIR_TARGET = "${RECIPE_SYSROOT}"
  345. # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
  346. # packaged staging and/or multimachine.
  347. DEPLOY_DIR ?= "${TMPDIR}/deploy"
  348. DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
  349. DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
  350. DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
  351. DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
  352. DEPLOY_DIR_IMAGE ?= "${DEPLOY_DIR}/images/${MACHINE}"
  353. DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
  354. PKGDATA_DIR = "${TMPDIR}/pkgdata/${MACHINE}"
  355. ##################################################################
  356. # SDK variables.
  357. ##################################################################
  358. SDK_NAME_PREFIX ?= "oecore"
  359. SDK_NAME = "${SDK_NAME_PREFIX}-${SDK_ARCH}-${TUNE_PKGARCH}"
  360. SDKPATH = "/usr/local/${SDK_NAME_PREFIX}-${SDK_ARCH}"
  361. SDKPATHNATIVE = "${SDKPATH}/sysroots/${SDK_SYS}"
  362. ##################################################################
  363. # Kernel info.
  364. ##################################################################
  365. OLDEST_KERNEL = "3.2.0"
  366. OLDEST_KERNEL_aarch64 = "3.14"
  367. OLDEST_KERNEL_nios2 = "3.19"
  368. OLDEST_KERNEL_powerpc64le = "3.10.0"
  369. OLDEST_KERNEL_riscv32 = "5.4"
  370. OLDEST_KERNEL_riscv64 = "4.15"
  371. # SDK_OLDEST_KERNEL can't be set using overrides since there are
  372. # none for the SDK architecture. Best to set it from a machine-sdk
  373. # include file if you need an SDK arch-specific value
  374. SDK_OLDEST_KERNEL = "3.2.0"
  375. # Define where the kernel headers are installed on the target as well as where
  376. # they are staged.
  377. KERNEL_SRC_PATH = "/usr/src/kernel"
  378. STAGING_KERNEL_DIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-source"
  379. STAGING_KERNEL_BUILDDIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-build-artifacts"
  380. ##################################################################
  381. # Specific image creation and rootfs population info.
  382. ##################################################################
  383. IMAGE_ROOTFS = "${WORKDIR}/rootfs"
  384. # This option allows for a percentage overage of the actual image size rather than a
  385. # fixed extra space, this is space needed for initial startup and basic operations.
  386. IMAGE_OVERHEAD_FACTOR ?= "1.3"
  387. # This option allows for adding additional space in K above and beyond what the
  388. # IMAGE_OVERHEAD_FACTOR might add. This space is for additional packages, user data, ...
  389. # To set a fixed size then overriding IMAGE_ROOTFS_SIZE with the max size one wants
  390. # should do the trick
  391. IMAGE_ROOTFS_EXTRA_SPACE ?= "0"
  392. EXTRA_IMAGEDEPENDS = ""
  393. ##################################################################
  394. # Toolchain info.
  395. ##################################################################
  396. PATH_prepend = "${COREBASE}/scripts:${STAGING_BINDIR_TOOLCHAIN}:${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}${base_bindir_native}:"
  397. export PATH
  398. ##################################################################
  399. # Build utility info.
  400. ##################################################################
  401. # Directory where host tools are copied
  402. HOSTTOOLS_DIR = "${TMPDIR}/hosttools"
  403. # Tools needed to run builds with OE-Core
  404. HOSTTOOLS += " \
  405. [ ar as awk basename bash bzip2 cat chgrp chmod chown chrpath cmp comm cp cpio \
  406. cpp cut date dd diff diffstat dirname du echo egrep env expand expr false \
  407. fgrep file find flock g++ gawk gcc getconf getopt git grep gunzip gzip \
  408. head hostname iconv id install ld ldd ln ls make md5sum mkdir mknod \
  409. mktemp mv nm objcopy objdump od patch perl pr printf pwd \
  410. python3 ranlib readelf readlink realpath rm rmdir rpcgen sed seq sh \
  411. sha1sum sha224sum sha256sum sha384sum sha512sum \
  412. sleep sort split stat strings strip tail tar tee test touch tr true uname \
  413. uniq wc wget which xargs \
  414. "
  415. # Tools needed to run testimage runtime image testing
  416. HOSTTOOLS += "${@'ip ping ps scp ssh stty' if (bb.utils.contains_any('IMAGE_CLASSES', 'testimage testsdk', True, False, d) or any(x in (d.getVar("BBINCLUDED") or "") for x in ["testimage.bbclass", "testsdk.bbclass"])) else ''}"
  417. # Link to these if present
  418. HOSTTOOLS_NONFATAL += "aws gcc-ar gpg ld.bfd ld.gold nc pigz sftp socat ssh sudo"
  419. # Temporary add few more detected in bitbake world
  420. HOSTTOOLS_NONFATAL += "join nl size yes zcat"
  421. # Used by bzr fetcher
  422. HOSTTOOLS_NONFATAL += "bzr"
  423. # Used by ssh fetcher
  424. HOSTTOOLS_NONFATAL += "scp"
  425. # Link to git-lfs if present
  426. HOSTTOOLS_NONFATAL += "git-lfs"
  427. CCACHE ??= ""
  428. TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TARGET}"
  429. export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
  430. export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
  431. export FC = "${CCACHE}${HOST_PREFIX}gfortran ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
  432. export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS} ${HOST_CC_ARCH}"
  433. export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS} ${HOST_LD_ARCH}"
  434. export CCLD = "${CC}"
  435. export AR = "${HOST_PREFIX}gcc-ar"
  436. export AS = "${HOST_PREFIX}as ${HOST_AS_ARCH}"
  437. export RANLIB = "${HOST_PREFIX}gcc-ranlib"
  438. export STRIP = "${HOST_PREFIX}strip"
  439. export OBJCOPY = "${HOST_PREFIX}objcopy"
  440. export OBJDUMP = "${HOST_PREFIX}objdump"
  441. export STRINGS = "${HOST_PREFIX}strings"
  442. export NM = "${HOST_PREFIX}nm"
  443. export READELF = "${HOST_PREFIX}readelf"
  444. PYTHON = "${@sys.executable}"
  445. export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
  446. export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
  447. export BUILD_FC = "${CCACHE}${BUILD_PREFIX}gfortran ${BUILD_CC_ARCH}"
  448. export BUILD_CPP = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH} -E"
  449. export BUILD_LD = "${BUILD_PREFIX}ld ${BUILD_LD_ARCH}"
  450. export BUILD_CCLD = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
  451. export BUILD_AR = "${BUILD_PREFIX}ar"
  452. export BUILD_AS = "${BUILD_PREFIX}as ${BUILD_AS_ARCH}"
  453. export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
  454. export BUILD_STRIP = "${BUILD_PREFIX}strip"
  455. export BUILD_NM = "${BUILD_PREFIX}nm"
  456. export MAKE = "make"
  457. EXTRA_OEMAKE = ""
  458. EXTRA_OECONF = ""
  459. export LC_ALL = "en_US.UTF-8"
  460. export TZ = 'UTC'
  461. ##################################################################
  462. # Patch handling.
  463. ##################################################################
  464. PATCHTOOL = "quilt"
  465. PATCHRESOLVE = "noop"
  466. ##################################################################
  467. # Build flags and options.
  468. ##################################################################
  469. export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
  470. BUILDSDK_CPPFLAGS = ""
  471. export CPPFLAGS = "${TARGET_CPPFLAGS}"
  472. TARGET_CPPFLAGS = ""
  473. export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
  474. BUILDSDK_CFLAGS = "${BUILDSDK_CPPFLAGS} ${BUILD_OPTIMIZATION} ${DEBUG_PREFIX_MAP}"
  475. export CFLAGS = "${TARGET_CFLAGS}"
  476. TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
  477. export BUILD_CXXFLAGS = "${BUILD_CFLAGS}"
  478. BUILDSDK_CXXFLAGS = "${BUILDSDK_CFLAGS}"
  479. export CXXFLAGS = "${TARGET_CXXFLAGS}"
  480. TARGET_CXXFLAGS = "${TARGET_CFLAGS}"
  481. export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
  482. -L${STAGING_BASE_LIBDIR_NATIVE} \
  483. -Wl,--enable-new-dtags \
  484. -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
  485. -Wl,-rpath-link,${STAGING_BASE_LIBDIR_NATIVE} \
  486. -Wl,-rpath,${STAGING_LIBDIR_NATIVE} \
  487. -Wl,-rpath,${STAGING_BASE_LIBDIR_NATIVE} \
  488. -Wl,-O1"
  489. BUILDSDK_LDFLAGS = "-Wl,-O1"
  490. LINKER_HASH_STYLE ??= "gnu"
  491. TARGET_LINK_HASH_STYLE ?= "${@['-Wl,--hash-style=gnu',''][d.getVar('LINKER_HASH_STYLE') != 'gnu']}"
  492. ASNEEDED ?= "-Wl,--as-needed"
  493. export LDFLAGS = "${TARGET_LDFLAGS}"
  494. TARGET_LDFLAGS = "-Wl,-O1 ${TARGET_LINK_HASH_STYLE} ${ASNEEDED}"
  495. # mips does not support GNU hash style therefore we override
  496. LINKER_HASH_STYLE_mipsarch_libc-musl = "sysv"
  497. # Pass parallel make options to the compile task
  498. EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
  499. PARALLEL_MAKEINST ??= "${PARALLEL_MAKE}"
  500. # Pass parallel make options to the install task
  501. EXTRA_OEMAKE_prepend_task-install = "${PARALLEL_MAKEINST} "
  502. ##################################################################
  503. # Optimization flags.
  504. ##################################################################
  505. # Beware: applied last to first
  506. DEBUG_PREFIX_MAP ?= "-fmacro-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
  507. -fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
  508. -fdebug-prefix-map=${STAGING_DIR_HOST}= \
  509. -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
  510. "
  511. DEBUG_FLAGS ?= "-g -feliminate-unused-debug-types ${DEBUG_PREFIX_MAP}"
  512. # Disabled until the option works properly -feliminate-dwarf2-dups
  513. FULL_OPTIMIZATION = "-O2 -pipe ${DEBUG_FLAGS}"
  514. DEBUG_OPTIMIZATION = "-Og ${DEBUG_FLAGS} -pipe"
  515. SELECTED_OPTIMIZATION = "${@d.getVar(oe.utils.vartrue('DEBUG_BUILD', 'DEBUG_OPTIMIZATION', 'FULL_OPTIMIZATION', d))}"
  516. SELECTED_OPTIMIZATION[vardeps] += "FULL_OPTIMIZATION DEBUG_OPTIMIZATION DEBUG_BUILD"
  517. BUILD_OPTIMIZATION = "${@oe.utils.vartrue('DEBUG_BUILD', '-Og -g -feliminate-unused-debug-types', '-O2', d)} -pipe"
  518. BUILD_OPTIMIZATION[vardeps] += "DEBUG_BUILD"
  519. ##################################################################
  520. # Settings used by bitbake-layers.
  521. ##################################################################
  522. BBLAYERS_LAYERINDEX_URL ??= "https://layers.openembedded.org/layerindex/"
  523. BBLAYERS_FETCH_DIR ??= "${COREBASE}"
  524. ##################################################################
  525. # Download locations and utilities.
  526. ##################################################################
  527. APACHE_MIRROR = "https://archive.apache.org/dist"
  528. DEBIAN_MIRROR = "http://ftp.debian.org/debian/pool"
  529. GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
  530. GNOME_GIT = "git://gitlab.gnome.org/GNOME"
  531. GNOME_MIRROR = "https://ftp.gnome.org/pub/GNOME/sources"
  532. GNU_MIRROR = "https://ftp.gnu.org/gnu"
  533. GNUPG_MIRROR = "https://www.gnupg.org/ftp/gcrypt"
  534. GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
  535. KERNELORG_MIRROR = "https://cdn.kernel.org/pub"
  536. SOURCEFORGE_MIRROR = "https://downloads.sourceforge.net"
  537. XLIBS_MIRROR = "https://xlibs.freedesktop.org/release"
  538. XORG_MIRROR = "https://www.x.org/releases/"
  539. SAVANNAH_GNU_MIRROR = "https://download.savannah.gnu.org/releases"
  540. SAVANNAH_NONGNU_MIRROR = "https://download.savannah.nongnu.org/releases"
  541. CPAN_MIRROR = "https://search.cpan.org/CPAN"
  542. SRC_URI[vardepsexclude] += "\
  543. APACHE_MIRROR \
  544. CPAN_MIRROR \
  545. DEBIAN_MIRROR \
  546. GENTOO_MIRROR \
  547. GNOME_GIT \
  548. GNOME_MIRROR \
  549. GNU_MIRROR \
  550. GNUPG_MIRROR \
  551. GPE_MIRROR \
  552. KERNELORG_MIRROR \
  553. SAVANNAH_GNU_MIRROR \
  554. SAVANNAH_NONGNU_MIRROR \
  555. SOURCEFORGE_MIRROR \
  556. XLIBS_MIRROR \
  557. XORG_MIRROR \
  558. "
  559. # You can use the mirror of your country to get faster downloads by putting
  560. # export DEBIAN_MIRROR = "http://ftp.de.debian.org/debian/pool"
  561. # into your local.conf
  562. SRCDATE = "${DATE}"
  563. SRCREV ??= "INVALID"
  564. AUTOREV = "${@bb.fetch2.get_autorev(d)}"
  565. AUTOREV[vardepvalue] = "${SRCPV}"
  566. # Set Dynamically in base.bbclass
  567. # SRCPV = "${@bb.fetch2.get_srcrev(d)}"
  568. SRCPV[vardepvalue] = "${SRCPV}"
  569. SRC_URI = ""
  570. # Use pseudo as the fakeroot implementation
  571. PSEUDO_LOCALSTATEDIR ?= "${WORKDIR}/pseudo/"
  572. PSEUDO_PASSWD ?= "${STAGING_DIR_TARGET}:${PSEUDO_SYSROOT}"
  573. PSEUDO_SYSROOT = "${COMPONENTS_DIR}/${BUILD_ARCH}/pseudo-native"
  574. PSEUDO_IGNORE_PATHS = "/usr/,/etc/,/lib,/dev/,${T},${WORKDIR}/recipe-sysroot,${SSTATE_DIR},${STAMPS_DIR},${WORKDIR}/pkgdata-sysroot,${TMPDIR}/sstate-control,${DEPLOY_DIR},${WORKDIR}/deploy-,${TMPDIR}/buildstats,${WORKDIR}/sstate-build-package_,${WORKDIR}/sstate-install-package_,${WORKDIR}/sstate-build-image_complete,${TMPDIR}/sysroots-components,${BUILDHISTORY_DIR},${TMPDIR}/pkgdata,${TOPDIR}/cache,${COREBASE}/scripts,${COREBASE}/meta,${CCACHE_DIR}"
  575. export PSEUDO_DISABLED = "1"
  576. #export PSEUDO_PREFIX = "${STAGING_DIR_NATIVE}${prefix_native}"
  577. #export PSEUDO_BINDIR = "${STAGING_DIR_NATIVE}${bindir_native}"
  578. #export PSEUDO_LIBDIR = "${STAGING_DIR_NATIVE}$PSEUDOBINDIR/../lib/pseudo/lib
  579. FAKEROOTBASEENV = "PSEUDO_BINDIR=${PSEUDO_SYSROOT}${bindir_native} PSEUDO_LIBDIR=${PSEUDO_SYSROOT}${prefix_native}/lib/pseudo/lib PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_IGNORE_PATHS=${PSEUDO_IGNORE_PATHS} PSEUDO_DISABLED=1"
  580. FAKEROOTCMD = "${PSEUDO_SYSROOT}${bindir_native}/pseudo"
  581. FAKEROOTENV = "PSEUDO_PREFIX=${PSEUDO_SYSROOT}${prefix_native} PSEUDO_LOCALSTATEDIR=${PSEUDO_LOCALSTATEDIR} PSEUDO_PASSWD=${PSEUDO_PASSWD} PSEUDO_NOSYMLINKEXP=1 PSEUDO_IGNORE_PATHS=${PSEUDO_IGNORE_PATHS} PSEUDO_DISABLED=0"
  582. FAKEROOTNOENV = "PSEUDO_UNLOAD=1"
  583. FAKEROOTDIRS = "${PSEUDO_LOCALSTATEDIR}"
  584. PREFERRED_PROVIDER_virtual/fakeroot-native ?= "pseudo-native"
  585. ##################################################################
  586. # Not sure about the rest of this yet.
  587. ##################################################################
  588. # Pre-build configuration output
  589. BUILDCFG_HEADER = "Build Configuration${@" (mc:${BB_CURRENT_MC})" if d.getVar("BBMULTICONFIG") else ""}:"
  590. BUILDCFG_VARS = "BB_VERSION BUILD_SYS NATIVELSBSTRING TARGET_SYS MACHINE DISTRO DISTRO_VERSION TUNE_FEATURES TARGET_FPU"
  591. BUILDCFG_VARS[type] = "list"
  592. BUILDCFG_NEEDEDVARS = "TARGET_ARCH TARGET_OS"
  593. BUILDCFG_NEEDEDVARS[type] = "list"
  594. # Other
  595. export PKG_CONFIG_DIR = "${STAGING_DIR_HOST}${libdir}/pkgconfig"
  596. export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
  597. export PKG_CONFIG_LIBDIR = "${PKG_CONFIG_DIR}"
  598. export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR_HOST}"
  599. export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
  600. export PKG_CONFIG_SYSTEM_LIBRARY_PATH = "${base_libdir}:${libdir}"
  601. export PKG_CONFIG_SYSTEM_INCLUDE_PATH = "${includedir}"
  602. # Don't allow git to chdir up past WORKDIR so that it doesn't detect the OE
  603. # repository when building a recipe
  604. export GIT_CEILING_DIRECTORIES = "${WORKDIR}"
  605. ###
  606. ### Config file processing
  607. ###
  608. # An empty distro leads to :: entries in OVERRIDES and FILEOVERRIDES which
  609. # is a bad idea. Setting a dummy value is better than a ton of anonymous python.
  610. DISTRO ??= "nodistro"
  611. DISTRO_NAME ??= "OpenEmbedded"
  612. # Overrides are processed left to right, so the ones that are named later take precedence.
  613. # You generally want them to go from least to most specific. This means that:
  614. # A variable '<foo>_arm' overrides a variable '<foo>' when ${TARGET_ARCH} is arm.
  615. # A variable '<foo>_qemuarm' overrides '<foo>' and overrides '<foo>_arm' when ${MACHINE} is 'qemuarm'.
  616. # If you use combination ie '<foo>_qemuarm_arm', then '<foo>_qemuarm_arm' will override
  617. # '<foo>_qemuarm' and then '<foo>' will be overriden with that value from '<foo>_qemuarm'.
  618. # And finally '<foo>_forcevariable' overrides any standard variable, with the highest priority.
  619. # This works for functions as well, they are really just variables.
  620. #
  621. OVERRIDES = "${TARGET_OS}:${TRANSLATED_TARGET_ARCH}:pn-${PN}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${CLASSOVERRIDE}${LIBCOVERRIDE}:forcevariable"
  622. LIBCOVERRIDE ?= ""
  623. CLASSOVERRIDE ?= "class-target"
  624. DISTROOVERRIDES ?= "${@d.getVar('DISTRO') or ''}"
  625. MACHINEOVERRIDES ?= "${MACHINE}"
  626. FILESOVERRIDES = "${TRANSLATED_TARGET_ARCH}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}"
  627. ##################################################################
  628. # Include the rest of the config files.
  629. ##################################################################
  630. require conf/abi_version.conf
  631. include conf/site.conf
  632. include conf/auto.conf
  633. include conf/local.conf
  634. require conf/multiconfig/${BB_CURRENT_MC}.conf
  635. include conf/machine/${MACHINE}.conf
  636. include conf/machine-sdk/${SDKMACHINE}.conf
  637. include conf/distro/${DISTRO}.conf
  638. include conf/distro/defaultsetup.conf
  639. include conf/documentation.conf
  640. include conf/licenses.conf
  641. require conf/sanity.conf
  642. ##################################################################
  643. # Weak variables (usually to retain backwards compatibility)
  644. ##################################################################
  645. DL_DIR ?= "${TOPDIR}/downloads"
  646. SSTATE_DIR ?= "${TOPDIR}/sstate-cache"
  647. IMAGE_FSTYPES ?= "tar.gz"
  648. IMAGE_FSTYPES_DEBUGFS ?= "tar.gz"
  649. INITRAMFS_FSTYPES ?= "cpio.gz"
  650. # The maximum size in Kbytes for the generated initramfs image size.
  651. # Usually, it should be less than 1/2 of ram size, or you may fail to
  652. # boot it.
  653. INITRAMFS_MAXSIZE ??= "131072"
  654. DEFAULT_TASK_PROVIDER ?= "packagegroup-base"
  655. MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
  656. # The size in Kbytes for the generated image if it is larger than
  657. # the required size (du -ks IMAGE_ROOTFS * IMAGE_OVERHEAD_FACTOR),
  658. # and no effect if less than it.
  659. IMAGE_ROOTFS_SIZE ??= "65536"
  660. # Forcefully set CACHE now so future changes to things like
  661. # MACHINE don't change the path to the cache
  662. CACHE := "${CACHE}"
  663. # Default to setting automatically based on cpu count
  664. BB_NUMBER_THREADS ?= "${@oe.utils.cpu_count()}"
  665. # Default to setting automatically based on cpu count
  666. PARALLEL_MAKE ?= "-j ${@oe.utils.cpu_count()}"
  667. # Default parallelism and resource usage for xz
  668. XZ_MEMLIMIT ?= "50%"
  669. XZ_THREADS ?= "${@oe.utils.cpu_count(at_least=2)}"
  670. XZ_DEFAULTS ?= "--memlimit=${XZ_MEMLIMIT} --threads=${XZ_THREADS}"
  671. XZ_DEFAULTS[vardepsexclude] += "XZ_MEMLIMIT XZ_THREADS"
  672. ##################################################################
  673. # Magic Cookie for SANITY CHECK
  674. ##################################################################
  675. OES_BITBAKE_CONF = "1"
  676. ##################################################################
  677. # Machine properties and packagegroup-base stuff
  678. ##################################################################
  679. MACHINE_FEATURES ?= ""
  680. DISTRO_FEATURES ?= ""
  681. DISTRO_EXTRA_RDEPENDS ?= ""
  682. DISTRO_EXTRA_RRECOMMENDS ?= ""
  683. MACHINE_EXTRA_RDEPENDS ?= ""
  684. MACHINE_EXTRA_RRECOMMENDS ?= ""
  685. MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
  686. MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
  687. EXTRA_IMAGE_FEATURES ??= ""
  688. IMAGE_FEATURES += "${EXTRA_IMAGE_FEATURES}"
  689. # Native distro features (will always be used for -native, even if they
  690. # are not enabled for target)
  691. DISTRO_FEATURES_NATIVE ?= "x11 ipv6 xattr"
  692. DISTRO_FEATURES_NATIVESDK ?= "x11"
  693. # Normally target distro features will not be applied to native builds:
  694. # Native distro features on this list will use the target feature value
  695. DISTRO_FEATURES_FILTER_NATIVE ?= "api-documentation opengl"
  696. DISTRO_FEATURES_FILTER_NATIVESDK ?= "api-documentation opengl"
  697. DISTRO_FEATURES_BACKFILL = "pulseaudio sysvinit gobject-introspection-data ldconfig"
  698. MACHINE_FEATURES_BACKFILL = "rtc qemu-usermode"
  699. COMBINED_FEATURES = "${@oe.utils.set_intersect('DISTRO_FEATURES', 'MACHINE_FEATURES', d)}"
  700. COMBINED_FEATURES[vardeps] += "DISTRO_FEATURES MACHINE_FEATURES"
  701. SERIAL_CONSOLE ??= ""
  702. SERIAL_CONSOLES ??= "${@d.getVar('SERIAL_CONSOLE').replace(' ', ';')}"
  703. NO_RECOMMENDATIONS ??= ""
  704. BAD_RECOMMENDATIONS ?= ""
  705. # Make sure MACHINE isn't exported
  706. # (breaks binutils at least)
  707. MACHINE[unexport] = "1"
  708. # Make sure TARGET_ARCH isn't exported
  709. # (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
  710. # in them, undocumented)
  711. TARGET_ARCH[unexport] = "1"
  712. # Make sure DISTRO isn't exported
  713. # (breaks sysvinit at least)
  714. DISTRO[unexport] = "1"
  715. # Make sure SHELL isn't exported
  716. # (can break any number of things if the user's shell isn't POSIX-compliant,
  717. # including the flock command). The user's shell shouldn't affect our builds.
  718. SHELL[unexport] = "1"
  719. # Used by canadian-cross to handle string conversions on TARGET_ARCH where needed
  720. TRANSLATED_TARGET_ARCH ??= "${@d.getVar('TARGET_ARCH').replace("_", "-")}"
  721. # Complete output from bitbake
  722. BB_CONSOLELOG ?= "${LOG_DIR}/cooker/${MACHINE}/${DATETIME}.log"
  723. # Setup our default hash policy
  724. BB_SIGNATURE_HANDLER ?= "OEBasicHash"
  725. BB_HASHEXCLUDE_COMMON ?= "TMPDIR FILE PATH PWD BB_TASKHASH BBPATH BBSERVER DL_DIR \
  726. THISDIR FILESEXTRAPATHS FILE_DIRNAME HOME LOGNAME SHELL \
  727. USER FILESPATH STAGING_DIR_HOST STAGING_DIR_TARGET COREBASE PRSERV_HOST \
  728. STAMPS_DIR PRSERV_DUMPDIR PRSERV_DUMPFILE PRSERV_LOCKDOWN PARALLEL_MAKE \
  729. CCACHE_DIR EXTERNAL_TOOLCHAIN CCACHE CCACHE_NOHASHDIR LICENSE_PATH SDKPKGSUFFIX \
  730. WARN_QA ERROR_QA WORKDIR STAMPCLEAN PKGDATA_DIR BUILD_ARCH SSTATE_PKGARCH \
  731. BB_WORKERCONTEXT BB_LIMITEDDEPS BB_UNIHASH extend_recipe_sysroot DEPLOY_DIR \
  732. SSTATE_HASHEQUIV_METHOD SSTATE_HASHEQUIV_REPORT_TASKDATA \
  733. SSTATE_HASHEQUIV_OWNER CCACHE_TOP_DIR BB_HASHSERVE GIT_CEILING_DIRECTORIES"
  734. BB_HASHBASE_WHITELIST ?= "${BB_HASHEXCLUDE_COMMON} PSEUDO_IGNORE_PATHS BUILDHISTORY_DIR SSTATE_DIR "
  735. BB_HASHCONFIG_WHITELIST ?= "${BB_HASHEXCLUDE_COMMON} DATE TIME SSH_AGENT_PID \
  736. SSH_AUTH_SOCK PSEUDO_BUILD BB_ENV_EXTRAWHITE DISABLE_SANITY_CHECKS \
  737. PARALLEL_MAKE BB_NUMBER_THREADS BB_ORIGENV BB_INVALIDCONF BBINCLUDED \
  738. GIT_PROXY_COMMAND ALL_PROXY all_proxy NO_PROXY no_proxy FTP_PROXY ftp_proxy \
  739. HTTP_PROXY http_proxy HTTPS_PROXY https_proxy SOCKS5_USER SOCKS5_PASSWD \
  740. BB_SETSCENE_ENFORCE BB_CMDLINE BB_SERVER_TIMEOUT"
  741. BB_SIGNATURE_EXCLUDE_FLAGS ?= "doc deps depends \
  742. lockfiles type vardepsexclude vardeps vardepvalue vardepvalueexclude \
  743. file-checksums python func task export unexport noexec nostamp dirs cleandirs \
  744. sstate-lockfile-shared prefuncs postfuncs export_func deptask rdeptask \
  745. recrdeptask nodeprrecs stamp-extra-info sstate-outputdirs filename lineno \
  746. progress mcdepends number_threads"
  747. MLPREFIX ??= ""
  748. MULTILIB_VARIANTS ??= ""
  749. # Older versions of bitbake (< 1.42) don't set BB_UNIHASH. For compatibility with these
  750. # versions, set BB_UNIHASH equivalent to BB_TASKHASH if unspecified, which is
  751. # what it would be anyway if the signature generator (e.g. OEEquivHash) doesn't
  752. # support unihashes.
  753. BB_UNIHASH ?= "${BB_TASKHASH}"