webkitgtk_2.26.2.bb 5.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125
  1. SUMMARY = "WebKit web rendering engine for the GTK+ platform"
  2. HOMEPAGE = "https://www.webkitgtk.org/"
  3. BUGTRACKER = "https://bugs.webkit.org/"
  4. LICENSE = "BSD & LGPLv2+"
  5. LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \
  6. file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \
  7. file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
  8. file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
  9. "
  10. SRC_URI = "https://www.webkitgtk.org/releases/${BPN}-${PV}.tar.xz \
  11. file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \
  12. file://0001-When-building-introspection-files-add-CMAKE_C_FLAGS-.patch \
  13. file://0001-OptionsGTK.cmake-drop-the-hardcoded-introspection-gt.patch \
  14. file://0001-Fix-racy-parallel-build-of-WebKit2-4.0.gir.patch \
  15. file://0001-Tweak-gtkdoc-settings-so-that-gtkdoc-generation-work.patch \
  16. file://x32_support.patch \
  17. file://cross-compile.patch \
  18. file://0001-Fix-build-with-musl.patch \
  19. file://include_array.patch \
  20. "
  21. SRC_URI[md5sum] = "65e06fe73ee166447894aaea95038e3b"
  22. SRC_URI[sha256sum] = "6b80f0637a80818559ac8fd50db3b394f41cb61904fb9b3ed65fa51635806512"
  23. inherit cmake pkgconfig gobject-introspection perlnative features_check upstream-version-is-even gtk-doc
  24. REQUIRED_DISTRO_FEATURES = "x11 opengl"
  25. CVE_PRODUCT = "webkitgtk webkitgtk\+"
  26. DEPENDS = "zlib libsoup-2.4 curl libxml2 cairo libxslt libxt libidn libgcrypt \
  27. gtk+3 gstreamer1.0 gstreamer1.0-plugins-base flex-native gperf-native sqlite3 \
  28. pango icu bison-native gawk intltool-native libwebp \
  29. atk udev harfbuzz jpeg libpng pulseaudio librsvg libtheora libvorbis libxcomposite libxtst \
  30. ruby-native libnotify gstreamer1.0-plugins-bad \
  31. gettext-native glib-2.0 glib-2.0-native libtasn1 \
  32. "
  33. PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', 'wayland' ,d)} \
  34. ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'webgl opengl', '' ,d)} \
  35. enchant \
  36. libsecret \
  37. "
  38. PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland"
  39. PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11"
  40. PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue"
  41. PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant"
  42. PACKAGECONFIG[gtk2] = "-DENABLE_PLUGIN_PROCESS_GTK2=ON,-DENABLE_PLUGIN_PROCESS_GTK2=OFF,gtk+"
  43. PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2"
  44. PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/libgl"
  45. PACKAGECONFIG[opengl] = "-DENABLE_OPENGL=ON,-DENABLE_OPENGL=OFF,virtual/libgl"
  46. PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret"
  47. PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen"
  48. # Source is at https://github.com/google/woff2
  49. PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2"
  50. PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg"
  51. EXTRA_OECMAKE = " \
  52. -DPORT=GTK \
  53. -DCMAKE_BUILD_TYPE=Release \
  54. ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \
  55. ${@bb.utils.contains('GTKDOC_ENABLED', 'True', '-DENABLE_GTKDOC=ON', '-DENABLE_GTKDOC=OFF', d)} \
  56. -DENABLE_MINIBROWSER=ON \
  57. -DPYTHON_EXECUTABLE=`which python3` \
  58. -DENABLE_BUBBLEWRAP_SANDBOX=OFF \
  59. "
  60. # Javascript JIT is not supported on ARC
  61. EXTRA_OECMAKE_append_arc = " -DENABLE_JIT=OFF "
  62. # By default 25-bit "medium" calls are used on ARC
  63. # which is not enough for binaries larger than 32 MiB
  64. CFLAGS_append_arc = " -mlong-calls"
  65. CXXFLAGS_append_arc = " -mlong-calls"
  66. # Javascript JIT is not supported on powerpc
  67. EXTRA_OECMAKE_append_powerpc = " -DENABLE_JIT=OFF "
  68. EXTRA_OECMAKE_append_powerpc64 = " -DENABLE_JIT=OFF "
  69. # ARM JIT code does not build on ARMv4/5/6 anymore
  70. EXTRA_OECMAKE_append_armv5 = " -DENABLE_JIT=OFF "
  71. EXTRA_OECMAKE_append_armv6 = " -DENABLE_JIT=OFF "
  72. EXTRA_OECMAKE_append_armv4 = " -DENABLE_JIT=OFF "
  73. EXTRA_OECMAKE_append_mipsarchn32 = " -DUSE_LD_GOLD=OFF "
  74. EXTRA_OECMAKE_append_powerpc = " -DUSE_LD_GOLD=OFF "
  75. # JIT not supported on MIPS either
  76. EXTRA_OECMAKE_append_mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON "
  77. # JIT not supported on X32
  78. # An attempt was made to upstream JIT support for x32 in
  79. # https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as
  80. # unresolved due to limited X32 adoption.
  81. EXTRA_OECMAKE_append_x86-x32 = " -DENABLE_JIT=OFF "
  82. SECURITY_CFLAGS_remove_aarch64 = "-fpie"
  83. SECURITY_CFLAGS_append_aarch64 = " -fPIE"
  84. FILES_${PN} += "${libdir}/webkit2gtk-4.0/injected-bundle/libwebkit2gtkinjectedbundle.so"
  85. RRECOMMENDS_${PN} += "ca-certificates shared-mime-info"
  86. # http://errors.yoctoproject.org/Errors/Details/20370/
  87. ARM_INSTRUCTION_SET_armv4 = "arm"
  88. ARM_INSTRUCTION_SET_armv5 = "arm"
  89. ARM_INSTRUCTION_SET_armv6 = "arm"
  90. # https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474
  91. # https://bugs.webkit.org/show_bug.cgi?id=159880
  92. # JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime.
  93. # Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb).
  94. ARM_INSTRUCTION_SET_armv7a = "thumb"
  95. ARM_INSTRUCTION_SET_armv7r = "thumb"
  96. ARM_INSTRUCTION_SET_armv7ve = "thumb"
  97. # qemu: uncaught target signal 11 (Segmentation fault) - core dumped
  98. # Segmentation fault
  99. GI_DATA_ENABLED_armv7a = "False"
  100. GI_DATA_ENABLED_armv7ve = "False"
  101. # Can't be built with ccache
  102. CCACHE_DISABLE = "1"