glew_2.1.0.bb 1.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445
  1. SUMMARY = "OpenGL extension loading library"
  2. DESCRIPTION = "The OpenGL Extension Wrangler Library (GLEW) is a cross-platform open-source C/C++ extension loading library."
  3. HOMEPAGE = "http://glew.sourceforge.net/"
  4. BUGTRACKER = "http://sourceforge.net/tracker/?group_id=67586"
  5. LICENSE = "MIT"
  6. LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=2ac251558de685c6b9478d89be3149c2"
  7. SRC_URI = "${SOURCEFORGE_MIRROR}/project/glew/glew/${PV}/glew-${PV}.tgz \
  8. file://no-strip.patch \
  9. file://0001-Fixed-compilation-with-current-mesa-versions.patch"
  10. SRC_URI[md5sum] = "b2ab12331033ddfaa50dc39345343980"
  11. SRC_URI[sha256sum] = "04de91e7e6763039bc11940095cd9c7f880baba82196a7765f727ac05a993c95"
  12. UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/glew/files/glew"
  13. UPSTREAM_CHECK_REGEX = "/glew/(?P<pver>(\d+[\.\-_]*)+)/"
  14. inherit lib_package pkgconfig features_check
  15. REQUIRED_DISTRO_FEATURES = "opengl"
  16. PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'opengl', 'egl-gles2', d)}"
  17. # The opengl and egl-XXX options are exclusive, enable only one.
  18. PACKAGECONFIG[opengl] = "SYSTEM='linux',,virtual/libx11 virtual/libgl libglu libxext libxi libxmu"
  19. PACKAGECONFIG[egl-gles2] = "SYSTEM='linux-egl' GLEW_NO_GLU='-DGLEW_NO_GLU' LDFLAGS.GL='-lEGL -lGLESv2',,virtual/egl virtual/libgles2"
  20. CFLAGS += "-D_GNU_SOURCE"
  21. # Override SYSTEM (via PACKAGECONFIG_CONFARGS) to avoid calling config.guess,
  22. # we're cross-compiling. Pass our CFLAGS via POPT as that's the optimisation
  23. # variable and safely overwritten.
  24. EXTRA_OEMAKE = "${PACKAGECONFIG_CONFARGS} \
  25. CC='${CC}' LD='${CC}' STRIP='' \
  26. LDFLAGS.EXTRA='${LDFLAGS}' \
  27. POPT='${CFLAGS}' \
  28. GLEW_PREFIX='${prefix}' BINDIR='${bindir}' \
  29. LIBDIR='${libdir}' INCDIR='${includedir}/GL' PKGDIR='${libdir}/pkgconfig'"
  30. do_compile() {
  31. oe_runmake
  32. }
  33. do_install() {
  34. oe_runmake 'DESTDIR=${D}' install.all
  35. }