xrdp_0.9.14.bb 3.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596
  1. SUMMARY = "An open source remote desktop protocol(rdp) server."
  2. LICENSE = "Apache-2.0"
  3. LIC_FILES_CHKSUM = "file://COPYING;md5=72cfbe4e7bd33a0a1de9630c91195c21 \
  4. "
  5. inherit features_check autotools pkgconfig useradd systemd
  6. DEPENDS = "openssl virtual/libx11 libxfixes libxrandr libpam nasm-native"
  7. REQUIRED_DISTRO_FEATURES = "x11 pam"
  8. SRC_URI = "git://github.com/neutrinolabs/xrdp.git;branch=devel \
  9. file://xrdp.sysconfig \
  10. file://0001-Added-req_distinguished_name-in-etc-xrdp-openssl.con.patch \
  11. file://0001-Fix-the-compile-error.patch \
  12. file://0001-riscv-doesn-t-require-pointers-to-be-aligned.patch \
  13. file://0001-correct-the-location-of-errno.h.patch \
  14. file://0001-Fixed-compiler-warnings-about-snprintf-truncations.patch \
  15. "
  16. SRCREV = "1469d659dbccd6d042ac44f0afc4e1309788dc9d"
  17. S = "${WORKDIR}/git"
  18. PACKAGECONFIG ??= ""
  19. PACKAGECONFIG[fuse] = " --enable-fuse, --disable-fuse, fuse"
  20. USERADD_PACKAGES = "${PN}"
  21. GROUPADD_PARAM_${PN} = "--system xrdp"
  22. USERADD_PARAM_${PN} = "--system --home /var/run/xrdp -g xrdp \
  23. --no-create-home --shell /bin/false xrdp"
  24. FILES_${PN} += "${datadir}/dbus-1/services/*.service \
  25. ${datadir}/dbus-1/accessibility-services/*.service "
  26. FILES_${PN}-dev += "${libdir}/xrdp/libcommon.so \
  27. ${libdir}/xrdp/libxrdp.so \
  28. ${libdir}/xrdp/libscp.so \
  29. ${libdir}/xrdp/libxrdpapi.so "
  30. EXTRA_OECONF = "--enable-pam-config=suse"
  31. do_configure_prepend() {
  32. cd ${S}
  33. ./bootstrap
  34. cd -
  35. }
  36. do_compile_prepend() {
  37. sed -i 's/(MAKE) $(AM_MAKEFLAGS) install-exec-am install-data-am/(MAKE) $(AM_MAKEFLAGS) install-exec-am/g' ${S}/keygen/Makefile.in
  38. }
  39. do_install_append() {
  40. install -d ${D}${sysconfdir}
  41. install -d ${D}${sysconfdir}/xrdp
  42. install -d ${D}${sysconfdir}/xrdp/pam.d
  43. install -d ${D}${sysconfdir}/sysconfig/xrdp
  44. # deal with systemd unit files
  45. install -d ${D}${systemd_unitdir}/system
  46. install -m 0644 ${S}/instfiles/xrdp.service.in ${D}${systemd_unitdir}/system/xrdp.service
  47. install -m 0644 ${S}/instfiles/xrdp-sesman.service.in ${D}${systemd_unitdir}/system/xrdp-sesman.service
  48. sed -i -e 's,@localstatedir@,${localstatedir},g' ${D}${systemd_unitdir}/system/xrdp.service ${D}${systemd_unitdir}/system/xrdp-sesman.service
  49. sed -i -e 's,@sysconfdir@,${sysconfdir},g' ${D}${systemd_unitdir}/system/xrdp.service ${D}${systemd_unitdir}/system/xrdp-sesman.service
  50. sed -i -e 's,@sbindir@,${sbindir},g' ${D}${systemd_unitdir}/system/xrdp.service ${D}${systemd_unitdir}/system/xrdp-sesman.service
  51. install -m 0644 ${S}/instfiles/*.ini ${D}${sysconfdir}/xrdp/
  52. install -m 0644 ${S}/sesman/sesman.ini.in ${D}${sysconfdir}/xrdp/
  53. install -m 0644 ${S}/sesman/startwm.sh ${D}${sysconfdir}/xrdp/
  54. install -m 0644 ${S}/xrdp/xrdp.ini.in ${D}${sysconfdir}/xrdp/
  55. install -m 0644 ${S}/xrdp/xrdp_keyboard.ini ${D}${sysconfdir}/xrdp/
  56. install -m 0644 ${S}/keygen/openssl.conf ${D}${sysconfdir}/xrdp/
  57. install -m 0644 ${WORKDIR}/xrdp.sysconfig ${D}${sysconfdir}/sysconfig/xrdp/
  58. chown xrdp:xrdp ${D}${sysconfdir}/xrdp
  59. }
  60. SYSTEMD_SERVICE_${PN} = "xrdp.service xrdp-sesman.service"
  61. pkg_postinst_${PN}() {
  62. if test -z "$D"
  63. then
  64. if test -x ${bindir}/xrdp-keygen
  65. then
  66. ${bindir}/xrdp-keygen xrdp ${sysconfdir}/xrdp/rsakeys.ini >/dev/null
  67. fi
  68. if test ! -s ${sysconfdir}/xrdp/cert.pem
  69. then
  70. openssl req -x509 -newkey rsa:2048 -sha256 -nodes -days 3652 \
  71. -keyout ${sysconfdir}/xrdp/key.pem \
  72. -out ${sysconfdir}/xrdp/cert.pem \
  73. -config ${sysconfdir}/xrdp/openssl.conf >/dev/null 2>&1
  74. chmod 400 ${sysconfdir}/xrdp/key.pem
  75. fi
  76. fi
  77. }