orc_0.4.32.bb 972 B

1234567891011121314151617181920212223242526272829
  1. SUMMARY = "Optimised Inner Loop Runtime Compiler"
  2. HOMEPAGE = "http://gstreamer.freedesktop.org/modules/orc.html"
  3. LICENSE = "BSD-2-Clause & BSD-3-Clause"
  4. LIC_FILES_CHKSUM = "file://COPYING;md5=1400bd9d09e8af56b9ec982b3d85797e"
  5. SRC_URI = "http://gstreamer.freedesktop.org/src/orc/orc-${PV}.tar.xz"
  6. SRC_URI[sha256sum] = "a66e3d8f2b7e65178d786a01ef61f2a0a0b4d0b8370de7ce134ba73da4af18f0"
  7. inherit meson pkgconfig gtk-doc
  8. GTKDOC_MESON_OPTION = "gtk_doc"
  9. GTKDOC_MESON_ENABLE_FLAG = "enabled"
  10. GTKDOC_MESON_DISABLE_FLAG = "disabled"
  11. BBCLASSEXTEND = "native nativesdk"
  12. PACKAGES =+ "orc-examples"
  13. PACKAGES_DYNAMIC += "^liborc-.*"
  14. FILES_orc-examples = "${libdir}/orc/*"
  15. FILES_${PN} = "${bindir}/*"
  16. python populate_packages_prepend () {
  17. libdir = d.expand('${libdir}')
  18. do_split_packages(d, libdir, r'^lib(.*)\.so\.*', 'lib%s', 'ORC %s library', extra_depends='', allow_links=True)
  19. }
  20. do_compile_prepend_class-native () {
  21. sed -i -e 's#/tmp#.#g' ${S}/orc/orccodemem.c
  22. }