bitbake.conf 32 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829
  1. ##################################################################
  2. # Standard target filesystem paths.
  3. ##################################################################
  4. #
  5. # If changing these values, beware that native/cross/nativesdk bbclass
  6. # files may also need changes to keep in sync.
  7. #
  8. # Used by multilib code to change the library paths
  9. baselib = "${BASELIB}"
  10. baselib[vardepvalue] = "${baselib}"
  11. BASELIB = "lib"
  12. BASELIB_powerpc64 = "lib64"
  13. # Path prefixes
  14. export base_prefix = ""
  15. export prefix = "/usr"
  16. export exec_prefix = "${prefix}"
  17. # Base paths
  18. export base_bindir = "${base_prefix}/bin"
  19. export base_sbindir = "${base_prefix}/sbin"
  20. export base_libdir = "${base_prefix}/${baselib}"
  21. export nonarch_base_libdir = "${base_prefix}/lib"
  22. # Architecture independent paths
  23. export sysconfdir = "${base_prefix}/etc"
  24. export servicedir = "${base_prefix}/srv"
  25. export sharedstatedir = "${base_prefix}/com"
  26. export localstatedir = "${base_prefix}/var"
  27. export datadir = "${prefix}/share"
  28. export infodir = "${datadir}/info"
  29. export mandir = "${datadir}/man"
  30. export docdir = "${datadir}/doc"
  31. export systemd_unitdir = "${nonarch_base_libdir}/systemd"
  32. export systemd_system_unitdir = "${nonarch_base_libdir}/systemd/system"
  33. export nonarch_libdir = "${exec_prefix}/lib"
  34. export systemd_user_unitdir = "${nonarch_libdir}/systemd/user"
  35. # Architecture dependent paths
  36. export bindir = "${exec_prefix}/bin"
  37. export sbindir = "${exec_prefix}/sbin"
  38. export libdir = "${exec_prefix}/${baselib}"
  39. export libexecdir = "${exec_prefix}/libexec"
  40. export includedir = "${exec_prefix}/include"
  41. export oldincludedir = "${exec_prefix}/include"
  42. localedir = "${libdir}/locale"
  43. # Linkage between native/cross/nativesdk layouts
  44. base_bindir_native = "/bin"
  45. base_sbindir_native = "/sbin"
  46. sysconfdir_native = "/etc"
  47. prefix_native = "/usr"
  48. bindir_native = "${prefix_native}/bin"
  49. sbindir_native = "${prefix_native}/sbin"
  50. includedir_native = "${prefix_native}/include"
  51. libdir_native = "${prefix_native}/lib"
  52. libexecdir_native = "${prefix_native}/libexec"
  53. base_libdir_native = "/lib"
  54. datadir_native = "${prefix_native}/share"
  55. bindir_cross = "/bin"
  56. bindir_crossscripts = "${bindir}/crossscripts"
  57. prefix_nativesdk = "/usr"
  58. bindir_nativesdk = "${prefix_nativesdk}/bin"
  59. sbindir_nativesdk = "${prefix_nativesdk}/sbin"
  60. base_bindir_nativesdk = "/bin"
  61. base_sbindir_nativesdk = "/sbin"
  62. includedir_nativesdk = "${prefix_nativesdk}/include"
  63. libdir_nativesdk = "${prefix_nativesdk}/lib"
  64. base_libdir_nativesdk = "/lib"
  65. localstatedir_nativesdk = "/var"
  66. #
  67. # Cross recipes need to know about the target layout
  68. # := is used carefully here
  69. #
  70. target_datadir := "${datadir}"
  71. # Used to find env/perl/python
  72. USRBINPATH = "${bindir}"
  73. USRBINPATH_class-native = "/usr/bin"
  74. USRBINPATH_class-nativesdk = "/usr/bin"
  75. # Root home directory
  76. ROOT_HOME ??= "/home/root"
  77. ##################################################################
  78. # Architecture-dependent build variables.
  79. ##################################################################
  80. # Immediate expansion since there is no point in reapeatedly calling
  81. # os.uname() throughout parsing
  82. BUILD_ARCH := "${@os.uname()[4]}"
  83. BUILD_OS := "${@os.uname()[0].lower()}"
  84. BUILD_VENDOR = ""
  85. BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  86. BUILD_PREFIX = ""
  87. BUILD_CC_ARCH = ""
  88. BUILD_LD_ARCH = ""
  89. BUILD_AS_ARCH = ""
  90. BUILD_EXEEXT = ""
  91. HOST_ARCH = "${TARGET_ARCH}"
  92. HOST_OS = "${TARGET_OS}"
  93. HOST_VENDOR = "${TARGET_VENDOR}"
  94. HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
  95. HOST_PREFIX = "${TARGET_PREFIX}"
  96. HOST_CC_ARCH = "${TARGET_CC_ARCH}"
  97. HOST_LD_ARCH = "${TARGET_LD_ARCH}"
  98. HOST_AS_ARCH = "${TARGET_AS_ARCH}"
  99. HOST_EXEEXT = ""
  100. TUNE_ARCH ??= "INVALID"
  101. TUNE_CCARGS ??= ""
  102. TUNE_CCARGS[vardepvalue] = "${TUNE_CCARGS}"
  103. TUNE_LDARGS ??= ""
  104. TUNE_ASARGS ??= ""
  105. TUNE_FEATURES ??= "${TUNE_FEATURES_tune-${DEFAULTTUNE}}"
  106. LIBCEXTENSION ??= ""
  107. ABIEXTENSION ??= ""
  108. USE_NLS ??= "${@bb.utils.contains('DISTRO_FEATURES', 'libc-locale-code', 'yes', 'no', d)}"
  109. SDKUSE_NLS ??= "yes"
  110. TARGET_ARCH = "${TUNE_ARCH}"
  111. TARGET_OS = "linux${LIBCEXTENSION}${ABIEXTENSION}"
  112. TARGET_VENDOR = "-oe"
  113. TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + d.getVar('TARGET_OS'), ''][d.getVar('TARGET_OS') == ('' or 'custom')]}"
  114. TARGET_PREFIX = "${TARGET_SYS}-"
  115. TARGET_CC_ARCH = "${TUNE_CCARGS}"
  116. TARGET_LD_ARCH = "${TUNE_LDARGS}"
  117. TARGET_AS_ARCH = "${TUNE_ASARGS}"
  118. SDKMACHINE ??= "x86_64"
  119. SDK_OS = "${BUILD_OS}"
  120. SDK_VENDOR = "-oesdk"
  121. SDK_SYS = "${SDK_ARCH}${SDK_VENDOR}${@['-' + d.getVar('SDK_OS'), ''][d.getVar('SDK_OS') == ('' or 'custom')]}"
  122. SDK_PREFIX = "${SDK_SYS}-"
  123. SDK_CC_ARCH = "${BUILD_CC_ARCH}"
  124. SDKPKGSUFFIX = "nativesdk"
  125. SDK_PACKAGE_ARCHS = "all any noarch ${SDK_ARCH}-${SDKPKGSUFFIX}"
  126. SDK_LD_ARCH = "${BUILD_LD_ARCH}"
  127. SDK_AS_ARCH = "${BUILD_AS_ARCH}"
  128. TUNE_PKGARCH ??= ""
  129. PACKAGE_ARCH ??= "${TUNE_PKGARCH}"
  130. MACHINE_ARCH = "${@[d.getVar('TUNE_PKGARCH'), d.getVar('MACHINE')][bool(d.getVar('MACHINE'))].replace('-', '_')}"
  131. PACKAGE_EXTRA_ARCHS ??= "${PACKAGE_EXTRA_ARCHS_tune-${DEFAULTTUNE}}"
  132. PACKAGE_ARCHS = "all any noarch ${PACKAGE_EXTRA_ARCHS} ${MACHINE_ARCH}"
  133. # MACHINE_ARCH shouldn't be included here as a variable dependency
  134. # since machine specific packages are handled using multimachine
  135. PACKAGE_ARCHS[vardepsexclude] = "MACHINE_ARCH"
  136. MULTIMACH_TARGET_SYS = "${PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  137. MULTIMACH_HOST_SYS = "${PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
  138. ##################################################################
  139. # Date/time variables.
  140. ##################################################################
  141. DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
  142. TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
  143. DATETIME = "${DATE}${TIME}"
  144. ##################################################################
  145. # Openembedded Software Prerequisites.
  146. ##################################################################
  147. # python-native should be here but python relies on building
  148. # its own in staging
  149. ASSUME_PROVIDED = "\
  150. bzip2-native \
  151. chrpath-native \
  152. file-native \
  153. findutils-native \
  154. git-native \
  155. grep-native \
  156. diffstat-native \
  157. patch-native \
  158. libgcc-native \
  159. hostperl-runtime-native \
  160. hostpython-runtime-native \
  161. tar-native \
  162. virtual/libintl-native \
  163. virtual/libiconv-native \
  164. texinfo-native \
  165. bash-native \
  166. sed-native \
  167. wget-native \
  168. "
  169. # gzip-native should be listed above?
  170. ##################################################################
  171. # Package default variables.
  172. ##################################################################
  173. PN = "${@bb.parse.BBHandler.vars_from_file(d.getVar('FILE', False),d)[0] or 'defaultpkgname'}"
  174. PV = "${@bb.parse.BBHandler.vars_from_file(d.getVar('FILE', False),d)[1] or '1.0'}"
  175. PR = "${@bb.parse.BBHandler.vars_from_file(d.getVar('FILE', False),d)[2] or 'r0'}"
  176. PE = ""
  177. PF = "${PN}-${EXTENDPE}${PV}-${PR}"
  178. EXTENDPE = "${@['','${PE}_'][int(d.getVar('PE') or 0) > 0]}"
  179. P = "${PN}-${PV}"
  180. PRAUTO = ""
  181. EXTENDPRAUTO = "${@['.${PRAUTO}', ''][not d.getVar('PRAUTO')]}"
  182. PRAUTOINX = "${PF}"
  183. PKGV ?= "${PV}"
  184. PKGR ?= "${PR}${EXTENDPRAUTO}"
  185. PKGE ?= "${@['','${PE}'][int(d.getVar('PE') or 0) > 0]}"
  186. EXTENDPKGEVER = "${@['','${PKGE}:'][d.getVar('PKGE').strip() != '']}"
  187. EXTENDPKGV ?= "${EXTENDPKGEVER}${PKGV}-${PKGR}"
  188. # Base package name
  189. # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
  190. # otherwise it is the same as PN and P
  191. SPECIAL_PKGSUFFIX = "-native -cross -initial -intermediate -crosssdk -cross-canadian"
  192. BPN = "${@base_prune_suffix(d.getVar('PN'), d.getVar('SPECIAL_PKGSUFFIX').split(), d)}"
  193. BP = "${BPN}-${PV}"
  194. # Package info.
  195. SECTION = "base"
  196. PRIORITY = "optional"
  197. SUMMARY ?= "${PN} version ${PV}-${PR}"
  198. DESCRIPTION ?= "${SUMMARY}."
  199. # The following two are commented out because they result in a recursive
  200. # definition of the variable in some corner cases. These are left in
  201. # to illustrate the intended behavior.
  202. #SUMMARY_${PN} ?= "${SUMMARY}"
  203. #DESCRIPTION_${PN} ?= "${DESCRIPTION}"
  204. SUMMARY_${PN}-dbg ?= "${SUMMARY} - Debugging files"
  205. DESCRIPTION_${PN}-dbg ?= "${DESCRIPTION} \
  206. This package contains ELF symbols and related sources for debugging purposes."
  207. SUMMARY_${PN}-dev ?= "${SUMMARY} - Development files"
  208. DESCRIPTION_${PN}-dev ?= "${DESCRIPTION} \
  209. This package contains symbolic links, header files, and \
  210. related items necessary for software development."
  211. SUMMARY_${PN}-staticdev ?= "${SUMMARY} - Development files (Static Libraries)"
  212. DESCRIPTION_${PN}-staticdev?= "${DESCRIPTION} \
  213. This package contains static libraries for software development."
  214. SUMMARY_${PN}-doc ?= "${SUMMARY} - Documentation files"
  215. DESCRIPTION_${PN}-doc ?= "${DESCRIPTION} \
  216. This package contains documentation."
  217. LICENSE ??= "INVALID"
  218. MAINTAINER = "OE-Core Developers <openembedded-core@lists.openembedded.org>"
  219. HOMEPAGE = ""
  220. # Package dependencies and provides.
  221. # Ensure that -dev packages recommend the corresponding -dev packages of their
  222. # deps, and the same for -dbg.
  223. DEPCHAIN_PRE = ""
  224. DEPCHAIN_POST = "-dev -dbg"
  225. DEPENDS = ""
  226. RDEPENDS = ""
  227. PROVIDES = ""
  228. PROVIDES_prepend = "${PN} "
  229. RPROVIDES = ""
  230. MULTI_PROVIDER_WHITELIST = "virtual/libintl virtual/libintl-native virtual/nativesdk-libintl virtual/xserver virtual/update-alternatives-native virtual/update-alternatives"
  231. SOLIBS = ".so.*"
  232. SOLIBS_darwin = ".dylib"
  233. SOLIBSDEV = ".so"
  234. # Due to the ordering of PACKAGES and the naming of the dev symlinks on darwin,
  235. # we can't make the symlinks end up in the -dev packages easily at this point. This hack
  236. # at least means builds aren't completely broken and symlinks don't take up much space.
  237. SOLIBSDEV_darwin = ".dylibbroken"
  238. PACKAGE_BEFORE_PN ?= ""
  239. PACKAGES = "${PN}-dbg ${PN}-staticdev ${PN}-dev ${PN}-doc ${PN}-locale ${PACKAGE_BEFORE_PN} ${PN}"
  240. PACKAGES_DYNAMIC = "^${PN}-locale-.*"
  241. FILES = ""
  242. FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} \
  243. ${sysconfdir} ${sharedstatedir} ${localstatedir} \
  244. ${base_bindir}/* ${base_sbindir}/* \
  245. ${base_libdir}/*${SOLIBS} \
  246. ${base_prefix}/lib/udev ${prefix}/lib/udev \
  247. ${base_libdir}/udev ${libdir}/udev \
  248. ${datadir}/${BPN} ${libdir}/${BPN}/* \
  249. ${datadir}/pixmaps ${datadir}/applications \
  250. ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
  251. ${libdir}/bonobo/servers"
  252. FILES_${PN}-bin = "${bindir}/* ${sbindir}/*"
  253. FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
  254. ${datadir}/gnome/help"
  255. SECTION_${PN}-doc = "doc"
  256. FILES_SOLIBSDEV ?= "${base_libdir}/lib*${SOLIBSDEV} ${libdir}/lib*${SOLIBSDEV}"
  257. FILES_${PN}-dev = "${includedir} ${FILES_SOLIBSDEV} ${libdir}/*.la \
  258. ${libdir}/*.o ${libdir}/pkgconfig ${datadir}/pkgconfig \
  259. ${datadir}/aclocal ${base_libdir}/*.o \
  260. ${libdir}/${BPN}/*.la ${base_libdir}/*.la"
  261. SECTION_${PN}-dev = "devel"
  262. ALLOW_EMPTY_${PN}-dev = "1"
  263. RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPKGV})"
  264. FILES_${PN}-staticdev = "${libdir}/*.a ${base_libdir}/*.a ${libdir}/${BPN}/*.a"
  265. SECTION_${PN}-staticdev = "devel"
  266. RDEPENDS_${PN}-staticdev = "${PN}-dev (= ${EXTENDPKGV})"
  267. FILES_${PN}-dbg = "/usr/lib/debug /usr/src/debug"
  268. SECTION_${PN}-dbg = "devel"
  269. ALLOW_EMPTY_${PN}-dbg = "1"
  270. FILES_${PN}-locale = "${datadir}/locale"
  271. # File manifest
  272. FILE_DIRNAME = "${@os.path.dirname(d.getVar('FILE', False))}"
  273. # FILESPATH is set in base.bbclass
  274. #FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/${BP}:${FILE_DIRNAME}/${BPN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
  275. # This default was only used for checking
  276. FILESEXTRAPATHS ?= "__default:"
  277. ##################################################################
  278. # General work and output directories for the build system.
  279. ##################################################################
  280. TMPDIR ?= "${TOPDIR}/tmp"
  281. CACHE = "${TMPDIR}/cache${@['', '/' + str(d.getVar('MACHINE'))][bool(d.getVar('MACHINE'))]}${@['', '/' + str(d.getVar('SDKMACHINE'))][bool(d.getVar('SDKMACHINE'))]}"
  282. # The persistent cache should be shared by all builds
  283. PERSISTENT_DIR = "${TOPDIR}/cache"
  284. LOG_DIR = "${TMPDIR}/log"
  285. CO_DIR = "${DL_DIR}"
  286. CVSDIR = "${CO_DIR}/cvs"
  287. SVNDIR = "${CO_DIR}/svn"
  288. GITDIR = "${CO_DIR}/git2"
  289. BZRDIR = "${CO_DIR}/bzr"
  290. HGDIR = "${CO_DIR}/hg"
  291. STAMPS_DIR ?= "${TMPDIR}/stamps"
  292. STAMP = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
  293. STAMPCLEAN = "${STAMPS_DIR}/${MULTIMACH_TARGET_SYS}/${PN}/*-*"
  294. BASE_WORKDIR ?= "${TMPDIR}/work"
  295. WORKDIR = "${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}/${PN}/${EXTENDPE}${PV}-${PR}"
  296. T = "${WORKDIR}/temp"
  297. D = "${WORKDIR}/image"
  298. S = "${WORKDIR}/${BP}"
  299. B = "${S}"
  300. STAGING_DIR = "${TMPDIR}/sysroots"
  301. STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
  302. STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${bindir_native}"
  303. STAGING_BINDIR_CROSS = "${STAGING_BINDIR}/crossscripts"
  304. STAGING_BINDIR_TOOLCHAIN = "${STAGING_DIR_NATIVE}${bindir_native}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  305. STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${libdir_native}"
  306. STAGING_LIBEXECDIR_NATIVE = "${STAGING_DIR_NATIVE}${libexecdir_native}"
  307. STAGING_BASE_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${base_libdir_native}"
  308. STAGING_SBINDIR_NATIVE = "${STAGING_DIR_NATIVE}${sbindir_native}"
  309. STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${includedir_native}"
  310. STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${sysconfdir_native}"
  311. STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${datadir_native}"
  312. STAGING_DIR_HOST = "${STAGING_DIR}/${MACHINE}"
  313. STAGING_BINDIR = "${STAGING_DIR_HOST}${bindir}"
  314. STAGING_LIBDIR = "${STAGING_DIR_HOST}${libdir}"
  315. STAGING_LIBEXECDIR = "${STAGING_DIR_HOST}${libexecdir}"
  316. STAGING_BASELIBDIR = "${STAGING_DIR_HOST}${base_libdir}"
  317. STAGING_INCDIR = "${STAGING_DIR_HOST}${includedir}"
  318. STAGING_DATADIR = "${STAGING_DIR_HOST}${datadir}"
  319. STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${exec_prefix}"
  320. STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
  321. STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
  322. STAGING_DIR_TARGET = "${STAGING_DIR}/${MACHINE}"
  323. STAGING_DIR_TCBOOTSTRAP = "${STAGING_DIR_TARGET}-tcbootstrap"
  324. # Setting DEPLOY_DIR outside of TMPDIR is helpful, when you are using
  325. # packaged staging and/or multimachine.
  326. DEPLOY_DIR ?= "${TMPDIR}/deploy"
  327. DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
  328. DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
  329. DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
  330. DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
  331. DEPLOY_DIR_IMAGE ?= "${DEPLOY_DIR}/images/${MACHINE}"
  332. DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
  333. PKGDATA_DIR = "${STAGING_DIR_HOST}/pkgdata"
  334. ##################################################################
  335. # SDK variables.
  336. ##################################################################
  337. SDK_NAME_PREFIX ?= "oecore"
  338. SDK_NAME = "${SDK_NAME_PREFIX}-${SDK_ARCH}-${TUNE_PKGARCH}"
  339. SDKPATH = "/usr/local/${SDK_NAME_PREFIX}-${SDK_ARCH}"
  340. SDKPATHNATIVE = "${SDKPATH}/sysroots/${SDK_SYS}"
  341. ##################################################################
  342. # Kernel info.
  343. ##################################################################
  344. OLDEST_KERNEL = "3.2.0"
  345. OLDEST_KERNEL_aarch64 = "3.14"
  346. OLDEST_KERNEL_nios2 = "3.19"
  347. # SDK_OLDEST_KERNEL can't be set using overrides since there are
  348. # none for the SDK architecture. Best to set it from a machine-sdk
  349. # include file if you need an SDK arch-specific value
  350. SDK_OLDEST_KERNEL = "3.2.0"
  351. # Define where the kernel headers are installed on the target as well as where
  352. # they are staged.
  353. KERNEL_SRC_PATH = "/usr/src/kernel"
  354. STAGING_KERNEL_DIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-source"
  355. STAGING_KERNEL_BUILDDIR = "${TMPDIR}/work-shared/${MACHINE}/kernel-build-artifacts"
  356. ##################################################################
  357. # Specific image creation and rootfs population info.
  358. ##################################################################
  359. IMAGE_ROOTFS = "${WORKDIR}/rootfs"
  360. IMAGE_BASENAME = "${PN}"
  361. IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
  362. IMAGE_NAME[vardepsexclude] += "DATETIME"
  363. IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
  364. # This option allows for a percentage overage of the actual image size rather than a
  365. # fixed extra space, this is space needed for initial startup and basic operations.
  366. IMAGE_OVERHEAD_FACTOR ?= "1.3"
  367. # This option allows for adding additional space in K above and beyond what the
  368. # IMAGE_OVERHEAD_FACTOR might add. This space is for additional packages, user data, ...
  369. # To set a fixed size then overriding IMAGE_ROOTFS_SIZE with the max size one wants
  370. # should do the trick
  371. IMAGE_ROOTFS_EXTRA_SPACE ?= "0"
  372. EXTRA_IMAGEDEPENDS = ""
  373. ##################################################################
  374. # Toolchain info.
  375. ##################################################################
  376. PATH_prepend = "${COREBASE}/scripts:${STAGING_BINDIR_TOOLCHAIN}:${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${sbindir_native}:${STAGING_BINDIR_NATIVE}:${STAGING_DIR_NATIVE}${base_sbindir_native}:${STAGING_DIR_NATIVE}${base_bindir_native}:"
  377. export PATH
  378. ##################################################################
  379. # Build utility info.
  380. ##################################################################
  381. CCACHE ??= ""
  382. # Disable ccache explicitly if CCACHE is null since gcc may be a symlink
  383. # of ccache some distributions (e.g., Fedora 17).
  384. export CCACHE_DISABLE ??= "${@[0,1][d.getVar('CCACHE') == '']}"
  385. # ccache < 3.1.10 will create CCACHE_DIR on startup even if disabled, and
  386. # autogen sets HOME=/dev/null so in certain situations builds can fail.
  387. # Explicitly export CCACHE_DIR until we can assume ccache >3.1.10 on the host.
  388. export CCACHE_DIR ??= "${@os.getenv('HOME')}/.ccache"
  389. TOOLCHAIN_OPTIONS = " --sysroot=${STAGING_DIR_TARGET}"
  390. export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
  391. export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
  392. export FC = "${CCACHE}${HOST_PREFIX}gfortran ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
  393. export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS} ${HOST_CC_ARCH}"
  394. export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS} ${HOST_LD_ARCH}"
  395. export CCLD = "${CC}"
  396. export AR = "${HOST_PREFIX}ar"
  397. export AS = "${HOST_PREFIX}as ${HOST_AS_ARCH}"
  398. export RANLIB = "${HOST_PREFIX}ranlib"
  399. export STRIP = "${HOST_PREFIX}strip"
  400. export OBJCOPY = "${HOST_PREFIX}objcopy"
  401. export OBJDUMP = "${HOST_PREFIX}objdump"
  402. export STRINGS = "${HOST_PREFIX}strings"
  403. export NM = "${HOST_PREFIX}nm"
  404. export READELF = "${HOST_PREFIX}readelf"
  405. PYTHON = "${@sys.executable}"
  406. export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
  407. export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
  408. export BUILD_FC = "${CCACHE}${BUILD_PREFIX}gfortran ${BUILD_CC_ARCH}"
  409. export BUILD_CPP = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH} -E"
  410. export BUILD_LD = "${BUILD_PREFIX}ld ${BUILD_LD_ARCH}"
  411. export BUILD_CCLD = "${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
  412. export BUILD_AR = "${BUILD_PREFIX}ar"
  413. export BUILD_AS = "${BUILD_PREFIX}as ${BUILD_AS_ARCH}"
  414. export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
  415. export BUILD_STRIP = "${BUILD_PREFIX}strip"
  416. export BUILD_NM = "${BUILD_PREFIX}nm"
  417. export MAKE = "make"
  418. EXTRA_OEMAKE = ""
  419. EXTRA_OECONF = ""
  420. export LC_ALL = "en_US.UTF-8"
  421. ##################################################################
  422. # Patch handling.
  423. ##################################################################
  424. PATCHTOOL = "quilt"
  425. PATCHRESOLVE = "noop"
  426. ##################################################################
  427. # Build flags and options.
  428. ##################################################################
  429. export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
  430. BUILDSDK_CPPFLAGS = ""
  431. export CPPFLAGS = "${TARGET_CPPFLAGS}"
  432. export TARGET_CPPFLAGS = ""
  433. export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
  434. BUILDSDK_CFLAGS = "${BUILDSDK_CPPFLAGS} ${BUILD_OPTIMIZATION}"
  435. export CFLAGS = "${TARGET_CFLAGS}"
  436. export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
  437. export BUILD_CXXFLAGS = "${BUILD_CFLAGS}"
  438. export CXXFLAGS = "${TARGET_CXXFLAGS}"
  439. export TARGET_CXXFLAGS = "${TARGET_CFLAGS}"
  440. export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
  441. -L${STAGING_BASE_LIBDIR_NATIVE} \
  442. -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
  443. -Wl,-rpath-link,${STAGING_BASE_LIBDIR_NATIVE} \
  444. -Wl,-rpath,${STAGING_LIBDIR_NATIVE} \
  445. -Wl,-rpath,${STAGING_BASE_LIBDIR_NATIVE} \
  446. -Wl,-O1"
  447. BUILDSDK_LDFLAGS = "-Wl,-O1"
  448. LINKER_HASH_STYLE ??= "gnu"
  449. # mips does not support GNU hash style therefore we override
  450. LINKER_HASH_STYLE_mipsarch = "sysv"
  451. TARGET_LINK_HASH_STYLE ?= "${@['-Wl,--hash-style=gnu',''][d.getVar('LINKER_HASH_STYLE') != 'gnu']}"
  452. export LDFLAGS = "${TARGET_LDFLAGS}"
  453. export TARGET_LDFLAGS = "-Wl,-O1 ${TARGET_LINK_HASH_STYLE}"
  454. #export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${libdir} \
  455. # -Wl,-rpath-link,${STAGING_DIR_TARGET}${libdir} \
  456. # -Wl,-O1"
  457. # Pass parallel make options to the compile task
  458. EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
  459. PARALLEL_MAKEINST ??= "${PARALLEL_MAKE}"
  460. # Pass parallel make options to the install task
  461. EXTRA_OEMAKE_prepend_task-install = "${PARALLEL_MAKEINST} "
  462. ##################################################################
  463. # Optimization flags.
  464. ##################################################################
  465. DEBUG_PREFIX_MAP ?= "-fdebug-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR} \
  466. -fdebug-prefix-map=${STAGING_DIR_NATIVE}= \
  467. -fdebug-prefix-map=${STAGING_DIR_HOST}= \
  468. "
  469. DEBUG_FLAGS ?= "-g -feliminate-unused-debug-types ${DEBUG_PREFIX_MAP}"
  470. # Disabled until the option works properly -feliminate-dwarf2-dups
  471. FULL_OPTIMIZATION = "-O2 -pipe ${DEBUG_FLAGS}"
  472. DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer ${DEBUG_FLAGS} -pipe"
  473. SELECTED_OPTIMIZATION = "${@d.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][d.getVar('DEBUG_BUILD') == '1'])}"
  474. SELECTED_OPTIMIZATION[vardeps] += "FULL_OPTIMIZATION DEBUG_OPTIMIZATION"
  475. BUILD_OPTIMIZATION = "-O2 -pipe"
  476. ##################################################################
  477. # Settings used by bitbake-layers.
  478. ##################################################################
  479. BBLAYERS_LAYERINDEX_URL ??= "http://layers.openembedded.org/layerindex/"
  480. BBLAYERS_FETCH_DIR ??= "${COREBASE}"
  481. ##################################################################
  482. # Download locations and utilities.
  483. ##################################################################
  484. APACHE_MIRROR = "http://archive.apache.org/dist"
  485. DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
  486. GENTOO_MIRROR = "http://distfiles.gentoo.org/distfiles"
  487. GNOME_GIT = "git://git.gnome.org"
  488. GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
  489. GNU_MIRROR = "http://ftp.gnu.org/gnu"
  490. GNUPG_MIRROR = "https://www.gnupg.org/ftp/gcrypt"
  491. GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
  492. KERNELORG_MIRROR = "http://kernel.org/pub"
  493. SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
  494. XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
  495. XORG_MIRROR = "http://xorg.freedesktop.org/releases"
  496. SAVANNAH_GNU_MIRROR = "http://download.savannah.gnu.org/releases"
  497. SAVANNAH_NONGNU_MIRROR = "http://download.savannah.nongnu.org/releases"
  498. CPAN_MIRROR = "http://search.cpan.org/CPAN"
  499. SRC_URI[vardepsexclude] += "\
  500. APACHE_MIRROR \
  501. CPAN_MIRROR \
  502. DEBIAN_MIRROR \
  503. GENTOO_MIRROR \
  504. GNOME_GIT \
  505. GNOME_MIRROR \
  506. GNU_MIRROR \
  507. GNUPG_MIRROR \
  508. GPE_MIRROR \
  509. KERNELORG_MIRROR \
  510. SAVANNAH_GNU_MIRROR \
  511. SAVANNAH_NONGNU_MIRROR \
  512. SOURCEFORGE_MIRROR \
  513. XLIBS_MIRROR \
  514. XORG_MIRROR \
  515. "
  516. # You can use the mirror of your country to get faster downloads by putting
  517. # export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
  518. # into your local.conf
  519. FETCHCMD_svn = "/usr/bin/env svn --non-interactive --trust-server-cert"
  520. FETCHCMD_cvs = "/usr/bin/env cvs"
  521. FETCHCMD_wget = "/usr/bin/env wget -t 2 -T 30 -nv --passive-ftp --no-check-certificate"
  522. FETCHCMD_bzr = "/usr/bin/env bzr"
  523. FETCHCMD_hg = "/usr/bin/env hg"
  524. SRCDATE = "${DATE}"
  525. SRCREV ??= "INVALID"
  526. AUTOREV = "${@bb.fetch2.get_autorev(d)}"
  527. # Set Dynamically in base.bbclass
  528. # SRCPV = "${@bb.fetch2.get_srcrev(d)}"
  529. SRCPV[vardepvalue] = "${SRCPV}"
  530. SRC_URI = ""
  531. # Use pseudo as the fakeroot implementation
  532. PSEUDO_LOCALSTATEDIR ?= "${WORKDIR}/pseudo/"
  533. PSEUDO_PASSWD ?= "${STAGING_DIR_TARGET}:${STAGING_DIR_NATIVE}"
  534. export PSEUDO_DISABLED = "1"
  535. #export PSEUDO_PREFIX = "${STAGING_DIR_NATIVE}${prefix_native}"
  536. #export PSEUDO_BINDIR = "${STAGING_DIR_NATIVE}${bindir_native}"
  537. #export PSEUDO_LIBDIR = "${STAGING_DIR_NATIVE}$PSEUDOBINDIR/../lib/pseudo/lib
  538. FAKEROOTBASEENV = "PSEUDO_BINDIR=${STAGING_BINDIR_NATIVE} PSEUDO_LIBDIR=${STAGING_BINDIR_NATIVE}/../lib/pseudo/lib PSEUDO_PREFIX=${STAGING_BINDIR_NATIVE}/../../ PSEUDO_DISABLED=1"
  539. FAKEROOTCMD = "${STAGING_BINDIR_NATIVE}/pseudo"
  540. FAKEROOTENV = "PSEUDO_PREFIX=${STAGING_DIR_NATIVE}${prefix_native} PSEUDO_LOCALSTATEDIR=${PSEUDO_LOCALSTATEDIR} PSEUDO_PASSWD=${PSEUDO_PASSWD} PSEUDO_NOSYMLINKEXP=1 PSEUDO_DISABLED=0"
  541. FAKEROOTNOENV = "PSEUDO_UNLOAD=1"
  542. FAKEROOTDIRS = "${PSEUDO_LOCALSTATEDIR}"
  543. PREFERRED_PROVIDER_virtual/fakeroot-native ?= "pseudo-native"
  544. ##################################################################
  545. # Not sure about the rest of this yet.
  546. ##################################################################
  547. # Pre-build configuration output
  548. BUILDCFG_HEADER = "Build Configuration:"
  549. BUILDCFG_VARS = "BB_VERSION BUILD_SYS NATIVELSBSTRING TARGET_SYS MACHINE DISTRO DISTRO_VERSION TUNE_FEATURES TARGET_FPU"
  550. BUILDCFG_VARS[type] = "list"
  551. BUILDCFG_NEEDEDVARS = "TARGET_ARCH TARGET_OS"
  552. BUILDCFG_NEEDEDVARS[type] = "list"
  553. # Other
  554. export PKG_CONFIG_DIR = "${STAGING_DIR_HOST}${libdir}/pkgconfig"
  555. export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
  556. export PKG_CONFIG_LIBDIR = "${PKG_CONFIG_DIR}"
  557. export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR_HOST}"
  558. export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
  559. export PKG_CONFIG_SYSTEM_LIBRARY_PATH = "${base_libdir}:${libdir}"
  560. export PKG_CONFIG_SYSTEM_INCLUDE_PATH = "${includedir}"
  561. ###
  562. ### Config file processing
  563. ###
  564. # An empty distro leads to :: entries in OVERRIDES and FILEOVERRIDES which
  565. # is a bad idea. Setting a dummy value is better than a ton of anonymous python.
  566. DISTRO ??= "nodistro"
  567. DISTRO_NAME ??= "OpenEmbedded"
  568. # Overrides are processed left to right, so the ones that are named later take precedence.
  569. # You generally want them to go from least to most specific.
  570. #
  571. # This means that an envionment variable named '<foo>_arm' overrides an
  572. # environment variable '<foo>' (when ${TARGET_ARCH} is arm).
  573. # An environment variable '<foo>_qemuarm' overrides '<foo>' and overrides
  574. # '<foo>_arm' when ${MACHINE} is 'qemuarm'.
  575. # If you use combination ie '<foo>_qemuarm_arm', then '<foo>_qemuarm_arm' will override
  576. # '<foo>_qemuarm' and then '<foo>' will be overriden with that value from '<foo>_qemuarm'.
  577. # And finally '<foo>_forcevariable' overrides any standard variable, with the highest priority.
  578. #
  579. # This works for functions as well, they are really just environment variables.
  580. # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
  581. OVERRIDES = "${TARGET_OS}:${TRANSLATED_TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${CLASSOVERRIDE}:forcevariable"
  582. OVERRIDES[vardepsexclude] = "MACHINEOVERRIDES"
  583. CLASSOVERRIDE ?= "class-target"
  584. DISTROOVERRIDES ?= "${@d.getVar('DISTRO') or ''}"
  585. MACHINEOVERRIDES ?= "${MACHINE}"
  586. MACHINEOVERRIDES[vardepsexclude] = "MACHINE"
  587. FILESOVERRIDES = "${TRANSLATED_TARGET_ARCH}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}"
  588. ##################################################################
  589. # Include the rest of the config files.
  590. ##################################################################
  591. require conf/abi_version.conf
  592. include conf/site.conf
  593. include conf/auto.conf
  594. include conf/local.conf
  595. require conf/multiconfig/${BB_CURRENT_MC}.conf
  596. include conf/build/${BUILD_SYS}.conf
  597. include conf/target/${TARGET_SYS}.conf
  598. include conf/machine/${MACHINE}.conf
  599. include conf/machine-sdk/${SDKMACHINE}.conf
  600. include conf/distro/${DISTRO}.conf
  601. include conf/distro/defaultsetup.conf
  602. include conf/documentation.conf
  603. include conf/licenses.conf
  604. require conf/sanity.conf
  605. ##################################################################
  606. # Weak variables (usually to retain backwards compatibility)
  607. ##################################################################
  608. DL_DIR ?= "${TOPDIR}/downloads"
  609. SSTATE_DIR ?= "${TOPDIR}/sstate-cache"
  610. IMAGE_FSTYPES ?= "tar.gz"
  611. IMAGE_FSTYPES_DEBUGFS ?= "${IMAGE_FSTYPES}"
  612. INITRAMFS_FSTYPES ?= "cpio.gz"
  613. # The maximum size in Kbytes for the generated initramfs image size.
  614. # Usually, it should be less than 1/2 of ram size, or you may fail to
  615. # boot it.
  616. INITRAMFS_MAXSIZE ??= "131072"
  617. DEFAULT_TASK_PROVIDER ?= "packagegroup-base"
  618. MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
  619. # The size in Kbytes for the generated image if it is larger than
  620. # the required size (du -ks IMAGE_ROOTFS * IMAGE_OVERHEAD_FACTOR),
  621. # and no effect if less than it.
  622. IMAGE_ROOTFS_SIZE ??= "65536"
  623. # Forcefully set CACHE now so future changes to things like
  624. # MACHINE don't change the path to the cache
  625. CACHE := "${CACHE}"
  626. # Default to setting automatically based on cpu count
  627. BB_NUMBER_THREADS ?= "${@oe.utils.cpu_count()}"
  628. # Default to setting automatically based on cpu count
  629. PARALLEL_MAKE ?= "-j ${@oe.utils.cpu_count()}"
  630. ##################################################################
  631. # Magic Cookie for SANITY CHECK
  632. ##################################################################
  633. OES_BITBAKE_CONF = "1"
  634. ##################################################################
  635. # Machine properties and packagegroup-base stuff
  636. ##################################################################
  637. MACHINE_FEATURES ?= ""
  638. DISTRO_FEATURES ?= ""
  639. DISTRO_EXTRA_RDEPENDS ?= ""
  640. DISTRO_EXTRA_RRECOMMENDS ?= ""
  641. MACHINE_EXTRA_RDEPENDS ?= ""
  642. MACHINE_EXTRA_RRECOMMENDS ?= ""
  643. MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
  644. MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
  645. EXTRA_IMAGE_FEATURES ??= ""
  646. IMAGE_FEATURES += "${EXTRA_IMAGE_FEATURES}"
  647. DISTRO_FEATURES_BACKFILL = "pulseaudio sysvinit bluez5 gobject-introspection-data"
  648. MACHINE_FEATURES_BACKFILL = "rtc qemu-usermode"
  649. COMBINED_FEATURES = "${@oe.utils.set_intersect('DISTRO_FEATURES', 'MACHINE_FEATURES', d)}"
  650. COMBINED_FEATURES[vardeps] += "DISTRO_FEATURES MACHINE_FEATURES"
  651. SERIAL_CONSOLE ??= ""
  652. SERIAL_CONSOLES ??= "${@d.getVar('SERIAL_CONSOLE').replace(' ', ';')}"
  653. NO_RECOMMENDATIONS ?= ""
  654. BAD_RECOMMENDATIONS ?= ""
  655. # Make sure MACHINE isn't exported
  656. # (breaks binutils at least)
  657. MACHINE[unexport] = "1"
  658. # Make sure TARGET_ARCH isn't exported
  659. # (breaks Makefiles using implicit rules, e.g. quilt, as GNU make has this
  660. # in them, undocumented)
  661. TARGET_ARCH[unexport] = "1"
  662. # Make sure DISTRO isn't exported
  663. # (breaks sysvinit at least)
  664. DISTRO[unexport] = "1"
  665. # Make sure SHELL isn't exported
  666. # (can break any number of things if the user's shell isn't POSIX-compliant,
  667. # including the flock command). The user's shell shouldn't affect our builds.
  668. SHELL[unexport] = "1"
  669. # Used by canadian-cross to handle string conversions on TARGET_ARCH where needed
  670. TRANSLATED_TARGET_ARCH ??= "${@d.getVar('TARGET_ARCH').replace("_", "-")}"
  671. # Complete output from bitbake
  672. BB_CONSOLELOG ?= "${LOG_DIR}/cooker/${MACHINE}/${DATETIME}.log"
  673. # Setup our default hash policy
  674. BB_SIGNATURE_HANDLER ?= "OEBasicHash"
  675. BB_HASHBASE_WHITELIST ?= "TMPDIR FILE PATH PWD BB_TASKHASH BBPATH BBSERVER DL_DIR \
  676. SSTATE_DIR THISDIR FILESEXTRAPATHS FILE_DIRNAME HOME LOGNAME SHELL TERM \
  677. USER FILESPATH STAGING_DIR_HOST STAGING_DIR_TARGET COREBASE PRSERV_HOST \
  678. PRSERV_DUMPDIR PRSERV_DUMPFILE PRSERV_LOCKDOWN PARALLEL_MAKE \
  679. CCACHE_DIR EXTERNAL_TOOLCHAIN CCACHE CCACHE_DISABLE LICENSE_PATH SDKPKGSUFFIX \
  680. WARN_QA ERROR_QA WORKDIR STAMPCLEAN PKGDATA_DIR BUILD_ARCH SSTATE_PKGARCH \
  681. BB_WORKERCONTEXT"
  682. BB_HASHCONFIG_WHITELIST ?= "${BB_HASHBASE_WHITELIST} DATE TIME SSH_AGENT_PID \
  683. SSH_AUTH_SOCK PSEUDO_BUILD BB_ENV_EXTRAWHITE DISABLE_SANITY_CHECKS \
  684. PARALLEL_MAKE BB_NUMBER_THREADS BB_ORIGENV BB_INVALIDCONF BBINCLUDED \
  685. GIT_PROXY_COMMAND ALL_PROXY all_proxy NO_PROXY no_proxy FTP_PROXY ftp_proxy \
  686. HTTP_PROXY http_proxy HTTPS_PROXY https_proxy SOCKS5_USER SOCKS5_PASSWD \
  687. BB_SETSCENE_ENFORCE"
  688. BB_SIGNATURE_EXCLUDE_FLAGS ?= "doc deps depends \
  689. lockfiles type vardepsexclude vardeps vardepvalue vardepvalueexclude \
  690. file-checksums python func task export unexport noexec nostamp dirs cleandirs \
  691. sstate-lockfile-shared prefuncs postfuncs export_func deptask rdeptask \
  692. recrdeptask nodeprrecs stamp-extra-info sstate-outputdirs filename lineno \
  693. progress"
  694. MLPREFIX ??= ""
  695. MULTILIB_VARIANTS ??= ""