monkey_1.6.9.bb 2.9 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879
  1. SUMMARY = "Fast and Lightweight HTTP Server for Linux"
  2. HOMEPAGE = "http://monkey-project.com"
  3. BUGTRACKER = "https://github.com/monkey/monkey/issues"
  4. LICENSE = "Apache-2.0"
  5. LIC_FILES_CHKSUM = "file://LICENSE;md5=2ee41112a44fe7014dce33e26468ba93"
  6. SECTION = "net"
  7. SRC_URI = "http://monkey-project.com/releases/1.6/monkey-${PV}.tar.gz \
  8. file://monkey.service \
  9. file://monkey.init"
  10. SRC_URI[sha256sum] = "f1122e89cda627123286542b0a18fcaa131cbe9d4f5dd897d9455157289148fb"
  11. UPSTREAM_CHECK_URI = "https://github.com/monkey/monkey/releases"
  12. UPSTREAM_CHECK_REGEX = "v(?P<pver>\d+(\.\d+)+).tar.gz"
  13. EXTRA_OECMAKE = "-DINSTALL_LOGDIR=${localstatedir}/log/monkey/ \
  14. -DPID_FILE=${localstatedir}/run/monkey.pid \
  15. -DINSTALL_SYSCONFDIR=${sysconfdir}/monkey/ \
  16. -DWITH_PLUGINS=* \
  17. -DWITHOUT_PLUGINS=mbedtls \
  18. -DWITH_DEBUG=1 \
  19. -DDEFAULT_USER='www-data' \
  20. -DWITH_SYSTEM_MALLOC=1 \
  21. "
  22. EXTRA_OECMAKE_append_libc-musl = " -DWITH_MUSL=1 "
  23. # GCC-10+ defaults to -fno-common
  24. CFLAGS += "-fcommon"
  25. DISABLE_STATIC = ""
  26. inherit cmake pkgconfig update-rc.d systemd
  27. OECMAKE_GENERATOR = "Unix Makefiles"
  28. do_install_append() {
  29. rm -rf ${D}/run
  30. rm -rf ${D}${localstatedir}/run
  31. install -Dm 0755 ${WORKDIR}/monkey.init ${D}${sysconfdir}/init.d/monkey
  32. if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
  33. install -Dm 644 ${WORKDIR}/monkey.service ${D}/${systemd_unitdir}/system/monkey.service
  34. fi
  35. }
  36. INITSCRIPT_NAME = "monkey"
  37. INITSCRIPT_PARAMS = "defaults 70"
  38. SYSTEMD_SERVICE_${PN} = "monkey.service"
  39. PACKAGES += "${PN}-plugins"
  40. FILES_${PN}-plugins = "${libdir}/monkey-*.so"
  41. FILES_${PN} += "${localstatedir}/www/monkey/ /run"
  42. CONFFILES_${PN} = "${sysconfdir}/monkey/monkey.conf \
  43. ${sysconfdir}/monkey/sites/default \
  44. ${sysconfdir}/monkey/monkey.mime \
  45. ${sysconfdir}/monkey/plugins.load \
  46. ${sysconfdir}/monkey/plugins/proxy_reverse/proxy_reverse.conf \
  47. ${sysconfdir}/monkey/plugins/mandril/mandril.conf \
  48. ${sysconfdir}/monkey/plugins/fastcgi/fastcgi.conf \
  49. ${sysconfdir}/monkey/plugins/logger/logger.conf \
  50. ${sysconfdir}/monkey/plugins/cgi/cgi.conf \
  51. ${sysconfdir}/monkey/plugins/cheetah/cheetah.conf \
  52. ${sysconfdir}/monkey/plugins/dirlisting/dirhtml.conf \
  53. ${sysconfdir}/monkey/plugins/dirlisting/themes/guineo/header.theme \
  54. ${sysconfdir}/monkey/plugins/dirlisting/themes/guineo/footer.theme \
  55. ${sysconfdir}/monkey/plugins/dirlisting/themes/guineo/entry.theme \
  56. ${sysconfdir}/monkey/plugins/auth/README \
  57. ${sysconfdir}/monkey/plugins/auth/monkey.users \
  58. "