opencv_4.5.0.bb 11 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218
  1. SUMMARY = "Opencv : The Open Computer Vision Library"
  2. HOMEPAGE = "http://opencv.org/"
  3. SECTION = "libs"
  4. LICENSE = "Apache-2.0"
  5. LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
  6. ARM_INSTRUCTION_SET_armv4 = "arm"
  7. ARM_INSTRUCTION_SET_armv5 = "arm"
  8. DEPENDS = "libtool swig-native bzip2 zlib glib-2.0 libwebp"
  9. SRCREV_opencv = "d5fd2f0155ffad366f9ac912dfd6d189a7a6a98e"
  10. SRCREV_contrib = "37315babf9984a5b6aa981644a20dd8df1a5ff02"
  11. SRCREV_ipp = "a56b6ac6f030c312b2dce17430eef13aed9af274"
  12. SRCREV_boostdesc = "34e4206aef44d50e6bbcd0ab06354b52e7466d26"
  13. SRCREV_vgg = "fccf7cd6a4b12079f73bbfb21745f9babcd4eb1d"
  14. SRCREV_face = "8afa57abc8229d611c4937165d20e2a2d9fc5a12"
  15. def ipp_filename(d):
  16. import re
  17. arch = d.getVar('TARGET_ARCH')
  18. if re.match("i.86$", arch):
  19. return "ippicv_2020_lnx_ia32_20191018_general.tgz"
  20. else:
  21. return "ippicv_2020_lnx_intel64_20191018_general.tgz"
  22. def ipp_md5sum(d):
  23. import re
  24. arch = d.getVar('TARGET_ARCH')
  25. if re.match("i.86$", arch):
  26. return "ad189a940fb60eb71f291321322fe3e8"
  27. else:
  28. return "7421de0095c7a39162ae13a6098782f9"
  29. IPP_FILENAME = "${@ipp_filename(d)}"
  30. IPP_MD5 = "${@ipp_md5sum(d)}"
  31. SRCREV_FORMAT = "opencv_contrib_ipp_boostdesc_vgg"
  32. SRC_URI = "git://github.com/opencv/opencv.git;name=opencv \
  33. git://github.com/opencv/opencv_contrib.git;destsuffix=contrib;name=contrib \
  34. git://github.com/opencv/opencv_3rdparty.git;branch=ippicv/master_20191018;destsuffix=ipp;name=ipp \
  35. git://github.com/opencv/opencv_3rdparty.git;branch=contrib_xfeatures2d_boostdesc_20161012;destsuffix=boostdesc;name=boostdesc \
  36. git://github.com/opencv/opencv_3rdparty.git;branch=contrib_xfeatures2d_vgg_20160317;destsuffix=vgg;name=vgg \
  37. git://github.com/opencv/opencv_3rdparty.git;branch=contrib_face_alignment_20170818;destsuffix=face;name=face \
  38. file://0001-3rdparty-ippicv-Use-pre-downloaded-ipp.patch \
  39. file://0003-To-fix-errors-as-following.patch \
  40. file://0001-Temporarliy-work-around-deprecated-ffmpeg-RAW-functi.patch \
  41. file://0001-Dont-use-isystem.patch \
  42. file://download.patch \
  43. file://0001-Make-ts-module-external.patch \
  44. file://0001-samples-cmake-digits-needs-opencv_dnn-module-to-buil.patch \
  45. "
  46. SRC_URI_append_riscv64 = " file://0001-Use-Os-to-compile-tinyxml2.cpp.patch;patchdir=../contrib"
  47. S = "${WORKDIR}/git"
  48. # OpenCV wants to download more files during configure. We download these in
  49. # do_fetch and construct a source cache in the format it expects
  50. OPENCV_DLDIR = "${WORKDIR}/downloads"
  51. do_unpack_extra() {
  52. tar xzf ${WORKDIR}/ipp/ippicv/${IPP_FILENAME} -C ${WORKDIR}
  53. md5() {
  54. # Return the MD5 of $1
  55. echo $(md5sum $1 | cut -d' ' -f1)
  56. }
  57. cache() {
  58. TAG=$1
  59. shift
  60. mkdir --parents ${OPENCV_DLDIR}/$TAG
  61. for F in $*; do
  62. DEST=${OPENCV_DLDIR}/$TAG/$(md5 $F)-$(basename $F)
  63. test -e $DEST || ln -s $F $DEST
  64. done
  65. }
  66. cache xfeatures2d/boostdesc ${WORKDIR}/boostdesc/*.i
  67. cache xfeatures2d/vgg ${WORKDIR}/vgg/*.i
  68. cache data ${WORKDIR}/face/*.dat
  69. }
  70. addtask unpack_extra after do_unpack before do_patch
  71. CMAKE_VERBOSE = "VERBOSE=1"
  72. EXTRA_OECMAKE = "-DOPENCV_EXTRA_MODULES_PATH=${WORKDIR}/contrib/modules \
  73. -DWITH_1394=OFF \
  74. -DENABLE_PRECOMPILED_HEADERS=OFF \
  75. -DCMAKE_SKIP_RPATH=ON \
  76. -DOPENCV_ICV_HASH=${IPP_MD5} \
  77. -DIPPROOT=${WORKDIR}/ippicv_lnx \
  78. -DOPENCV_GENERATE_PKGCONFIG=ON \
  79. -DOPENCV_DOWNLOAD_PATH=${OPENCV_DLDIR} \
  80. -DOPENCV_ALLOW_DOWNLOADS=OFF \
  81. ${@bb.utils.contains("TARGET_CC_ARCH", "-msse3", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1", "", d)} \
  82. ${@bb.utils.contains("TARGET_CC_ARCH", "-msse4.1", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1 -DENABLE_SSE41=1", "", d)} \
  83. ${@bb.utils.contains("TARGET_CC_ARCH", "-msse4.2", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1 -DENABLE_SSE41=1 -DENABLE_SSE42=1", "", d)} \
  84. "
  85. EXTRA_OECMAKE_append_x86 = " -DX86=ON"
  86. PACKAGECONFIG ??= "gapi python3 eigen jpeg png tiff v4l libv4l gstreamer samples tbb gphoto2 \
  87. ${@bb.utils.contains("DISTRO_FEATURES", "x11", "gtk", "", d)} \
  88. ${@bb.utils.contains("LICENSE_FLAGS_WHITELIST", "commercial", "libav", "", d)}"
  89. PACKAGECONFIG[gapi] = "-DWITH_ADE=ON -Dade_DIR=${STAGING_LIBDIR},-DWITH_ADE=OFF,ade"
  90. PACKAGECONFIG[amdblas] = "-DWITH_OPENCLAMDBLAS=ON,-DWITH_OPENCLAMDBLAS=OFF,libclamdblas,"
  91. PACKAGECONFIG[amdfft] = "-DWITH_OPENCLAMDFFT=ON,-DWITH_OPENCLAMDFFT=OFF,libclamdfft,"
  92. PACKAGECONFIG[dnn] = "-DBUILD_opencv_dnn=ON -DPROTOBUF_UPDATE_FILES=ON -DBUILD_PROTOBUF=OFF,-DBUILD_opencv_dnn=OFF,protobuf protobuf-native,"
  93. PACKAGECONFIG[eigen] = "-DWITH_EIGEN=ON,-DWITH_EIGEN=OFF,libeigen gflags glog,"
  94. PACKAGECONFIG[freetype] = "-DBUILD_opencv_freetype=ON,-DBUILD_opencv_freetype=OFF,freetype,"
  95. PACKAGECONFIG[gphoto2] = "-DWITH_GPHOTO2=ON,-DWITH_GPHOTO2=OFF,libgphoto2,"
  96. PACKAGECONFIG[gstreamer] = "-DWITH_GSTREAMER=ON,-DWITH_GSTREAMER=OFF,gstreamer1.0 gstreamer1.0-plugins-base,"
  97. PACKAGECONFIG[gtk] = "-DWITH_GTK=ON,-DWITH_GTK=OFF,gtk+3,"
  98. PACKAGECONFIG[jasper] = "-DWITH_JASPER=ON,-DWITH_JASPER=OFF,jasper,"
  99. PACKAGECONFIG[java] = "-DJAVA_INCLUDE_PATH=${JAVA_HOME}/include -DJAVA_INCLUDE_PATH2=${JAVA_HOME}/include/linux -DJAVA_AWT_INCLUDE_PATH=${JAVA_HOME}/include -DJAVA_AWT_LIBRARY=${JAVA_HOME}/lib/amd64/libjawt.so -DJAVA_JVM_LIBRARY=${JAVA_HOME}/lib/amd64/server/libjvm.so,,ant-native fastjar-native openjdk-8-native,"
  100. PACKAGECONFIG[jpeg] = "-DWITH_JPEG=ON,-DWITH_JPEG=OFF,jpeg,"
  101. PACKAGECONFIG[libav] = "-DWITH_FFMPEG=ON,-DWITH_FFMPEG=OFF,libav,"
  102. PACKAGECONFIG[libv4l] = "-DWITH_LIBV4L=ON,-DWITH_LIBV4L=OFF,v4l-utils,"
  103. PACKAGECONFIG[opencl] = "-DWITH_OPENCL=ON,-DWITH_OPENCL=OFF,opencl-headers virtual/opencl-icd,"
  104. PACKAGECONFIG[oracle-java] = "-DJAVA_INCLUDE_PATH=${ORACLE_JAVA_HOME}/include -DJAVA_INCLUDE_PATH2=${ORACLE_JAVA_HOME}/include/linux -DJAVA_AWT_INCLUDE_PATH=${ORACLE_JAVA_HOME}/include -DJAVA_AWT_LIBRARY=${ORACLE_JAVA_HOME}/lib/amd64/libjawt.so -DJAVA_JVM_LIBRARY=${ORACLE_JAVA_HOME}/lib/amd64/server/libjvm.so,,ant-native oracle-jse-jdk oracle-jse-jdk-native,"
  105. PACKAGECONFIG[png] = "-DWITH_PNG=ON,-DWITH_PNG=OFF,libpng,"
  106. PACKAGECONFIG[python2] = "-DPYTHON2_NUMPY_INCLUDE_DIRS:PATH=${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/numpy/core/include,,python-numpy,"
  107. PACKAGECONFIG[python3] = "-DPYTHON3_NUMPY_INCLUDE_DIRS:PATH=${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/numpy/core/include,,python3-numpy,"
  108. PACKAGECONFIG[samples] = "-DBUILD_EXAMPLES=ON -DINSTALL_PYTHON_EXAMPLES=ON,-DBUILD_EXAMPLES=OFF,,"
  109. PACKAGECONFIG[tbb] = "-DWITH_TBB=ON,-DWITH_TBB=OFF,tbb,"
  110. PACKAGECONFIG[text] = "-DBUILD_opencv_text=ON,-DBUILD_opencv_text=OFF,tesseract,"
  111. PACKAGECONFIG[tiff] = "-DWITH_TIFF=ON,-DWITH_TIFF=OFF,tiff,"
  112. PACKAGECONFIG[v4l] = "-DWITH_V4L=ON,-DWITH_V4L=OFF,v4l-utils,"
  113. inherit pkgconfig cmake
  114. inherit ${@bb.utils.contains('PACKAGECONFIG', 'python3', 'distutils3-base', '', d)}
  115. inherit ${@bb.utils.contains('PACKAGECONFIG', 'python2', 'distutils-base', '', d)}
  116. export PYTHON_CSPEC="-I${STAGING_INCDIR}/${PYTHON_DIR}"
  117. export PYTHON="${STAGING_BINDIR_NATIVE}/${@bb.utils.contains('PACKAGECONFIG', 'python3', 'python3', 'python', d)}"
  118. export ORACLE_JAVA_HOME="${STAGING_DIR_NATIVE}/usr/bin/java"
  119. export JAVA_HOME="${STAGING_DIR_NATIVE}/usr/lib/jvm/openjdk-8-native"
  120. export ANT_DIR="${STAGING_DIR_NATIVE}/usr/share/ant/"
  121. TARGET_CC_ARCH += "-I${S}/include "
  122. PACKAGES += "${@bb.utils.contains('PACKAGECONFIG', 'samples', '${PN}-samples', '', d)} \
  123. ${@bb.utils.contains('PACKAGECONFIG', 'oracle-java', '${PN}-java', '', d)} \
  124. ${@bb.utils.contains('PACKAGECONFIG', 'java', '${PN}-java', '', d)} \
  125. ${@bb.utils.contains('PACKAGECONFIG', 'python2', 'python-${BPN}', '', d)} \
  126. ${@bb.utils.contains('PACKAGECONFIG', 'python3', 'python3-${BPN}', '', d)} \
  127. ${PN}-apps"
  128. python populate_packages_prepend () {
  129. cv_libdir = d.expand('${libdir}')
  130. do_split_packages(d, cv_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev', allow_links=True)
  131. do_split_packages(d, cv_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
  132. do_split_packages(d, cv_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
  133. do_split_packages(d, cv_libdir, '^lib(.*)\.so\.*', 'lib%s', 'OpenCV %s library', extra_depends='', allow_links=True)
  134. pn = d.getVar('PN')
  135. metapkg = pn + '-dev'
  136. d.setVar('ALLOW_EMPTY_' + metapkg, "1")
  137. blacklist = [ metapkg ]
  138. metapkg_rdepends = [ ]
  139. packages = d.getVar('PACKAGES').split()
  140. for pkg in packages[1:]:
  141. if not pkg in blacklist and not pkg in metapkg_rdepends and pkg.endswith('-dev'):
  142. metapkg_rdepends.append(pkg)
  143. d.setVar('RRECOMMENDS_' + metapkg, ' '.join(metapkg_rdepends))
  144. metapkg = pn
  145. d.setVar('ALLOW_EMPTY_' + metapkg, "1")
  146. blacklist = [ metapkg, "libopencv-ts" ]
  147. metapkg_rdepends = [ ]
  148. for pkg in packages[1:]:
  149. if not pkg in blacklist and not pkg in metapkg_rdepends and not pkg.endswith('-dev') and not pkg.endswith('-dbg') and not pkg.endswith('-doc') and not pkg.endswith('-locale') and not pkg.endswith('-staticdev'):
  150. metapkg_rdepends.append(pkg)
  151. d.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends))
  152. }
  153. PACKAGES_DYNAMIC += "^libopencv-.*"
  154. FILES_${PN} = ""
  155. FILES_${PN}-dbg += "${datadir}/OpenCV/java/.debug/* ${datadir}/OpenCV/samples/bin/.debug/*"
  156. FILES_${PN}-dev = "${includedir} ${libdir}/pkgconfig ${libdir}/cmake/opencv4/*.cmake"
  157. FILES_${PN}-staticdev += "${libdir}/opencv4/3rdparty/*.a"
  158. FILES_${PN}-apps = "${bindir}/* ${datadir}/opencv4 ${datadir}/licenses"
  159. FILES_${PN}-java = "${datadir}/OpenCV/java"
  160. FILES_${PN}-samples = "${datadir}/opencv4/samples/"
  161. INSANE_SKIP_${PN}-java = "libdir"
  162. INSANE_SKIP_${PN}-dbg = "libdir"
  163. ALLOW_EMPTY_${PN} = "1"
  164. SUMMARY_python-opencv = "Python bindings to opencv"
  165. FILES_python-opencv = "${PYTHON_SITEPACKAGES_DIR}/*"
  166. RDEPENDS_python-opencv = "python-core python-numpy"
  167. SUMMARY_python3-opencv = "Python bindings to opencv"
  168. FILES_python3-opencv = "${PYTHON_SITEPACKAGES_DIR}/*"
  169. RDEPENDS_python3-opencv = "python3-core python3-numpy"
  170. RDEPENDS_${PN}-apps = "bash"
  171. do_compile_prepend() {
  172. # remove the build host info to improve reproducibility
  173. if [ -f ${WORKDIR}/build/modules/core/version_string.inc ]; then
  174. sed -i "s#${WORKDIR}#/workdir#g" ${WORKDIR}/build/modules/core/version_string.inc
  175. fi
  176. }
  177. do_install_append() {
  178. # Move Python files into correct library folder (for multilib build)
  179. if [ "$libdir" != "/usr/lib" -a -d ${D}/usr/lib ]; then
  180. mv ${D}/usr/lib/* ${D}/${libdir}/
  181. rm -rf ${D}/usr/lib
  182. fi
  183. }
  184. TOOLCHAIN = "gcc"