mesa.inc 14 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318
  1. SUMMARY = "A free implementation of the OpenGL API"
  2. DESCRIPTION = "Mesa is an open-source implementation of the OpenGL specification - \
  3. a system for rendering interactive 3D graphics. \
  4. A variety of device drivers allows Mesa to be used in many different environments \
  5. ranging from software emulation to complete hardware acceleration for modern GPUs. \
  6. Mesa is used as part of the overall Direct Rendering Infrastructure and X.org \
  7. environment."
  8. HOMEPAGE = "http://mesa3d.org"
  9. BUGTRACKER = "https://bugs.freedesktop.org"
  10. SECTION = "x11"
  11. LICENSE = "MIT"
  12. LIC_FILES_CHKSUM = "file://docs/license.rst;md5=9aa1bc48c9826ad9fdb16661f6930496"
  13. PE = "2"
  14. SRC_URI = "https://mesa.freedesktop.org/archive/mesa-${PV}.tar.xz \
  15. file://0001-meson.build-check-for-all-linux-host_os-combinations.patch \
  16. file://0002-meson.build-make-TLS-ELF-optional.patch \
  17. file://0004-Revert-mesa-Enable-asm-unconditionally-now-that-gen_.patch \
  18. file://0005-vc4-use-intmax_t-for-formatted-output-of-timespec-me.patch \
  19. file://0001-meson-misdetects-64bit-atomics-on-mips-clang.patch \
  20. file://0001-futex.h-Define-__NR_futex-if-it-does-not-exist.patch \
  21. file://0001-anv-fix-a-build-race-between-generating-a-header-and.patch \
  22. "
  23. SRC_URI[sha256sum] = "d1a46d9a3f291bc0e0374600bdcb59844fa3eafaa50398e472a36fc65fd0244a"
  24. UPSTREAM_CHECK_GITTAGREGEX = "mesa-(?P<pver>\d+(\.\d+)+)"
  25. #because we cannot rely on the fact that all apps will use pkgconfig,
  26. #make eglplatform.h independent of MESA_EGL_NO_X11_HEADER
  27. do_install_append() {
  28. if ${@bb.utils.contains('PACKAGECONFIG', 'egl', 'true', 'false', d)}; then
  29. if [ -f ${D}${includedir}/EGL/eglplatform.h ]; then
  30. sed -i -e 's/^#elif defined(__unix__) && defined(EGL_NO_X11)$/#elif defined(__unix__) \&\& defined(EGL_NO_X11) || ${@bb.utils.contains('PACKAGECONFIG', 'x11', '0', '1', d)}/' ${D}${includedir}/EGL/eglplatform.h
  31. fi
  32. fi
  33. }
  34. DEPENDS = "expat makedepend-native flex-native bison-native libxml2-native zlib chrpath-replacement-native python3-mako-native gettext-native"
  35. EXTRANATIVEPATH += "chrpath-native"
  36. PROVIDES = " \
  37. ${@bb.utils.contains('PACKAGECONFIG', 'opengl', 'virtual/libgl', '', d)} \
  38. ${@bb.utils.contains('PACKAGECONFIG', 'gles', 'virtual/libgles1 virtual/libgles2', '', d)} \
  39. ${@bb.utils.contains('PACKAGECONFIG', 'egl', 'virtual/egl', '', d)} \
  40. ${@bb.utils.contains('PACKAGECONFIG', 'gbm', 'virtual/libgbm', '', d)} \
  41. virtual/mesa \
  42. "
  43. inherit meson pkgconfig python3native gettext features_check
  44. # Unset these to stop python trying to report the target Python setup
  45. _PYTHON_SYSCONFIGDATA_NAME[unexport] = "1"
  46. STAGING_INCDIR[unexport] = "1"
  47. STAGING_LIBDIR[unexport] = "1"
  48. BBCLASSEXTEND = "native nativesdk"
  49. ANY_OF_DISTRO_FEATURES_class-target = "opengl vulkan"
  50. PLATFORMS ??= "${@bb.utils.filter('PACKAGECONFIG', 'x11 wayland', d)} \
  51. ${@bb.utils.contains('PACKAGECONFIG', 'gbm', 'drm', '', d)} \
  52. surfaceless"
  53. export YOCTO_ALTERNATE_EXE_PATH = "${STAGING_LIBDIR}/llvm${MESA_LLVM_RELEASE}/llvm-config"
  54. export YOCTO_ALTERNATE_MULTILIB_NAME = "${base_libdir}"
  55. export LLVM_CONFIG = "${STAGING_BINDIR_NATIVE}/llvm-config${MESA_LLVM_RELEASE}"
  56. export WANT_LLVM_RELEASE = "${MESA_LLVM_RELEASE}"
  57. MESA_LLVM_RELEASE ?= "${LLVMVERSION}"
  58. # set the MESA_BUILD_TYPE to either 'release' (default) or 'debug'
  59. # by default the upstream mesa sources build a debug release
  60. # here we assume the user will want a release build by default
  61. MESA_BUILD_TYPE ?= "release"
  62. def check_buildtype(d):
  63. _buildtype = d.getVar('MESA_BUILD_TYPE')
  64. if _buildtype not in ['release', 'debug']:
  65. bb.fatal("unknown build type (%s), please set MESA_BUILD_TYPE to either 'release' or 'debug'" % _buildtype)
  66. if _buildtype == 'debug':
  67. return 'debugoptimized'
  68. return 'plain'
  69. MESON_BUILDTYPE = "${@check_buildtype(d)}"
  70. EXTRA_OEMESON = " \
  71. -Dshared-glapi=true \
  72. -Dgallium-opencl=disabled \
  73. -Dglx-read-only-text=true \
  74. -Dplatforms='${@",".join("${PLATFORMS}".split())}' \
  75. "
  76. def strip_comma(s):
  77. return s.strip(',')
  78. PACKAGECONFIG_class-target ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland vulkan', d)} \
  79. ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl egl gles gbm dri gallium virgl', '', d)} \
  80. ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'x11 dri3', '', d)} \
  81. ${@bb.utils.contains('DISTRO_FEATURES', 'x11 vulkan', 'dri3', '', d)} \
  82. elf-tls \
  83. "
  84. PACKAGECONFIG_class-native ?= "gbm dri egl opengl elf-tls x11"
  85. PACKAGECONFIG_class-nativesdk ?= "gbm dri egl opengl elf-tls x11"
  86. PACKAGECONFIG_remove_libc-musl = "elf-tls"
  87. # "gbm" requires "dri", "opengl"
  88. PACKAGECONFIG[gbm] = "-Dgbm=true,-Dgbm=false"
  89. X11_DEPS = "xorgproto virtual/libx11 libxext libxxf86vm libxdamage libxfixes xrandr"
  90. # "x11" requires "opengl"
  91. PACKAGECONFIG[x11] = ",-Dglx=disabled,${X11_DEPS}"
  92. PACKAGECONFIG[elf-tls] = "-Delf-tls=true, -Delf-tls=false"
  93. PACKAGECONFIG[xvmc] = "-Dgallium-xvmc=true,-Dgallium-xvmc=false,libxvmc"
  94. PACKAGECONFIG[wayland] = ",,wayland-native wayland libdrm wayland-protocols"
  95. DRIDRIVERS_class-native = "swrast"
  96. DRIDRIVERS_class-nativesdk = "swrast"
  97. DRIDRIVERS_append_x86_class-target = ",r100,r200,nouveau,i965,i915"
  98. DRIDRIVERS_append_x86-64_class-target = ",r100,r200,nouveau,i965,i915"
  99. # "dri" requires "opengl"
  100. PACKAGECONFIG[dri] = "-Ddri-drivers=${@strip_comma('${DRIDRIVERS}')}, -Ddri-drivers='', xorgproto libdrm"
  101. PACKAGECONFIG[dri3] = "-Ddri3=true, -Ddri3=false, xorgproto libxshmfence"
  102. # Vulkan drivers need dri3 enabled
  103. # amd could be enabled as well but requires gallium-llvm with llvm >= 3.9
  104. VULKAN_DRIVERS = ""
  105. VULKAN_DRIVERS_append_x86_class-target = ",intel"
  106. VULKAN_DRIVERS_append_x86-64_class-target = ",intel"
  107. VULKAN_DRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'freedreno', ',freedreno', '', d)}"
  108. PACKAGECONFIG[vulkan] = "-Dvulkan-drivers=${@strip_comma('${VULKAN_DRIVERS}')}, -Dvulkan-drivers='',"
  109. PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=false"
  110. # "gles" requires "opengl"
  111. PACKAGECONFIG[gles] = "-Dgles1=true -Dgles2=true, -Dgles1=false -Dgles2=false"
  112. # "egl" requires "dri", "opengl"
  113. PACKAGECONFIG[egl] = "-Degl=true, -Degl=false"
  114. PACKAGECONFIG[etnaviv] = ""
  115. PACKAGECONFIG[freedreno] = ""
  116. PACKAGECONFIG[kmsro] = ""
  117. PACKAGECONFIG[vc4] = ""
  118. PACKAGECONFIG[v3d] = ""
  119. GALLIUMDRIVERS = "swrast"
  120. # gallium swrast was found to crash Xorg on startup in x32 qemu
  121. GALLIUMDRIVERS_x86-x32 = ""
  122. GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'etnaviv', ',etnaviv', '', d)}"
  123. GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'freedreno', ',freedreno', '', d)}"
  124. GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'kmsro', ',kmsro', '', d)}"
  125. GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'vc4', ',vc4', '', d)}"
  126. GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'v3d', ',v3d', '', d)}"
  127. # radeonsi requires LLVM
  128. GALLIUMDRIVERS_RADEONSI = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',radeonsi', '', d)}"
  129. GALLIUMDRIVERS_LLVM = "r300,svga,nouveau${GALLIUMDRIVERS_RADEONSI}"
  130. PACKAGECONFIG[r600] = ""
  131. PACKAGECONFIG[virgl] = ""
  132. GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'gallium-llvm', ',${GALLIUMDRIVERS_LLVM}', '', d)}"
  133. GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',r600', '', d)}"
  134. GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'virgl', ',virgl', '', d)}"
  135. PACKAGECONFIG[gallium] = "-Dgallium-drivers=${@strip_comma('${GALLIUMDRIVERS}')}, -Dgallium-drivers=''"
  136. PACKAGECONFIG[gallium-llvm] = "-Dllvm=true -Dshared-llvm=true, -Dllvm=false, llvm${MESA_LLVM_RELEASE} llvm-native \
  137. elfutils"
  138. PACKAGECONFIG[xa] = "-Dgallium-xa=true, -Dgallium-xa=false"
  139. PACKAGECONFIG[va] = "-Dgallium-va=true,-Dgallium-va=false,libva-initial"
  140. PACKAGECONFIG[vdpau] = "-Dgallium-vdpau=true,-Dgallium-vdpau=false,libvdpau"
  141. PACKAGECONFIG[lima] = ""
  142. GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'lima', ',lima', '', d)}"
  143. PACKAGECONFIG[panfrost] = ""
  144. GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'panfrost', ',panfrost', '', d)}"
  145. OSMESA = "${@bb.utils.contains('PACKAGECONFIG', 'gallium', 'gallium', 'classic', d)}"
  146. PACKAGECONFIG[osmesa] = "-Dosmesa=${OSMESA},-Dosmesa=none"
  147. PACKAGECONFIG[unwind] = "-Dlibunwind=true,-Dlibunwind=false,libunwind"
  148. # mesa tries to run cross-built gen_matypes on build machine to get struct size information
  149. EXTRA_OEMESON_append = " -Dasm=false"
  150. # llvmpipe is slow if compiled with -fomit-frame-pointer (e.g. -O2)
  151. FULL_OPTIMIZATION_append = " -fno-omit-frame-pointer"
  152. CFLAGS_append_armv5 = " -DMISSING_64BIT_ATOMICS"
  153. CFLAGS_append_armv6 = " -DMISSING_64BIT_ATOMICS"
  154. # Remove the mesa dependency on mesa-dev, as mesa is empty
  155. RDEPENDS_${PN}-dev = ""
  156. # Add dependency so that GLES3 header don't need to be added manually
  157. RDEPENDS_libgles2-mesa-dev += "libgles3-mesa-dev"
  158. PACKAGES =+ "libegl-mesa libegl-mesa-dev \
  159. libosmesa libosmesa-dev \
  160. libgl-mesa libgl-mesa-dev \
  161. libglapi libglapi-dev \
  162. libgbm libgbm-dev \
  163. libgles1-mesa libgles1-mesa-dev \
  164. libgles2-mesa libgles2-mesa-dev \
  165. libgles3-mesa libgles3-mesa-dev \
  166. libxatracker libxatracker-dev \
  167. mesa-megadriver mesa-vulkan-drivers \
  168. mesa-vdpau-drivers \
  169. "
  170. do_install_append () {
  171. # Drivers never need libtool .la files
  172. rm -f ${D}${libdir}/dri/*.la
  173. rm -f ${D}${libdir}/egl/*.la
  174. rm -f ${D}${libdir}/gallium-pipe/*.la
  175. rm -f ${D}${libdir}/gbm/*.la
  176. # it was packaged in libdricore9.1.3-1 and preventing upgrades when debian.bbclass was used
  177. chrpath --delete ${D}${libdir}/dri/*_dri.so || true
  178. # libwayland-egl has been moved to wayland 1.15+
  179. rm -f ${D}${libdir}/libwayland-egl*
  180. rm -f ${D}${libdir}/pkgconfig/wayland-egl.pc
  181. }
  182. # For the packages that make up the OpenGL interfaces, inject variables so that
  183. # they don't get Debian-renamed (which would remove the -mesa suffix), and
  184. # RPROVIDEs/RCONFLICTs on the generic libgl name.
  185. python __anonymous() {
  186. pkgconfig = (d.getVar('PACKAGECONFIG') or "").split()
  187. for p in (("egl", "libegl", "libegl1"),
  188. ("dri", "libgl", "libgl1"),
  189. ("gles", "libgles1", "libglesv1-cm1"),
  190. ("gles", "libgles2", "libglesv2-2"),
  191. ("gles", "libgles3",)):
  192. if not p[0] in pkgconfig:
  193. continue
  194. mlprefix = d.getVar("MLPREFIX")
  195. fullp = mlprefix + p[1] + "-mesa"
  196. mlprefix = d.getVar("MLPREFIX")
  197. pkgs = " ".join(mlprefix + x for x in p[1:])
  198. d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
  199. d.appendVar("RREPLACES_" + fullp, pkgs)
  200. d.appendVar("RPROVIDES_" + fullp, pkgs)
  201. d.appendVar("RCONFLICTS_" + fullp, pkgs)
  202. d.appendVar("RRECOMMENDS_" + fullp, " ${MLPREFIX}mesa-megadriver")
  203. # For -dev, the first element is both the Debian and original name
  204. fullp += "-dev"
  205. pkgs = mlprefix + p[1] + "-dev"
  206. d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
  207. d.appendVar("RREPLACES_" + fullp, pkgs)
  208. d.appendVar("RPROVIDES_" + fullp, pkgs)
  209. d.appendVar("RCONFLICTS_" + fullp, pkgs)
  210. }
  211. python mesa_populate_packages() {
  212. pkgs = ['mesa', 'mesa-dev', 'mesa-dbg']
  213. for pkg in pkgs:
  214. d.setVar("RPROVIDES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
  215. d.setVar("RCONFLICTS_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
  216. d.setVar("RREPLACES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
  217. import re
  218. dri_drivers_root = oe.path.join(d.getVar('PKGD'), d.getVar('libdir'), "dri")
  219. if os.path.isdir(dri_drivers_root):
  220. dri_pkgs = os.listdir(dri_drivers_root)
  221. lib_name = d.expand("${MLPREFIX}mesa-megadriver")
  222. for p in dri_pkgs:
  223. m = re.match(r'^(.*)_dri\.so$', p)
  224. if m:
  225. pkg_name = " ${MLPREFIX}mesa-driver-%s" % legitimize_package_name(m.group(1))
  226. d.appendVar("RPROVIDES_%s" % lib_name, pkg_name)
  227. d.appendVar("RCONFLICTS_%s" % lib_name, pkg_name)
  228. d.appendVar("RREPLACES_%s" % lib_name, pkg_name)
  229. pipe_drivers_root = os.path.join(d.getVar('libdir'), "gallium-pipe")
  230. do_split_packages(d, pipe_drivers_root, r'^pipe_(.*)\.so$', 'mesa-driver-pipe-%s', 'Mesa %s pipe driver', extra_depends='')
  231. }
  232. PACKAGESPLITFUNCS_prepend = "mesa_populate_packages "
  233. PACKAGES_DYNAMIC += "^mesa-driver-.*"
  234. FILES_mesa-megadriver = "${libdir}/dri/* ${datadir}/drirc.d/00-mesa-defaults.conf"
  235. FILES_mesa-vulkan-drivers = "${libdir}/libvulkan_*.so ${datadir}/vulkan"
  236. FILES_${PN}-vdpau-drivers = "${libdir}/vdpau/*.so.*"
  237. FILES_libegl-mesa = "${libdir}/libEGL.so.*"
  238. FILES_libgbm = "${libdir}/libgbm.so.*"
  239. FILES_libgles1-mesa = "${libdir}/libGLESv1*.so.*"
  240. FILES_libgles2-mesa = "${libdir}/libGLESv2.so.*"
  241. FILES_libgl-mesa = "${libdir}/libGL.so.*"
  242. FILES_libglapi = "${libdir}/libglapi.so.*"
  243. FILES_libosmesa = "${libdir}/libOSMesa.so.*"
  244. FILES_libxatracker = "${libdir}/libxatracker.so.*"
  245. FILES_${PN}-dev = "${libdir}/pkgconfig/dri.pc ${includedir}/vulkan ${libdir}/vdpau/*.so"
  246. FILES_libegl-mesa-dev = "${libdir}/libEGL.* ${includedir}/EGL ${includedir}/KHR ${libdir}/pkgconfig/egl.pc"
  247. FILES_libgbm-dev = "${libdir}/libgbm.* ${libdir}/pkgconfig/gbm.pc ${includedir}/gbm.h"
  248. FILES_libgl-mesa-dev = "${libdir}/libGL.* ${includedir}/GL ${libdir}/pkgconfig/gl.pc"
  249. FILES_libglapi-dev = "${libdir}/libglapi.*"
  250. FILES_libgles1-mesa-dev = "${libdir}/libGLESv1*.* ${includedir}/GLES ${libdir}/pkgconfig/glesv1*.pc"
  251. FILES_libgles2-mesa-dev = "${libdir}/libGLESv2.* ${includedir}/GLES2 ${libdir}/pkgconfig/glesv2.pc"
  252. FILES_libgles3-mesa-dev = "${includedir}/GLES3"
  253. FILES_libosmesa-dev = "${libdir}/libOSMesa.* ${includedir}/GL/osmesa.h ${libdir}/pkgconfig/osmesa.pc"
  254. FILES_libxatracker-dev = "${libdir}/libxatracker.so ${libdir}/libxatracker.la \
  255. ${includedir}/xa_tracker.h ${includedir}/xa_composite.h ${includedir}/xa_context.h \
  256. ${libdir}/pkgconfig/xatracker.pc"
  257. # Fix upgrade path from mesa to mesa-megadriver
  258. RREPLACES_mesa-megadriver = "mesa"
  259. RCONFLICTS_mesa-megadriver = "mesa"
  260. RPROVIDES_mesa-megadriver = "mesa"