module.bbclass 2.7 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374
  1. inherit module-base kernel-module-split pkgconfig
  2. EXTRA_OEMAKE += "KERNEL_SRC=${STAGING_KERNEL_DIR}"
  3. MODULES_INSTALL_TARGET ?= "modules_install"
  4. MODULES_MODULE_SYMVERS_LOCATION ?= ""
  5. python __anonymous () {
  6. depends = d.getVar('DEPENDS')
  7. extra_symbols = []
  8. for dep in depends.split():
  9. if dep.startswith("kernel-module-"):
  10. extra_symbols.append("${STAGING_INCDIR}/" + dep + "/Module.symvers")
  11. d.setVar('KBUILD_EXTRA_SYMBOLS', " ".join(extra_symbols))
  12. }
  13. python do_devshell_prepend () {
  14. os.environ['CFLAGS'] = ''
  15. os.environ['CPPFLAGS'] = ''
  16. os.environ['CXXFLAGS'] = ''
  17. os.environ['LDFLAGS'] = ''
  18. os.environ['KERNEL_PATH'] = d.getVar('STAGING_KERNEL_DIR')
  19. os.environ['KERNEL_SRC'] = d.getVar('STAGING_KERNEL_DIR')
  20. os.environ['KERNEL_VERSION'] = d.getVar('KERNEL_VERSION')
  21. os.environ['CC'] = d.getVar('KERNEL_CC')
  22. os.environ['LD'] = d.getVar('KERNEL_LD')
  23. os.environ['AR'] = d.getVar('KERNEL_AR')
  24. os.environ['O'] = d.getVar('STAGING_KERNEL_BUILDDIR')
  25. kbuild_extra_symbols = d.getVar('KBUILD_EXTRA_SYMBOLS')
  26. if kbuild_extra_symbols:
  27. os.environ['KBUILD_EXTRA_SYMBOLS'] = kbuild_extra_symbols
  28. else:
  29. os.environ['KBUILD_EXTRA_SYMBOLS'] = ''
  30. }
  31. module_do_compile() {
  32. unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
  33. oe_runmake KERNEL_PATH=${STAGING_KERNEL_DIR} \
  34. KERNEL_VERSION=${KERNEL_VERSION} \
  35. CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
  36. AR="${KERNEL_AR}" \
  37. O=${STAGING_KERNEL_BUILDDIR} \
  38. KBUILD_EXTRA_SYMBOLS="${KBUILD_EXTRA_SYMBOLS}" \
  39. ${MAKE_TARGETS}
  40. }
  41. module_do_install() {
  42. unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
  43. oe_runmake DEPMOD=echo MODLIB="${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}" \
  44. INSTALL_FW_PATH="${D}${nonarch_base_libdir}/firmware" \
  45. CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
  46. O=${STAGING_KERNEL_BUILDDIR} \
  47. ${MODULES_INSTALL_TARGET}
  48. if [ ! -e "${B}/${MODULES_MODULE_SYMVERS_LOCATION}/Module.symvers" ] ; then
  49. bbwarn "Module.symvers not found in ${B}/${MODULES_MODULE_SYMVERS_LOCATION}"
  50. bbwarn "Please consider setting MODULES_MODULE_SYMVERS_LOCATION to a"
  51. bbwarn "directory below B to get correct inter-module dependencies"
  52. else
  53. install -Dm0644 "${B}/${MODULES_MODULE_SYMVERS_LOCATION}"/Module.symvers ${D}${includedir}/${BPN}/Module.symvers
  54. # Module.symvers contains absolute path to the build directory.
  55. # While it doesn't actually seem to matter which path is specified,
  56. # clear them out to avoid confusion
  57. sed -e 's:${B}/::g' -i ${D}${includedir}/${BPN}/Module.symvers
  58. fi
  59. }
  60. EXPORT_FUNCTIONS do_compile do_install
  61. # add all splitted modules to PN RDEPENDS, PN can be empty now
  62. KERNEL_MODULES_META_PACKAGE = "${PN}"
  63. FILES_${PN} = ""
  64. ALLOW_EMPTY_${PN} = "1"