ptest.bbclass 4.2 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119
  1. SUMMARY_${PN}-ptest ?= "${SUMMARY} - Package test files"
  2. DESCRIPTION_${PN}-ptest ?= "${DESCRIPTION} \
  3. This package contains a test directory ${PTEST_PATH} for package test purposes."
  4. PTEST_PATH ?= "${libdir}/${BPN}/ptest"
  5. PTEST_BUILD_HOST_FILES ?= "Makefile"
  6. PTEST_BUILD_HOST_PATTERN ?= ""
  7. FILES_${PN}-ptest += "${PTEST_PATH}"
  8. SECTION_${PN}-ptest = "devel"
  9. ALLOW_EMPTY_${PN}-ptest = "1"
  10. PTEST_ENABLED = "${@bb.utils.contains('DISTRO_FEATURES', 'ptest', '1', '0', d)}"
  11. PTEST_ENABLED_class-native = ""
  12. PTEST_ENABLED_class-nativesdk = ""
  13. PTEST_ENABLED_class-cross-canadian = ""
  14. RDEPENDS_${PN}-ptest += "${PN}"
  15. RDEPENDS_${PN}-ptest_class-native = ""
  16. RDEPENDS_${PN}-ptest_class-nativesdk = ""
  17. RRECOMMENDS_${PN}-ptest += "ptest-runner"
  18. PACKAGES =+ "${@bb.utils.contains('PTEST_ENABLED', '1', '${PN}-ptest', '', d)}"
  19. do_configure_ptest() {
  20. :
  21. }
  22. do_configure_ptest_base() {
  23. do_configure_ptest
  24. }
  25. do_compile_ptest() {
  26. :
  27. }
  28. do_compile_ptest_base() {
  29. do_compile_ptest
  30. }
  31. do_install_ptest() {
  32. :
  33. }
  34. do_install_ptest_base() {
  35. if [ -f ${WORKDIR}/run-ptest ]; then
  36. install -D ${WORKDIR}/run-ptest ${D}${PTEST_PATH}/run-ptest
  37. fi
  38. if grep -q install-ptest: Makefile; then
  39. oe_runmake DESTDIR=${D}${PTEST_PATH} install-ptest
  40. fi
  41. do_install_ptest
  42. chown -R root:root ${D}${PTEST_PATH}
  43. # Strip build host paths from any installed Makefile
  44. for filename in ${PTEST_BUILD_HOST_FILES}; do
  45. for installed_ptest_file in $(find ${D}${PTEST_PATH} -type f -name $filename); do
  46. bbnote "Stripping host paths from: $installed_ptest_file"
  47. sed -e 's#${HOSTTOOLS_DIR}/*##g' \
  48. -e 's#${WORKDIR}/*=#.=#g' \
  49. -e 's#${WORKDIR}/*##g' \
  50. -i $installed_ptest_file
  51. if [ -n "${PTEST_BUILD_HOST_PATTERN}" ]; then
  52. sed -E '/${PTEST_BUILD_HOST_PATTERN}/d' \
  53. -i $installed_ptest_file
  54. fi
  55. done
  56. done
  57. }
  58. PTEST_BINDIR_PKGD_PATH = "${PKGD}${PTEST_PATH}/bin"
  59. # This function needs to run after apply_update_alternative_renames because the
  60. # aforementioned function will update the ALTERNATIVE_LINK_NAME flag. Append is
  61. # used here to make this function to run as late as possible.
  62. PACKAGE_PREPROCESS_FUNCS_append = "${@bb.utils.contains('PTEST_BINDIR', '1', \
  63. bb.utils.contains('PTEST_ENABLED', '1', ' ptest_update_alternatives', '', d), '', d)}"
  64. python ptest_update_alternatives() {
  65. """
  66. This function will generate the symlinks in the PTEST_BINDIR_PKGD_PATH
  67. to match the renamed binaries by update-alternatives.
  68. """
  69. if not bb.data.inherits_class('update-alternatives', d) \
  70. or not update_alternatives_enabled(d):
  71. return
  72. bb.note("Generating symlinks for ptest")
  73. bin_paths = { d.getVar("bindir"), d.getVar("base_bindir"),
  74. d.getVar("sbindir"), d.getVar("base_sbindir") }
  75. ptest_bindir = d.getVar("PTEST_BINDIR_PKGD_PATH")
  76. os.mkdir(ptest_bindir)
  77. for pkg in (d.getVar('PACKAGES') or "").split():
  78. alternatives = update_alternatives_alt_targets(d, pkg)
  79. for alt_name, alt_link, alt_target, _ in alternatives:
  80. # Some alternatives are for man pages,
  81. # check if the alternative is in PATH
  82. if os.path.dirname(alt_link) in bin_paths:
  83. os.symlink(alt_target, os.path.join(ptest_bindir, alt_name))
  84. }
  85. do_configure_ptest_base[dirs] = "${B}"
  86. do_compile_ptest_base[dirs] = "${B}"
  87. do_install_ptest_base[dirs] = "${B}"
  88. do_install_ptest_base[cleandirs] = "${D}${PTEST_PATH}"
  89. addtask configure_ptest_base after do_configure before do_compile
  90. addtask compile_ptest_base after do_compile before do_install
  91. addtask install_ptest_base after do_install before do_package do_populate_sysroot
  92. python () {
  93. if not bb.data.inherits_class('native', d) and not bb.data.inherits_class('cross', d):
  94. d.setVarFlag('do_install_ptest_base', 'fakeroot', '1')
  95. d.setVarFlag('do_install_ptest_base', 'umask', '022')
  96. # Remove all '*ptest_base' tasks when ptest is not enabled
  97. if not(d.getVar('PTEST_ENABLED') == "1"):
  98. for i in ['do_configure_ptest_base', 'do_compile_ptest_base', 'do_install_ptest_base']:
  99. bb.build.deltask(i, d)
  100. }