build-appliance-image_15.0.0.bb 5.8 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141
  1. SUMMARY = "An image containing the build system itself"
  2. DESCRIPTION = "An image containing the build system that you can boot and run using either VirtualBox, VMware Player or VMware Workstation."
  3. HOMEPAGE = "http://www.yoctoproject.org/documentation/build-appliance"
  4. LICENSE = "MIT"
  5. LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
  6. IMAGE_INSTALL = "packagegroup-core-boot packagegroup-core-ssh-openssh packagegroup-self-hosted \
  7. kernel-dev kernel-devsrc connman connman-plugin-ethernet dhcp-client \
  8. tzdata python3-pip perl-misc"
  9. IMAGE_FEATURES += "x11-base package-management splash"
  10. QB_MEM = '${@bb.utils.contains("DISTRO_FEATURES", "opengl", "-m 512", "-m 256", d)}'
  11. # Ensure there's enough space to do a core-image-sato build, with rm_work enabled
  12. IMAGE_ROOTFS_EXTRA_SPACE = "41943040"
  13. # Do a quiet boot with limited console messages
  14. APPEND += "rootfstype=ext4 quiet"
  15. DEPENDS = "zip-native python3-pip-native"
  16. IMAGE_FSTYPES = "wic.vmdk"
  17. inherit core-image module-base setuptools3
  18. SRCREV ?= "33903932ad87bfa8e8bf7baf2256781714993b79"
  19. SRC_URI = "git://git.yoctoproject.org/poky \
  20. file://Yocto_Build_Appliance.vmx \
  21. file://Yocto_Build_Appliance.vmxf \
  22. file://README_VirtualBox_Guest_Additions.txt \
  23. file://README_VirtualBox_Toaster.txt \
  24. "
  25. RECIPE_NO_UPDATE_REASON = "Recipe is recursive and handled as part of the release process"
  26. BA_INCLUDE_SOURCES ??= "0"
  27. IMAGE_CMD_ext4_append () {
  28. # We don't need to reserve much space for root, 0.5% is more than enough
  29. tune2fs -m 0.5 ${IMGDEPLOYDIR}/${IMAGE_NAME}.rootfs.ext4
  30. }
  31. fakeroot do_populate_poky_src () {
  32. # Because fetch2's git's unpack uses -s cloneflag, the unpacked git repo
  33. # will become invalid in the target.
  34. rm -rf ${WORKDIR}/git/.git
  35. rm -f ${WORKDIR}/git/.gitignore
  36. cp -R ${WORKDIR}/git ${IMAGE_ROOTFS}/home/builder/poky
  37. mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/conf
  38. mkdir -p ${IMAGE_ROOTFS}/home/builder/poky/build/downloads
  39. if [ ${BA_INCLUDE_SOURCES} != 0 ]; then
  40. cp -RpL ${DL_DIR}/* ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/
  41. # Remove the git2_* tarballs -- this is ok since we still have the git2/.
  42. rm -rf ${IMAGE_ROOTFS}/home/builder/poky/build/downloads/git2_*
  43. fi
  44. # Place the README_VirtualBox_Guest_Additions file in builders home folder.
  45. cp ${WORKDIR}/README_VirtualBox_Guest_Additions.txt ${IMAGE_ROOTFS}/home/builder/
  46. # Place the README_VirtualBox_Toaster file in builders home folder.
  47. cp ${WORKDIR}/README_VirtualBox_Toaster.txt ${IMAGE_ROOTFS}/home/builder/
  48. # Create a symlink, needed for out-of-tree kernel modules build
  49. if [ ! -e ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build ]; then
  50. rm -f ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build
  51. lnr ${IMAGE_ROOTFS}${KERNEL_SRC_PATH} ${IMAGE_ROOTFS}/lib/modules/${KERNEL_VERSION}/build
  52. fi
  53. echo "INHERIT += \"rm_work\"" >> ${IMAGE_ROOTFS}/home/builder/poky/build/conf/auto.conf
  54. echo "export LC_ALL=en_US.utf8" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  55. # Also save (for reference only) the actual SRCREV used to create this image
  56. echo "export BA_SRCREV=${SRCREV}" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  57. echo "" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  58. echo 'export PATH=$PATH:/sbin' >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  59. echo "" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  60. echo "# If working behind a proxy and using the provided oe-git-proxy script" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  61. echo "# you need to set ALL_PROXY based on your proxy settings." >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  62. echo "# Example ALL_PROXY values:" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  63. echo "# export ALL_PROXY=https://proxy.example.com:8080" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  64. echo "# export ALL_PROXY=socks://socks.example.com:1080" >> ${IMAGE_ROOTFS}/home/builder/.bashrc
  65. chown -R builder:builder ${IMAGE_ROOTFS}/home/builder/poky
  66. chmod -R ug+rw ${IMAGE_ROOTFS}/home/builder/poky
  67. # Assume we will need CDROM to install guest additions
  68. mkdir -p ${IMAGE_ROOTFS}/media/cdrom
  69. # Allow builder to use sudo
  70. echo "builder ALL=(ALL) NOPASSWD: ALL" >> ${IMAGE_ROOTFS}/etc/sudoers
  71. # Load tap/tun at startup
  72. rm -f ${IMAGE_ROOTFS}/sbin/iptables
  73. lnr ${IMAGE_ROOTFS}/usr/sbin/iptables ${IMAGE_ROOTFS}/sbin/iptables
  74. echo "tun" >> ${IMAGE_ROOTFS}/etc/modules
  75. # Use Clearlooks GTK+ theme
  76. mkdir -p ${IMAGE_ROOTFS}/etc/gtk-2.0
  77. echo 'gtk-theme-name = "Clearlooks"' > ${IMAGE_ROOTFS}/etc/gtk-2.0/gtkrc
  78. # Install modules needed for toaster
  79. export STAGING_LIBDIR=${STAGING_LIBDIR_NATIVE}
  80. export STAGING_INCDIR=${STAGING_INCDIR_NATIVE}
  81. export HOME=${IMAGE_ROOTFS}/home/builder
  82. mkdir -p ${IMAGE_ROOTFS}/home/builder/.cache/pip
  83. pip3_install_params="--user -I -U -v -r ${IMAGE_ROOTFS}/home/builder/poky/bitbake/toaster-requirements.txt"
  84. if [ -n "${http_proxy}" ]; then
  85. pip3_install_params="${pip3_install_params} --proxy ${http_proxy}"
  86. fi
  87. pip3 install ${pip3_install_params}
  88. chown -R builder:builder ${IMAGE_ROOTFS}/home/builder/.local
  89. chown -R builder:builder ${IMAGE_ROOTFS}/home/builder/.cache
  90. }
  91. IMAGE_PREPROCESS_COMMAND += "do_populate_poky_src; "
  92. addtask rootfs after do_unpack
  93. python () {
  94. # Ensure we run these usually noexec tasks
  95. d.delVarFlag("do_fetch", "noexec")
  96. d.delVarFlag("do_unpack", "noexec")
  97. }
  98. create_bundle_files () {
  99. cd ${WORKDIR}
  100. mkdir -p Yocto_Build_Appliance
  101. cp *.vmx* Yocto_Build_Appliance
  102. ln -sf ${IMGDEPLOYDIR}/${IMAGE_NAME}${IMAGE_NAME_SUFFIX}.wic.vmdk Yocto_Build_Appliance/Yocto_Build_Appliance.vmdk
  103. zip -r ${IMGDEPLOYDIR}/Yocto_Build_Appliance-${DATETIME}.zip Yocto_Build_Appliance
  104. ln -sf Yocto_Build_Appliance-${DATETIME}.zip ${IMGDEPLOYDIR}/Yocto_Build_Appliance.zip
  105. }
  106. create_bundle_files[vardepsexclude] = "DATETIME"
  107. python do_bundle_files() {
  108. bb.build.exec_func('create_bundle_files', d)
  109. }
  110. addtask bundle_files after do_image_wic before do_image_complete