extrausers.bbclass 2.1 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768
  1. # This bbclass is used for image level user/group configuration.
  2. # Inherit this class if you want to make EXTRA_USERS_PARAMS effective.
  3. # Below is an example showing how to use this functionality.
  4. # IMAGE_CLASSES += "extrausers"
  5. # EXTRA_USERS_PARAMS = "\
  6. # useradd -p '' tester; \
  7. # groupadd developers; \
  8. # userdel nobody; \
  9. # groupdel -g video; \
  10. # groupmod -g 1020 developers; \
  11. # usermod -s /bin/sh tester; \
  12. # "
  13. inherit useradd_base
  14. PACKAGE_INSTALL_append = " ${@['', 'base-passwd shadow'][bool(d.getVar('EXTRA_USERS_PARAMS'))]}"
  15. # Image level user / group settings
  16. ROOTFS_POSTPROCESS_COMMAND_append = " set_user_group;"
  17. # Image level user / group settings
  18. set_user_group () {
  19. user_group_settings="${EXTRA_USERS_PARAMS}"
  20. export PSEUDO="${FAKEROOTENV} ${STAGING_DIR_NATIVE}${bindir}/pseudo"
  21. setting=`echo $user_group_settings | cut -d ';' -f1`
  22. remaining=`echo $user_group_settings | cut -d ';' -f2-`
  23. while test "x$setting" != "x"; do
  24. cmd=`echo $setting | cut -d ' ' -f1`
  25. opts=`echo $setting | cut -d ' ' -f2-`
  26. # Different from useradd.bbclass, there's no file locking issue here, as
  27. # this setting is actually a serial process. So we only retry once.
  28. case $cmd in
  29. useradd)
  30. perform_useradd "${IMAGE_ROOTFS}" "-R ${IMAGE_ROOTFS} $opts"
  31. ;;
  32. groupadd)
  33. perform_groupadd "${IMAGE_ROOTFS}" "-R ${IMAGE_ROOTFS} $opts"
  34. ;;
  35. userdel)
  36. perform_userdel "${IMAGE_ROOTFS}" "-R ${IMAGE_ROOTFS} $opts"
  37. ;;
  38. groupdel)
  39. perform_groupdel "${IMAGE_ROOTFS}" "-R ${IMAGE_ROOTFS} $opts"
  40. ;;
  41. usermod)
  42. perform_usermod "${IMAGE_ROOTFS}" "-R ${IMAGE_ROOTFS} $opts"
  43. ;;
  44. groupmod)
  45. perform_groupmod "${IMAGE_ROOTFS}" "-R ${IMAGE_ROOTFS} $opts"
  46. ;;
  47. *)
  48. bbfatal "Invalid command in EXTRA_USERS_PARAMS: $cmd"
  49. ;;
  50. esac
  51. # Avoid infinite loop if the last parameter doesn't end with ';'
  52. if [ "$setting" = "$remaining" ]; then
  53. break
  54. fi
  55. # iterate to the next setting
  56. setting=`echo $remaining | cut -d ';' -f1`
  57. remaining=`echo $remaining | cut -d ';' -f2-`
  58. done
  59. }
  60. USERADDEXTENSION ?= ""
  61. inherit ${USERADDEXTENSION}