libssh2_1.9.0.bb 1.7 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152
  1. SUMMARY = "A client-side C library implementing the SSH2 protocol"
  2. HOMEPAGE = "http://www.libssh2.org/"
  3. SECTION = "libs"
  4. DEPENDS = "zlib"
  5. LICENSE = "BSD-3-Clause"
  6. LIC_FILES_CHKSUM = "file://COPYING;md5=c5cf34fc0acb44b082ef50ef5e4354ca"
  7. SRC_URI = "http://www.libssh2.org/download/${BP}.tar.gz \
  8. file://CVE-2019-17498.patch \
  9. file://run-ptest \
  10. "
  11. SRC_URI_append_ptest = " file://0001-Don-t-let-host-enviroment-to-decide-if-a-test-is-bui.patch"
  12. SRC_URI[md5sum] = "1beefafe8963982adc84b408b2959927"
  13. SRC_URI[sha256sum] = "d5fb8bd563305fd1074dda90bd053fb2d29fc4bce048d182f96eaa466dfadafd"
  14. inherit autotools pkgconfig ptest
  15. EXTRA_OECONF += "\
  16. --with-libz \
  17. --with-libz-prefix=${STAGING_LIBDIR} \
  18. "
  19. # only one of openssl and gcrypt could be set
  20. PACKAGECONFIG ??= "openssl"
  21. PACKAGECONFIG[openssl] = "--with-crypto=openssl --with-libssl-prefix=${STAGING_LIBDIR}, , openssl"
  22. PACKAGECONFIG[gcrypt] = "--with-crypto=libgcrypt --with-libgcrypt-prefix=${STAGING_EXECPREFIXDIR}, , libgcrypt"
  23. BBCLASSEXTEND = "native nativesdk"
  24. # required for ptest on documentation
  25. RDEPENDS_${PN}-ptest = "man-db openssh"
  26. RDEPENDS_${PN}-ptest_append_libc-glibc = " locale-base-en-us"
  27. do_compile_ptest() {
  28. sed -i "/\$(MAKE) \$(AM_MAKEFLAGS) check-TESTS/d" tests/Makefile
  29. oe_runmake check
  30. }
  31. do_install_ptest() {
  32. install -d ${D}${PTEST_PATH}/tests
  33. install -m 0755 ${S}/test-driver ${D}${PTEST_PATH}/
  34. cp -rf ${B}/tests/.libs/* ${D}${PTEST_PATH}/tests/
  35. cp -rf ${S}/tests/mansyntax.sh ${D}${PTEST_PATH}/tests/
  36. cp -rf ${S}/tests/ssh2.sh ${D}${PTEST_PATH}/tests/
  37. cp -rf ${S}/tests/etc ${D}${PTEST_PATH}/tests/
  38. mkdir -p ${D}${PTEST_PATH}/docs
  39. cp -r ${S}/docs/* ${D}${PTEST_PATH}/docs/
  40. }