freerdp_2.2.0.bb 3.1 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485
  1. # Copyright (C) 2010-2012 O.S. Systems Software Ltda. All Rights Reserved
  2. # Released under the MIT license
  3. DESCRIPTION = "FreeRDP RDP client & server library"
  4. HOMEPAGE = "http://www.freerdp.com"
  5. DEPENDS = "openssl alsa-lib pcsc-lite"
  6. SECTION = "net"
  7. LICENSE = "Apache-2.0"
  8. LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
  9. inherit pkgconfig cmake gitpkgv
  10. PE = "1"
  11. PKGV = "${GITPKGVTAG}"
  12. SRCREV = "d2ba84a6885f57674098fe8e76c5f99d880e580d"
  13. SRC_URI = "git://github.com/FreeRDP/FreeRDP.git;branch=stable-2.0 \
  14. file://winpr-makecert-Build-with-install-RPATH.patch \
  15. "
  16. S = "${WORKDIR}/git"
  17. EXTRA_OECMAKE += " \
  18. -DWITH_ALSA=ON \
  19. -DWITH_PCSC=ON \
  20. -DWITH_FFMPEG=OFF \
  21. -DWITH_CUNIT=OFF \
  22. -DWITH_NEON=OFF \
  23. -DBUILD_STATIC_LIBS=OFF \
  24. -DCMAKE_POSITION_INDEPENDANT_CODE=ON \
  25. -DWITH_MANPAGES=OFF \
  26. "
  27. PACKAGECONFIG ??= " \
  28. ${@bb.utils.filter('DISTRO_FEATURES', 'directfb pam pulseaudio wayland x11', d)}\
  29. gstreamer cups \
  30. "
  31. X11_DEPS = "virtual/libx11 libxinerama libxext libxcursor libxv libxi libxrender libxfixes libxdamage libxrandr libxkbfile"
  32. PACKAGECONFIG[x11] = "-DWITH_X11=ON -DWITH_XINERAMA=ON -DWITH_XEXT=ON -DWITH_XCURSOR=ON -DWITH_XV=ON -DWITH_XI=ON -DWITH_XRENDER=ON -DWITH_XFIXES=ON -DWITH_XDAMAGE=ON -DWITH_XRANDR=ON -DWITH_XKBFILE=ON,-DWITH_X11=OFF,${X11_DEPS}"
  33. PACKAGECONFIG[wayland] = "-DWITH_WAYLAND=ON,-DWITH_WAYLAND=OFF,wayland wayland-native libxkbcommon"
  34. PACKAGECONFIG[directfb] = "-DWITH_DIRECTFB=ON,-DWITH_DIRECTFB=OFF,directfb"
  35. PACKAGECONFIG[pam] = "-DWITH_PAM=ON,-DWITH_PAM=OFF,libpam"
  36. PACKAGECONFIG[pulseaudio] = "-DWITH_PULSEAUDIO=ON,-DWITH_PULSEAUDIO=OFF,pulseaudio"
  37. PACKAGECONFIG[gstreamer] = "-DWITH_GSTREAMER_1_0=ON,-DWITH_GSTREAMER_1_0=OFF,gstreamer1.0 gstreamer1.0-plugins-base"
  38. PACKAGECONFIG[cups] = "-DWITH_CUPS=ON,-DWITH_CUPS=OFF,cups"
  39. PACKAGES =+ "libfreerdp"
  40. LEAD_SONAME = "libfreerdp.so"
  41. FILES_libfreerdp = "${libdir}/lib*${SOLIBS}"
  42. PACKAGES_DYNAMIC += "^libfreerdp-plugin-.*"
  43. # we will need winpr-makecert to generate TLS certificates
  44. do_install_append () {
  45. install -d ${D}${bindir}
  46. install -m755 winpr/tools/makecert-cli/winpr-makecert ${D}${bindir}
  47. rm -rf ${D}${libdir}/cmake
  48. rm -rf ${D}${libdir}/freerdp
  49. }
  50. python populate_packages_prepend () {
  51. freerdp_root = d.expand('${libdir}/freerdp')
  52. do_split_packages(d, freerdp_root, '^(audin_.*)\.so$',
  53. output_pattern='libfreerdp-plugin-%s',
  54. description='FreeRDP plugin %s',
  55. prepend=True, extra_depends='libfreerdp-plugin-audin')
  56. do_split_packages(d, freerdp_root, '^(rdpsnd_.*)\.so$',
  57. output_pattern='libfreerdp-plugin-%s',
  58. description='FreeRDP plugin %s',
  59. prepend=True, extra_depends='libfreerdp-plugin-rdpsnd')
  60. do_split_packages(d, freerdp_root, '^(tsmf_.*)\.so$',
  61. output_pattern='libfreerdp-plugin-%s',
  62. description='FreeRDP plugin %s',
  63. prepend=True, extra_depends='libfreerdp-plugin-tsmf')
  64. do_split_packages(d, freerdp_root, '^([^-]*)\.so$',
  65. output_pattern='libfreerdp-plugin-%s',
  66. description='FreeRDP plugin %s',
  67. prepend=True, extra_depends='')
  68. }