kbd_2.2.0.bb 2.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172
  1. SUMMARY = "Keytable files and keyboard utilities"
  2. HOMEPAGE = "http://www.kbd-project.org/"
  3. # everything minus console-fonts is GPLv2+
  4. LICENSE = "GPLv2+"
  5. LIC_FILES_CHKSUM = "file://COPYING;md5=892f569a555ba9c07a568a7c0c4fa63a"
  6. inherit autotools gettext ptest pkgconfig
  7. DEPENDS += "flex-native"
  8. RREPLACES_${PN} = "console-tools"
  9. RPROVIDES_${PN} = "console-tools"
  10. RCONFLICTS_${PN} = "console-tools"
  11. SRC_URI = "${KERNELORG_MIRROR}/linux/utils/${BPN}/${BP}.tar.xz \
  12. file://run-ptest \
  13. ${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'file://set-proper-path-of-resources.patch', '', d)} \
  14. file://0001-analyze.l-add-missing-string-format.patch \
  15. file://0001-Use-DATADIR-and-append-i386-to-fix-libkbdfile-test08.patch \
  16. file://fix_cflags.patch \
  17. "
  18. SRC_URI[md5sum] = "d1d7ae0b5fb875dc082731e09cd0c8bc"
  19. SRC_URI[sha256sum] = "21a1bc5f6fb3b18ce9fdd717e4533368060a3182a39c7155eaf7ec0f5f83e9f7"
  20. PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)} \
  21. ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests','', d)} \
  22. "
  23. PACKAGECONFIG[pam] = "--enable-vlock, --disable-vlock, libpam,"
  24. PACKAGECONFIG[tests] = "--enable-tests, --disable-tests, libcheck"
  25. do_compile_ptest() {
  26. oe_runmake -C ${B}/tests alt-is-meta dumpkeys-bkeymap dumpkeys-fulltable dumpkeys-mktable
  27. }
  28. do_install_ptest() {
  29. install -D ${B}/tests/Makefile ${D}${PTEST_PATH}/tests/Makefile
  30. sed -i -e '/Makefile:/,/^$/d' -e '/%: %.in/,/^$/d' \
  31. -e 's:--sysroot=${STAGING_DIR_TARGET}::g' \
  32. -e 's:${DEBUG_PREFIX_MAP}::g' \
  33. -e 's:${HOSTTOOLS_DIR}/::g' \
  34. -e 's:${RECIPE_SYSROOT_NATIVE}::g' \
  35. -e 's:${RECIPE_SYSROOT}::g' \
  36. -e 's:${S}/config/missing::g' \
  37. -e 's:${WORKDIR}::g' \
  38. -e '/^lib.*_SOURCES =/d' -e '/$(EXEEXT):/,/^$/d' ${D}${PTEST_PATH}/tests/Makefile
  39. find ${B}/tests -executable -exec install {} ${D}${PTEST_PATH}/tests \;
  40. cp -rf ${S}/tests/data ${D}${PTEST_PATH}/tests
  41. cp -rf ${S}/tests/findfile ${D}${PTEST_PATH}/tests
  42. cp -rf ${S}/data ${D}${PTEST_PATH}
  43. install -D -m 755 ${S}/config/test-driver ${D}${PTEST_PATH}/config/test-driver
  44. }
  45. PACKAGES += "${PN}-consolefonts ${PN}-keymaps ${PN}-unimaps ${PN}-consoletrans"
  46. FILES_${PN}-consolefonts = "${datadir}/consolefonts"
  47. FILES_${PN}-consoletrans = "${datadir}/consoletrans"
  48. FILES_${PN}-keymaps = "${datadir}/keymaps"
  49. FILES_${PN}-unimaps = "${datadir}/unimaps"
  50. RDEPENDS_${PN}-ptest = "make"
  51. inherit update-alternatives
  52. ALTERNATIVE_${PN} = "chvt deallocvt fgconsole openvt showkey \
  53. ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'vlock','', d)}"
  54. ALTERNATIVE_PRIORITY = "100"
  55. BBCLASSEXTEND = "native"