build-appliance-image_15.0.0.bb 5.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139
  1. SUMMARY = "An image containing the build system itself"
  2. DESCRIPTION = "An image containing the build system that you can boot and run using either VirtualBox, VMware Player or VMware Workstation."
  3. HOMEPAGE = "http://www.yoctoproject.org/documentation/build-appliance"
  4. LICENSE = "MIT"
  5. LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
  6. IMAGE_INSTALL = "packagegroup-core-boot packagegroup-core-ssh-openssh packagegroup-self-hosted \
  7. kernel-dev kernel-devsrc connman connman-plugin-ethernet dhcp-client \
  8. tzdata python3-pip perl-misc"
  9. IMAGE_FEATURES += "x11-base package-management splash"
  10. # Ensure there's enough space to do a core-image-sato build, with rm_work enabled
  11. IMAGE_ROOTFS_EXTRA_SPACE = "41943040"
  12. # Do a quiet boot with limited console messages
  13. APPEND += "rootfstype=ext4 quiet"
  14. DEPENDS = "zip-native python3-pip-native"
  15. IMAGE_FSTYPES = "wic.vmdk"
  16. inherit core-image module-base setuptools3
  17. SRCREV ?= "ba1fb60b3980c86794f8a4c23e3a984f9e3590e1"
  18. SRC_URI = "git://git.yoctoproject.org/poky;branch=warrior \
  19. file://Yocto_Build_Appliance.vmx \
  20. file://Yocto_Build_Appliance.vmxf \
  21. file://README_VirtualBox_Guest_Additions.txt \
  22. file://README_VirtualBox_Toaster.txt \
  23. "
  24. RECIPE_NO_UPDATE_REASON = "Recipe is recursive and handled as part of the release process"
  25. BA_INCLUDE_SOURCES ??= "0"
  26. IMAGE_CMD_ext4_append () {
  27. # We don't need to reserve much space for root, 0.5% is more than enough
  28. tune2fs -m 0.5 ${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.ext4
  29. }
  30. fakeroot do_populate_poky_src () {
  31. # Because fetch2's git's unpack uses -s cloneflag, the unpacked git repo
  32. # will become invalid in the target.
  33. rm -rf ${WORKDIR}/git/.git
  34. rm -f ${WORKDIR}/git/.gitignore
  35. cp -R ${WORKDIR}/git ${IMAGE_ROOTFS}/home/builder/poky
  36. mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/conf
  37. mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/downloads
  38. if [ ${BA_INCLUDE_SOURCES} != 0 ]; then
  39. cp -RpL ${DL_DIR}/* ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/
  40. # Remove the git2_* tarballs -- this is ok since we still have the git2/.
  41. rm -rf ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/git2_*
  42. fi
  43. # Place the README_VirtualBox_Guest_Additions file in builders home folder.
  44. cp ${WORKDIR}/README_VirtualBox_Guest_Additions.txt ${IMAGE_ROOTFS}/home/builder/
  45. # Place the README_VirtualBox_Toaster file in builders home folder.
  46. cp ${WORKDIR}/README_VirtualBox_Toaster.txt ${IMAGE_ROOTFS}/home/builder/
  47. # Create a symlink, needed for out-of-tree kernel modules build
  48. if [ ! -e ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build ]; then
  49. rm -f ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build
  50. lnr ${IMAGE_ROOTFS}${KERNEL_SRC_PATH} ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build
  51. fi
  52. echo "INHERIT += \"rm_work\"" >> ${IMAGE_ROOTFS}/home/builder/poky/build/conf/auto.conf
  53. echo "export LC_ALL=en_US.utf8" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  54. # Also save (for reference only) the actual SRCREV used to create this image
  55. echo "export BA_SRCREV=${SRCREV}" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  56. echo "" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  57. echo 'export PATH=$PATH:/sbin' >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  58. echo "" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  59. echo "# If working behind a proxy and using the provided oe-git-proxy script" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  60. echo "# you need to set ALL_PROXY based on your proxy settings." >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  61. echo "# Example ALL_PROXY values:" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  62. echo "# export ALL_PROXY=https://proxy.example.com:8080" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  63. echo "# export ALL_PROXY=socks://socks.example.com:1080" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  64. chown -R builder:builder ${IMAGE_ROOTFS}/home/builder/poky
  65. chmod -R ug+rw ${IMAGE_ROOTFS}/home/builder/poky
  66. # Assume we will need CDROM to install guest additions
  67. mkdir -p ${IMAGE_ROOTFS}/media/cdrom
  68. # Allow builder to use sudo
  69. echo "builder ALL=(ALL) NOPASSWD: ALL" >> ${IMAGE_ROOTFS}/etc/sudoers
  70. # Load tap/tun at startup
  71. rm -f ${IMAGE_ROOTFS}/sbin/iptables
  72. lnr ${IMAGE_ROOTFS}/usr/sbin/iptables ${IMAGE_ROOTFS}/sbin/iptables
  73. echo "tun" >> ${IMAGE_ROOTFS}/etc/modules
  74. # Use Clearlooks GTK+ theme
  75. mkdir -p ${IMAGE_ROOTFS}/etc/gtk-2.0
  76. echo 'gtk-theme-name = "Clearlooks"' > ${IMAGE_ROOTFS}/etc/gtk-2.0/gtkrc
  77. # Install modules needed for toaster
  78. export STAGING_LIBDIR=${STAGING_LIBDIR_NATIVE}
  79. export STAGING_INCDIR=${STAGING_INCDIR_NATIVE}
  80. export HOME=${IMAGE_ROOTFS}/home/builder
  81. mkdir -p ${IMAGE_ROOTFS}/home/builder/.cache/pip
  82. pip3_install_params="--user -I -U -v -r ${IMAGE_ROOTFS}/home/builder/poky/bitbake/toaster-requirements.txt"
  83. if [ -n "${http_proxy}" ]; then
  84. pip3_install_params="${pip3_install_params} --proxy ${http_proxy}"
  85. fi
  86. pip3 install ${pip3_install_params}
  87. chown -R builder:builder ${IMAGE_ROOTFS}/home/builder/.local
  88. chown -R builder:builder ${IMAGE_ROOTFS}/home/builder/.cache
  89. }
  90. IMAGE_PREPROCESS_COMMAND += "do_populate_poky_src; "
  91. addtask rootfs after do_unpack
  92. python () {
  93. # Ensure we run these usually noexec tasks
  94. d.delVarFlag("do_fetch", "noexec")
  95. d.delVarFlag("do_unpack", "noexec")
  96. }
  97. create_bundle_files () {
  98. cd ${WORKDIR}
  99. mkdir -p Yocto_Build_Appliance
  100. cp *.vmx* Yocto_Build_Appliance
  101. ln -sf ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.wic.vmdk Yocto_Build_Appliance/Yocto_Build_Appliance.vmdk
  102. zip -r ${IMGDEPLOYDIR}/Yocto_Build_Appliance-${DATETIME}.zip Yocto_Build_Appliance
  103. ln -sf Yocto_Build_Appliance-${DATETIME}.zip ${IMGDEPLOYDIR}/Yocto_Build_Appliance.zip
  104. }
  105. create_bundle_files[vardepsexclude] = "DATETIME"
  106. python do_bundle_files() {
  107. bb.build.exec_func('create_bundle_files', d)
  108. }
  109. addtask bundle_files after do_image_wic before do_image_complete