monit_5.27.1.bb 1.7 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253
  1. DESCRIPTION = "Monit is a free open source utility for managing and monitoring, \
  2. processes, programs, files, directories and filesystems on a UNIX system. \
  3. Monit conducts automatic maintenance and repair and can execute meaningful \
  4. causal actions in error situations."
  5. HOMEPAGE = "http://mmonit.com/monit/"
  6. LICENSE = "AGPL-3.0"
  7. LIC_FILES_CHKSUM = "file://COPYING;md5=ea116a7defaf0e93b3bb73b2a34a3f51 \
  8. file://libmonit/COPYING;md5=2405f1c59ed1bf3714cebdb40162ce92"
  9. SRC_URI = " \
  10. https://mmonit.com/monit/dist/monit-${PV}.tar.gz \
  11. file://monit \
  12. file://monitrc \
  13. "
  14. SRC_URI[md5sum] = "200068f37847e3402f6a9b061c2d327e"
  15. SRC_URI[sha256sum] = "f57408d16185687513a3c4eb3f2bb72eef76331ac16210e9652e846e5c84ed51"
  16. DEPENDS = "zlib bison-native libnsl2 flex-native openssl virtual/crypt"
  17. inherit autotools-brokensep systemd update-rc.d
  18. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}"
  19. PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam"
  20. EXTRA_OECONF = "\
  21. libmonit_cv_setjmp_available=no \
  22. libmonit_cv_vsnprintf_c99_conformant=no \
  23. --with-ssl-lib-dir=${STAGING_LIBDIR} \
  24. --with-ssl-incl-dir=${STAGING_INCDIR} \
  25. "
  26. SYSTEMD_SERVICE_${PN} = "monit.service"
  27. SYSTEMD_AUTO_ENABLE = "enable"
  28. INITSCRIPT_PACKAGES = "${PN}"
  29. INITSCRIPT_NAME_${PN} = "monit"
  30. INITSCRIPT_PARAMS_${PN} = "defaults 89"
  31. do_install_append() {
  32. # Configuration file
  33. install -Dm 0600 ${WORKDIR}/monitrc ${D}${sysconfdir}/monitrc
  34. # SystemD
  35. install -Dm 0644 ${S}/system/startup/monit.service.in ${D}${systemd_system_unitdir}/monit.service
  36. sed -i -e 's,@prefix@,${exec_prefix},g' ${D}${systemd_unitdir}/system/monit.service
  37. # SysV
  38. install -Dm 0755 ${WORKDIR}/monit ${D}${sysconfdir}/init.d/monit
  39. }