hdf5_1.8.21.bb 2.0 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758
  1. SUMMARY = "Management suite for extremely large and complex data collections"
  2. DESCRIPTION = "Unique technology suite that makes possible the management of \
  3. extremely large and complex data collections"
  4. HOMEPAGE = "https://www.hdfgroup.org/"
  5. SECTION = "libs"
  6. LICENSE = "HDF5"
  7. LIC_FILES_CHKSUM = "file://COPYING;md5=57e5351b17591e659eedae107265c606"
  8. inherit cmake siteinfo
  9. SRC_URI = " \
  10. https://support.hdfgroup.org/ftp/HDF5/releases/hdf5-1.8/hdf5-${PV}/src/${BPN}-${PV}.tar.bz2 \
  11. file://H5lib_settings.c \
  12. file://H5Tinit-64.c \
  13. file://H5Tinit-32.c \
  14. file://0001-cross-compiling-support.patch \
  15. file://0002-Remove-suffix-shared-from-shared-library-name.patch \
  16. "
  17. SRC_URI[md5sum] = "2d2408f2a9dfb5c7b79998002e9a90e9"
  18. SRC_URI[sha256sum] = "e5b1b1dee44a64b795a91c3321ab7196d9e0871fe50d42969761794e3899f40d"
  19. FILES_${PN} += "${libdir}/libhdf5.settings ${datadir}/*"
  20. EXTRA_OECMAKE = " \
  21. -DTEST_LFS_WORKS_RUN=0 \
  22. -DTEST_LFS_WORKS_RUN__TRYRUN_OUTPUT=0 \
  23. -DH5_PRINTF_LL_TEST_RUN=1 \
  24. -DH5_PRINTF_LL_TEST_RUN__TRYRUN_OUTPUT='8' \
  25. -DH5_LDOUBLE_TO_LONG_SPECIAL_RUN=0 \
  26. -DH5_LDOUBLE_TO_LONG_SPECIAL_RUN__TRYRUN_OUTPUT= \
  27. -DH5_LONG_TO_LDOUBLE_SPECIAL_RUN=0 \
  28. -DH5_LONG_TO_LDOUBLE_SPECIAL_RUN__TRYRUN_OUTPUT= \
  29. -DH5_LDOUBLE_TO_LLONG_ACCURATE_RUN=0 \
  30. -DH5_LDOUBLE_TO_LLONG_ACCURATE_RUN__TRYRUN_OUTPUT= \
  31. -DH5_LLONG_TO_LDOUBLE_CORRECT_RUN=0 \
  32. -DH5_LLONG_TO_LDOUBLE_CORRECT_RUN__TRYRUN_OUTPUT= \
  33. -DH5_NO_ALIGNMENT_RESTRICTIONS_RUN=0 \
  34. -DH5_NO_ALIGNMENT_RESTRICTIONS_RUN__TRYRUN_OUTPUT= \
  35. -DCMAKE_INSTALL_PREFIX='${prefix}' \
  36. -DHDF5_INSTALL_LIB_DIR='${baselib}' \
  37. "
  38. do_unpack[postfuncs] += "gen_hd5file"
  39. gen_hd5file() {
  40. install -m 544 ${WORKDIR}/H5lib_settings.c ${S}
  41. install -m 544 ${WORKDIR}/H5Tinit-${SITEINFO_BITS}.c ${S}/H5Tinit.c
  42. }
  43. do_install_append() {
  44. # Used for generating config files on target
  45. install -m 755 ${B}/bin/H5detect ${D}${bindir}
  46. install -m 755 ${B}/bin/H5make_libsettings ${D}${bindir}
  47. }
  48. BBCLASSEXTEND = "native"
  49. SRC_DISTRIBUTE_LICENSES += "HDF5"