vboxguestdrivers_6.1.16.bb 3.1 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485
  1. SUMMARY = "VirtualBox Linux Guest Drivers"
  2. SECTION = "core"
  3. LICENSE = "GPL-2.0"
  4. LIC_FILES_CHKSUM = "file://${WORKDIR}/${VBOX_NAME}/COPYING;md5=e197d5641bb35b29d46ca8c4bf7f2660"
  5. DEPENDS = "virtual/kernel"
  6. inherit module kernel-module-split
  7. COMPATIBLE_MACHINE = "(qemux86|qemux86-64)"
  8. VBOX_NAME = "VirtualBox-${PV}"
  9. SRC_URI = "http://download.virtualbox.org/virtualbox/${PV}/${VBOX_NAME}.tar.bz2 \
  10. file://Makefile.utils \
  11. file://0001-Additions-linux-drm-Adjustment-for-Linux-5.10.patch \
  12. file://0001-Runtime-memobj-r0drv-linux.c-Changes-to-support-the-.patch \
  13. file://0001-linser-vboxsf-Adjustment-for-linux-5.10-TASK_SIZE_MA.patch \
  14. "
  15. SRC_URI[md5sum] = "a12a647f6c114f2cb1571089b36841fe"
  16. SRC_URI[sha256sum] = "49c1990da16d8a3d5bda8cdb961ec8195a901e67e4c79aea44c1521a5fc2f9f1"
  17. S ?= "${WORKDIR}/vbox_module"
  18. S_task-patch = "${WORKDIR}/${VBOX_NAME}"
  19. export BUILD_TARGET_ARCH="${ARCH}"
  20. export BUILD_TARGET_ARCH_x86-64="amd64"
  21. EXTRA_OEMAKE += "KERN_DIR='${WORKDIR}/${KERNEL_VERSION}/build' KBUILD_VERBOSE=1"
  22. # otherwise 5.2.22 builds just vboxguest
  23. MAKE_TARGETS = "all"
  24. addtask export_sources after do_patch before do_configure
  25. do_export_sources() {
  26. mkdir -p "${S}"
  27. ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/export_modules.sh ${T}/vbox_modules.tar.gz
  28. tar -C "${S}" -xzf ${T}/vbox_modules.tar.gz
  29. # add a mount utility to use shared folder from VBox Addition Source Code
  30. mkdir -p "${S}/utils"
  31. install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/mount.vboxsf.c ${S}/utils
  32. install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/vbsfmount.c ${S}/utils
  33. install ${S}/../Makefile.utils ${S}/utils/Makefile
  34. }
  35. do_configure_prepend() {
  36. # vboxguestdrivers/5.2.6-r0/vbox_module/vboxguest/Makefile.include.header:99: *** The variable KERN_DIR must be a kernel build folder and end with /build without a trailing slash, or KERN_VER must be set. Stop.
  37. # vboxguestdrivers/5.2.6-r0/vbox_module/vboxguest/Makefile.include.header:108: *** The kernel build folder path must end in <version>/build, or the variable KERN_VER must be set. Stop.
  38. mkdir -p ${WORKDIR}/${KERNEL_VERSION}
  39. ln -snf ${STAGING_KERNEL_DIR} ${WORKDIR}/${KERNEL_VERSION}/build
  40. }
  41. # compile and install mount utility
  42. do_compile() {
  43. oe_runmake all
  44. oe_runmake 'LD=${CC}' 'LDFLAGS=${LDFLAGS}' -C ${S}/utils
  45. if ! [ -e vboxguest.ko -a -e vboxsf.ko -a -e vboxvideo.ko ] ; then
  46. echo "ERROR: One of vbox*.ko modules wasn't built"
  47. exit 1
  48. fi
  49. }
  50. module_do_install() {
  51. MODULE_DIR=${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/kernel/misc
  52. install -d $MODULE_DIR
  53. install -m 644 vboxguest.ko $MODULE_DIR
  54. install -m 644 vboxsf.ko $MODULE_DIR
  55. install -m 644 vboxvideo.ko $MODULE_DIR
  56. }
  57. do_install_append() {
  58. install -d ${D}${base_sbindir}
  59. install -m 755 ${S}/utils/mount.vboxsf ${D}${base_sbindir}
  60. }
  61. PACKAGES += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
  62. RRECOMMENDS_${PN} += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
  63. FILES_${PN} = "${base_sbindir}"
  64. # autoload if installed
  65. KERNEL_MODULE_AUTOLOAD += "vboxguest vboxsf vboxvideo"