pidgin_2.13.0.bb 5.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118
  1. SUMMARY = "multi-protocol instant messaging client"
  2. SECTION = "x11/network"
  3. LICENSE = "GPLv2"
  4. LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
  5. DEPENDS = "python3 virtual/libintl intltool-native libxml2 gconf glib-2.0-native"
  6. inherit autotools gettext pkgconfig gconf perlnative python3native
  7. SRC_URI = "\
  8. ${SOURCEFORGE_MIRROR}/pidgin/pidgin-${PV}.tar.bz2 \
  9. file://sanitize-configure.ac.patch \
  10. file://purple-OE-branding-25.patch \
  11. file://pidgin-cross-python-265.patch \
  12. file://use_py3.patch \
  13. "
  14. SRC_URI[md5sum] = "423403494fe1951e47cc75231f743bb0"
  15. SRC_URI[sha256sum] = "2747150c6f711146bddd333c496870bfd55058bab22ffb7e4eb784018ec46d8f"
  16. PACKAGECONFIG ??= "gnutls consoleui avahi dbus idn nss \
  17. ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 gtk startup-notification', '', d)} \
  18. "
  19. PACKAGECONFIG[farsight2] = "--enable-farstream,--disable-farstream,farsight2"
  20. # --disable-gstreamer compile without GStreamer audio support
  21. # --disable-gstreamer-video
  22. # compile without GStreamer 1.0 Video Overlay support
  23. # --disable-gstreamer-interfaces
  24. # compile without GStreamer 0.10 interface support
  25. # --with-gstreamer=<version>
  26. # compile with GStreamer 0.10 or 1.0 interface
  27. PACKAGECONFIG[gstreamer] = "--enable-gstreamer,--disable-gstreamer,gstreamer"
  28. PACKAGECONFIG[vv] = "--enable-vv,--disable-vv,gstreamer"
  29. PACKAGECONFIG[idn] = "--enable-idn,--disable-idn,libidn"
  30. PACKAGECONFIG[gtk] = "--enable-gtkui,--disable-gtkui,gtk+"
  31. PACKAGECONFIG[x11] = "--with-x=yes --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR},--with-x=no,virtual/libx11"
  32. PACKAGECONFIG[startup-notification] = "--enable-startup-notification,--disable-startup-notification,startup-notification"
  33. PACKAGECONFIG[consoleui] = "--enable-consoleui --with-ncurses-headers=${STAGING_INCDIR},--disable-consoleui,ncurses"
  34. PACKAGECONFIG[gnutls] = "--enable-gnutls --with-gnutls-includes=${STAGING_INCDIR} --with-gnutls-libs=${STAGING_LIBDIR},--disable-gnutls,gnutls,libpurple-plugin-ssl-gnutls"
  35. PACKAGECONFIG[dbus] = "--enable-dbus,--disable-dbus,dbus dbus-glib"
  36. PACKAGECONFIG[avahi] = "--enable-avahi,--disable-avahi,avahi"
  37. PACKAGECONFIG[nss] = "--enable-nss,--disable-nss,nss nspr,libpurple-plugin-ssl-nss"
  38. EXTRA_OECONF = " \
  39. --disable-perl \
  40. --disable-tcl \
  41. --disable-gevolution \
  42. --disable-schemas-install \
  43. --disable-gtkspell \
  44. --disable-meanwhile \
  45. --disable-nm \
  46. --disable-screensaver \
  47. "
  48. do_configure_prepend() {
  49. touch ${S}/po/Makefile
  50. sed -i "s#PY_VERSION=`$PYTHON -c 'import sys ; print sys.version[0:3]'`#PY_VERSION=${PYTHON_BASEVERSION}#g" ${S}/configure.ac
  51. }
  52. OE_LT_RPATH_ALLOW=":${libdir}/purple-2:"
  53. OE_LT_RPATH_ALLOW[export]="1"
  54. PACKAGES =+ "libpurple-dev libpurple libgnt libgnt-dev finch finch-dev ${PN}-data"
  55. RPROVIDES_${PN}-dbg += "libpurple-dbg libgnt-dbg finch-dbg"
  56. LEAD_SONAME = "libpurple.so.0"
  57. FILES_libpurple = "${libdir}/libpurple*.so.* ${libdir}/purple-2 ${bindir}/purple-* ${sysconfdir}/gconf/schemas/purple* ${datadir}/purple/ca-certs"
  58. FILES_libpurple-dev = "${libdir}/libpurple*.la \
  59. ${libdir}/libpurple*.so \
  60. ${libdir}/purple-2/*.la \
  61. ${libdir}/purple-2/libjabber.so \
  62. ${libdir}/purple-2/liboscar.so \
  63. ${libdir}/purple-2/libymsg.so \
  64. ${datadir}/aclocal"
  65. FILES_libgnt = "${libdir}/libgnt.so.* ${libdir}/gnt/*.so"
  66. FILES_libgnt-dev = "${libdir}/gnt/*.la"
  67. FILES_finch = "${bindir}/finch"
  68. FILES_finch-dev = "${libdir}/finch/*.la"
  69. FILES_${PN} = "${bindir} ${datadir}/${PN} ${libdir}/${PN}/*.so \
  70. ${datadir}/applications"
  71. RRECOMMENDS_${PN} = "${PN}-data libpurple-protocol-irc libpurple-protocol-xmpp"
  72. FILES_${PN}-data = "${datadir}/pixmaps ${datadir}/sounds ${datadir}/icons ${datadir}/appdata"
  73. FILES_${PN}-dev += "${libdir}/${PN}/*.la"
  74. PACKAGES_DYNAMIC += "^libpurple-protocol-.* ^libpurple-plugin-.* ^pidgin-plugin-.* ^finch-plugin-.*"
  75. python populate_packages_prepend () {
  76. pidgroot = d.expand('${libdir}/pidgin')
  77. purple = d.expand('${libdir}/purple-2')
  78. finch = d.expand('${libdir}/finch')
  79. do_split_packages(d, pidgroot, '^([^l][^i][^b].*)\.so$',
  80. output_pattern='pidgin-plugin-%s',
  81. description='Pidgin plugin %s',
  82. prepend=True, extra_depends='')
  83. do_split_packages(d, purple, '^lib(.*)\.so$',
  84. output_pattern='libpurple-protocol-%s',
  85. description='Libpurple protocol plugin for %s',
  86. prepend=True, extra_depends='')
  87. do_split_packages(d, purple, '^(ssl-.*)\.so$',
  88. output_pattern='libpurple-plugin-%s',
  89. description='libpurple plugin %s',
  90. prepend=True, extra_depends='libpurple-plugin-ssl')
  91. do_split_packages(d, purple, '^([^l][^i][^b].*)\.so$',
  92. output_pattern='libpurple-plugin-%s',
  93. description='libpurple plugin %s',
  94. prepend=True, extra_depends='')
  95. do_split_packages(d, finch, '^([^l][^i][^b].*)\.so$',
  96. output_pattern='finch-plugin-%s',
  97. description='Finch plugin %s',
  98. prepend=True, extra_depends='')
  99. }