strace_4.26.bb 2.1 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758
  1. SUMMARY = "System call tracing tool"
  2. HOMEPAGE = "http://strace.io"
  3. SECTION = "console/utils"
  4. LICENSE = "LGPL-2.1+ & GPL-2+"
  5. LIC_FILES_CHKSUM = "file://COPYING;md5=5c84d1c6e48e7961ccd2cd2ae32f7bf1"
  6. SRC_URI = "https://strace.io/files/${PV}/strace-${PV}.tar.xz \
  7. file://disable-git-version-gen.patch \
  8. file://more-robust-test-for-m32-mx32-compile-support.patch \
  9. file://update-gawk-paths.patch \
  10. file://Makefile-ptest.patch \
  11. file://run-ptest \
  12. file://0001-Fix-build-when-using-non-glibc-libc-implementation-o.patch \
  13. file://mips-SIGEMT.patch \
  14. file://0001-caps-abbrev.awk-fix-gawk-s-path.patch \
  15. file://0001-tests-sigaction-Check-for-mips-and-alpha-before-usin.patch \
  16. file://0001-mips-o32-fix-build.patch \
  17. file://ptest-spacesave.patch \
  18. "
  19. SRC_URI[md5sum] = "daa51acc0c7c696221ec03cf0b30a7af"
  20. SRC_URI[sha256sum] = "7c4d2ffeef4f7d1cdc71062ca78d1130eb52f947c2fca82f59f6a1183bfa1e1c"
  21. inherit autotools ptest
  22. PACKAGECONFIG_class-target ??= "\
  23. ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \
  24. "
  25. PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
  26. PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
  27. EXTRA_OECONF += "--enable-mpers=no"
  28. CFLAGS_append_libc-musl = " -Dsigcontext_struct=sigcontext"
  29. TESTDIR = "tests"
  30. PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
  31. do_install_append() {
  32. # We don't ship strace-graph here because it needs perl
  33. rm ${D}${bindir}/strace-graph
  34. }
  35. do_compile_ptest() {
  36. oe_runmake -C ${TESTDIR} buildtest-TESTS
  37. }
  38. do_install_ptest() {
  39. oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
  40. install -m 755 ${S}/test-driver ${D}${PTEST_PATH}
  41. install -m 644 ${B}/config.h ${D}${PTEST_PATH}
  42. sed -i -e '/^src/s/strace.*[1-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
  43. }
  44. RDEPENDS_${PN}-ptest += "make coreutils grep gawk sed"
  45. BBCLASSEXTEND = "native"
  46. TOOLCHAIN = "gcc"