git.inc 4.8 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149
  1. SUMMARY = "Distributed version control system"
  2. HOMEPAGE = "http://git-scm.com"
  3. SECTION = "console/utils"
  4. LICENSE = "GPLv2"
  5. DEPENDS = "openssl curl zlib expat"
  6. PROVIDES_append_class-native = " git-replacement-native"
  7. SRC_URI = "${KERNELORG_MIRROR}/software/scm/git/git-${PV}.tar.gz;name=tarball \
  8. ${KERNELORG_MIRROR}/software/scm/git/git-manpages-${PV}.tar.gz;name=manpages \
  9. file://CVE-2018-11235.patch \
  10. file://CVE-2018-11233.patch"
  11. S = "${WORKDIR}/git-${PV}"
  12. LIC_FILES_CHKSUM = "file://COPYING;md5=7c0d7ef03a7eb04ce795b0f60e68e7e1"
  13. CVE_PRODUCT = "git-scm:git"
  14. PACKAGECONFIG ??= ""
  15. PACKAGECONFIG[cvsserver] = ""
  16. PACKAGECONFIG[svn] = ""
  17. EXTRA_OECONF = "--with-perl=${STAGING_BINDIR_NATIVE}/perl-native/perl \
  18. --without-tcltk \
  19. "
  20. # Needs brokensep as this doesn't use automake
  21. inherit autotools-brokensep perlnative bash-completion
  22. EXTRA_OEMAKE = "NO_PYTHON=1 CFLAGS='${CFLAGS}' LDFLAGS='${LDFLAGS}'"
  23. EXTRA_OEMAKE += "'PERL_PATH=/usr/bin/env perl'"
  24. EXTRA_OEMAKE_append_class-native = " NO_CROSS_DIRECTORY_HARDLINKS=1"
  25. do_compile_prepend () {
  26. # Remove perl/perl.mak to fix the out-of-date perl.mak error
  27. # during rebuild
  28. rm -f perl/perl.mak
  29. }
  30. do_install () {
  31. oe_runmake install DESTDIR="${D}" bindir=${bindir} \
  32. template_dir=${datadir}/git-core/templates
  33. install -d ${D}/${mandir}/man1
  34. install -d ${D}/${mandir}/man5
  35. install -d ${D}/${mandir}/man7
  36. install -t ${D}/${mandir}/man1 ${WORKDIR}/man1/*
  37. install -t ${D}/${mandir}/man5 ${WORKDIR}/man5/*
  38. install -t ${D}/${mandir}/man7 ${WORKDIR}/man7/*
  39. install -d ${D}/${datadir}/bash-completion/completions/
  40. install -m 644 ${S}/contrib/completion/git-completion.bash ${D}/${datadir}/bash-completion/completions/git
  41. }
  42. perl_native_fixup () {
  43. sed -i -e 's#${STAGING_BINDIR_NATIVE}/perl-native/#${bindir}/#' \
  44. -e 's#${libdir}/perl-native/#${libdir}/#' \
  45. ${@d.getVar("PERLTOOLS").replace(' /',d.getVar('D') + '/')}
  46. # ${libdir} is not applicable here, perl-native files are always
  47. # installed to /usr/lib on both 32/64 bits targets.
  48. mkdir -p ${D}${libdir}
  49. mv ${D}${exec_prefix}/lib/perl-native/perl ${D}${libdir}
  50. rmdir -p ${D}${exec_prefix}/lib/perl-native || true
  51. if [ ! "${@bb.utils.filter('PACKAGECONFIG', 'cvsserver', d)}" ]; then
  52. # Only install the git cvsserver command if explicitly requested
  53. # as it requires the DBI Perl module, which does not exist in
  54. # OE-Core.
  55. rm ${D}${libexecdir}/git-core/git-cvsserver \
  56. ${D}${bindir}/git-cvsserver
  57. fi
  58. if [ ! "${@bb.utils.filter('PACKAGECONFIG', 'svn', d)}" ]; then
  59. # Only install the git svn command and all Git::SVN Perl modules
  60. # if explicitly requested as they require the SVN::Core Perl
  61. # module, which does not exist in OE-Core.
  62. rm -r ${D}${libexecdir}/git-core/git-svn \
  63. ${D}${libdir}/perl/site_perl/*/Git/SVN*
  64. sed -i -e '/SVN/d' ${D}${libdir}/perl/site_perl/*/auto/Git/.packlist
  65. fi
  66. }
  67. REL_GIT_EXEC_PATH = "${@os.path.relpath(libexecdir, bindir)}/git-core"
  68. REL_GIT_TEMPLATE_DIR = "${@os.path.relpath(datadir, bindir)}/git-core/templates"
  69. do_install_append_class-target () {
  70. perl_native_fixup
  71. }
  72. do_install_append_class-native() {
  73. create_wrapper ${D}${bindir}/git \
  74. GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \
  75. GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR}
  76. }
  77. do_install_append_class-nativesdk() {
  78. create_wrapper ${D}${bindir}/git \
  79. GIT_EXEC_PATH='`dirname $''realpath`'/${REL_GIT_EXEC_PATH} \
  80. GIT_TEMPLATE_DIR='`dirname $''realpath`'/${REL_GIT_TEMPLATE_DIR}
  81. perl_native_fixup
  82. }
  83. FILES_${PN} += "${datadir}/git-core ${libexecdir}/git-core/"
  84. PERLTOOLS = " \
  85. ${libexecdir}/git-core/git-add--interactive \
  86. ${libexecdir}/git-core/git-archimport \
  87. ${libexecdir}/git-core/git-cvsexportcommit \
  88. ${libexecdir}/git-core/git-cvsimport \
  89. ${libexecdir}/git-core/git-cvsserver \
  90. ${bindir}/git-cvsserver \
  91. ${libexecdir}/git-core/git-difftool \
  92. ${libexecdir}/git-core/git-send-email \
  93. ${libexecdir}/git-core/git-svn \
  94. ${libexecdir}/git-core/git-instaweb \
  95. ${libexecdir}/git-core/git-submodule \
  96. ${libexecdir}/git-core/git-am \
  97. ${libexecdir}/git-core/git-request-pull \
  98. ${datadir}/gitweb/gitweb.cgi \
  99. ${datadir}/git-core/templates/hooks/prepare-commit-msg.sample \
  100. ${datadir}/git-core/templates/hooks/pre-rebase.sample \
  101. ${datadir}/git-core/templates/hooks/fsmonitor-watchman.sample \
  102. "
  103. # Git tools requiring perl
  104. PACKAGES =+ "${PN}-perltools"
  105. FILES_${PN}-perltools += " \
  106. ${PERLTOOLS} \
  107. ${libdir}/perl \
  108. ${datadir}/perl \
  109. "
  110. RDEPENDS_${PN}-perltools = "${PN} perl perl-module-file-path findutils"
  111. # git-tk package with gitk and git-gui
  112. PACKAGES =+ "${PN}-tk"
  113. #RDEPENDS_${PN}-tk = "${PN} tk tcl"
  114. #EXTRA_OEMAKE = "TCL_PATH=${STAGING_BINDIR_CROSS}/tclsh"
  115. FILES_${PN}-tk = " \
  116. ${bindir}/gitk \
  117. ${datadir}/gitk \
  118. "
  119. PACKAGES =+ "gitweb"
  120. FILES_gitweb = "${datadir}/gitweb/"
  121. RDEPENDS_gitweb = "perl"
  122. BBCLASSEXTEND = "native nativesdk"