cmake-native_3.18.4.bb 1.7 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253
  1. require cmake.inc
  2. inherit native
  3. DEPENDS += "bzip2-replacement-native xz-native zlib-native curl-native ncurses-native"
  4. SRC_URI += "file://OEToolchainConfig.cmake \
  5. file://environment.d-cmake.sh \
  6. file://0001-CMakeDetermineSystem-use-oe-environment-vars-to-load.patch \
  7. file://0005-Disable-use-of-ext2fs-ext2_fs.h-by-cmake-s-internal-.patch \
  8. "
  9. B = "${WORKDIR}/build"
  10. do_configure[cleandirs] = "${B}"
  11. CMAKE_EXTRACONF = "\
  12. -DCMAKE_LIBRARY_PATH=${STAGING_LIBDIR_NATIVE} \
  13. -DBUILD_CursesDialog=1 \
  14. -DCMAKE_USE_SYSTEM_LIBRARIES=1 \
  15. -DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=0 \
  16. -DCMAKE_USE_SYSTEM_LIBRARY_LIBARCHIVE=0 \
  17. -DCMAKE_USE_SYSTEM_LIBRARY_LIBUV=0 \
  18. -DCMAKE_USE_SYSTEM_LIBRARY_LIBRHASH=0 \
  19. -DCMAKE_USE_SYSTEM_LIBRARY_EXPAT=0 \
  20. -DENABLE_ACL=0 -DHAVE_ACL_LIBACL_H=0 \
  21. -DHAVE_SYS_ACL_H=0 \
  22. "
  23. do_configure () {
  24. ${S}/configure --verbose --prefix=${prefix} \
  25. ${@oe.utils.parallel_make_argument(d, '--parallel=%d')} \
  26. ${@bb.utils.contains('CCACHE', 'ccache ', '--enable-ccache', '', d)} \
  27. -- ${CMAKE_EXTRACONF}
  28. }
  29. do_compile() {
  30. oe_runmake
  31. }
  32. do_install() {
  33. oe_runmake 'DESTDIR=${D}' install
  34. # The following codes are here because eSDK needs to provide compatibilty
  35. # for SDK. That is, eSDK could also be used like traditional SDK.
  36. mkdir -p ${D}${datadir}/cmake
  37. install -m 644 ${WORKDIR}/OEToolchainConfig.cmake ${D}${datadir}/cmake/
  38. mkdir -p ${D}${base_prefix}/environment-setup.d
  39. install -m 644 ${WORKDIR}/environment.d-cmake.sh ${D}${base_prefix}/environment-setup.d/cmake.sh
  40. }
  41. do_compile[progress] = "percent"
  42. SYSROOT_DIRS_NATIVE += "${datadir}/cmake ${base_prefix}/environment-setup.d"