webkitgtk_2.30.2.bb 6.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135
  1. SUMMARY = "WebKit web rendering engine for the GTK+ platform"
  2. HOMEPAGE = "https://www.webkitgtk.org/"
  3. BUGTRACKER = "https://bugs.webkit.org/"
  4. LICENSE = "BSD & LGPLv2+"
  5. LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \
  6. file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \
  7. file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \
  8. file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \
  9. "
  10. SRC_URI = "https://www.webkitgtk.org/releases/${BPN}-${PV}.tar.xz \
  11. file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \
  12. file://0001-When-building-introspection-files-add-CMAKE_C_FLAGS-.patch \
  13. file://0001-Fix-racy-parallel-build-of-WebKit2-4.0.gir.patch \
  14. file://0001-Tweak-gtkdoc-settings-so-that-gtkdoc-generation-work.patch \
  15. file://0001-Enable-THREADS_PREFER_PTHREAD_FLAG.patch \
  16. file://0001-Fix-build-with-musl.patch \
  17. file://include_array.patch \
  18. file://include_xutil.patch \
  19. "
  20. SRC_URI[sha256sum] = "c467e0bc2bc610c2570928e3fd63cedaadc4719cbf9b04aa99f79dd71ad5682a"
  21. inherit cmake pkgconfig gobject-introspection perlnative features_check upstream-version-is-even gtk-doc
  22. ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
  23. REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'opengl', '', d)}"
  24. CVE_PRODUCT = "webkitgtk webkitgtk\+"
  25. DEPENDS = "zlib libsoup-2.4 curl libxml2 cairo libxslt libgcrypt \
  26. gtk+3 gstreamer1.0 gstreamer1.0-plugins-base flex-native gperf-native sqlite3 \
  27. pango icu bison-native gawk intltool-native libwebp \
  28. atk udev harfbuzz jpeg libpng librsvg libtheora libvorbis \
  29. ruby-native libnotify gstreamer1.0-plugins-bad \
  30. gettext-native glib-2.0 glib-2.0-native libtasn1 \
  31. "
  32. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd wayland x11', d)} \
  33. ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'webgl opengl', '', d)} \
  34. ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', 'webgl gles2', d)} \
  35. enchant \
  36. libsecret \
  37. "
  38. PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland libwpe wpebackend-fdo wayland-native"
  39. PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11 libxcomposite libxdamage libxrender libxt"
  40. PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue"
  41. PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant2"
  42. PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2"
  43. PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/libgl"
  44. PACKAGECONFIG[opengl] = "-DENABLE_GRAPHICS_CONTEXT_GL=ON,-DENABLE_GRAPHICS_CONTEXT_GL=OFF,virtual/libgl"
  45. PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret"
  46. PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen"
  47. PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2"
  48. PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg"
  49. PACKAGECONFIG[systemd] = "-DUSE_SYSTEMD=ON,-DUSE_SYSTEMD=off,systemd"
  50. # webkitgtk is full of /usr/bin/env python, particular for generating docs
  51. do_configure[postfuncs] += "setup_python_link"
  52. setup_python_link() {
  53. if [ ! -e ${STAGING_BINDIR_NATIVE}/python ]; then
  54. ln -s `which python3` ${STAGING_BINDIR_NATIVE}/python
  55. fi
  56. }
  57. EXTRA_OECMAKE = " \
  58. -DPORT=GTK \
  59. -DCMAKE_BUILD_TYPE=Release \
  60. ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \
  61. ${@bb.utils.contains('GTKDOC_ENABLED', 'True', '-DENABLE_GTKDOC=ON', '-DENABLE_GTKDOC=OFF', d)} \
  62. -DENABLE_MINIBROWSER=ON \
  63. -DPYTHON_EXECUTABLE=`which python3` \
  64. -DENABLE_BUBBLEWRAP_SANDBOX=OFF \
  65. "
  66. # Javascript JIT is not supported on ARC
  67. EXTRA_OECMAKE_append_arc = " -DENABLE_JIT=OFF "
  68. # By default 25-bit "medium" calls are used on ARC
  69. # which is not enough for binaries larger than 32 MiB
  70. CFLAGS_append_arc = " -mlong-calls"
  71. CXXFLAGS_append_arc = " -mlong-calls"
  72. # Javascript JIT is not supported on powerpc
  73. EXTRA_OECMAKE_append_powerpc = " -DENABLE_JIT=OFF "
  74. EXTRA_OECMAKE_append_powerpc64 = " -DENABLE_JIT=OFF "
  75. # ARM JIT code does not build on ARMv4/5/6 anymore
  76. EXTRA_OECMAKE_append_armv5 = " -DENABLE_JIT=OFF "
  77. EXTRA_OECMAKE_append_armv6 = " -DENABLE_JIT=OFF "
  78. EXTRA_OECMAKE_append_armv4 = " -DENABLE_JIT=OFF "
  79. EXTRA_OECMAKE_append_mipsarch = " -DUSE_LD_GOLD=OFF "
  80. EXTRA_OECMAKE_append_powerpc = " -DUSE_LD_GOLD=OFF "
  81. # JIT and gold linker does not work on RISCV
  82. EXTRA_OECMAKE_append_riscv32 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF"
  83. EXTRA_OECMAKE_append_riscv64 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF"
  84. # JIT not supported on MIPS either
  85. EXTRA_OECMAKE_append_mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON "
  86. # JIT not supported on X32
  87. # An attempt was made to upstream JIT support for x32 in
  88. # https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as
  89. # unresolved due to limited X32 adoption.
  90. EXTRA_OECMAKE_append_x86-x32 = " -DENABLE_JIT=OFF "
  91. SECURITY_CFLAGS_remove_aarch64 = "-fpie"
  92. SECURITY_CFLAGS_append_aarch64 = " -fPIE"
  93. FILES_${PN} += "${libdir}/webkit2gtk-4.0/injected-bundle/libwebkit2gtkinjectedbundle.so"
  94. RRECOMMENDS_${PN} += "ca-certificates shared-mime-info"
  95. # http://errors.yoctoproject.org/Errors/Details/20370/
  96. ARM_INSTRUCTION_SET_armv4 = "arm"
  97. ARM_INSTRUCTION_SET_armv5 = "arm"
  98. ARM_INSTRUCTION_SET_armv6 = "arm"
  99. # https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474
  100. # https://bugs.webkit.org/show_bug.cgi?id=159880
  101. # JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime.
  102. # Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb).
  103. ARM_INSTRUCTION_SET_armv7a = "thumb"
  104. ARM_INSTRUCTION_SET_armv7r = "thumb"
  105. ARM_INSTRUCTION_SET_armv7ve = "thumb"
  106. # introspection inside qemu-arm hangs forever on musl/arm builds
  107. # therefore disable GI_DATA
  108. GI_DATA_ENABLED_libc-musl_armv7a = "False"
  109. GI_DATA_ENABLED_libc-musl_armv7ve = "False"
  110. # Can't be built with ccache
  111. CCACHE_DISABLE = "1"