broadcom-bt-firmware_12.0.1.1105_p2.bb 2.7 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576
  1. # Copyright (C) 2018 Krzysztof Kozlowski <krzk@kernel.org>
  2. # Released under the MIT license (see COPYING.MIT for the terms)
  3. SUMMARY = "Broadcom Bluetooth firmware files"
  4. DESCRIPTION = "Firmware for Broadcom Bluetooth devices. Note that in case of BT+WiFi devices, separate WiFi firmware might be needed."
  5. HOMEPAGE = "https://github.com/winterheart/broadcom-bt-firmware"
  6. LICENSE = "Firmware-Broadcom-WIDCOMM"
  7. NO_GENERIC_LICENSE[Firmware-Broadcom-WIDCOMM] = "LICENSE.broadcom_bcm20702"
  8. LIC_FILES_CHKSUM = "file://LICENSE.broadcom_bcm20702;md5=c0d5ea0502b00df74173d0f8a48b619d"
  9. SRC_URI = "git://github.com/winterheart/broadcom-bt-firmware.git"
  10. SRCREV = "1af1116f73782951bd7bbe2139928e497c3a634b"
  11. PE = "1"
  12. S = "${WORKDIR}/git"
  13. inherit allarch
  14. CLEANBROKEN = "1"
  15. do_compile() {
  16. :
  17. }
  18. do_install() {
  19. install -d ${D}${nonarch_base_libdir}/firmware/brcm/
  20. cp brcm/*.hcd ${D}${nonarch_base_libdir}/firmware/brcm/
  21. # For license package:
  22. install -m 0644 LICENSE.broadcom_bcm20702 ${D}${nonarch_base_libdir}/firmware/brcm/
  23. # For main package:
  24. install -m 0644 DEVICES.md ${D}${nonarch_base_libdir}/firmware/brcm/
  25. }
  26. PACKAGES =+ " \
  27. ${PN}-bcm20702a1 \
  28. ${PN}-bcm20702b0 \
  29. ${PN}-bcm20703a1 \
  30. ${PN}-bcm43142a0 \
  31. ${PN}-bcm4335c0 \
  32. ${PN}-bcm4350c5 \
  33. ${PN}-bcm4356a2 \
  34. ${PN}-bcm4371c2 \
  35. ${PN}-license \
  36. "
  37. RDEPENDS_${PN}-bcm20702a1 = "${PN}-license"
  38. RDEPENDS_${PN}-bcm20702b0 = "${PN}-license"
  39. RDEPENDS_${PN}-bcm20703a1 = "${PN}-license"
  40. RDEPENDS_${PN}-bcm43142a0 = "${PN}-license"
  41. RDEPENDS_${PN}-bcm4335c0 = "${PN}-license"
  42. RDEPENDS_${PN}-bcm4350c5 = "${PN}-license"
  43. RDEPENDS_${PN}-bcm4356a2 = "${PN}-license"
  44. RDEPENDS_${PN}-bcm4371c2 = "${PN}-license"
  45. FILES_${PN}-bcm20702a1 = "${nonarch_base_libdir}/firmware/brcm/BCM20702A1*hcd"
  46. FILES_${PN}-bcm20702b0 = "${nonarch_base_libdir}/firmware/brcm/BCM20702B0*hcd"
  47. FILES_${PN}-bcm20703a1 = "${nonarch_base_libdir}/firmware/brcm/BCM20703A1*hcd"
  48. FILES_${PN}-bcm43142a0 = "${nonarch_base_libdir}/firmware/brcm/BCM43142A0*hcd"
  49. FILES_${PN}-bcm4335c0 = "${nonarch_base_libdir}/firmware/brcm/BCM4335C0*hcd"
  50. FILES_${PN}-bcm4350c5 = "${nonarch_base_libdir}/firmware/brcm/BCM4350C5*hcd"
  51. FILES_${PN}-bcm4356a2 = "${nonarch_base_libdir}/firmware/brcm/BCM4356A2*hcd"
  52. FILES_${PN}-bcm4371c2 = "${nonarch_base_libdir}/firmware/brcm/BCM4371C2*hcd"
  53. FILES_${PN}-license += "${nonarch_base_libdir}/firmware/brcm/LICENSE.broadcom_bcm20702"
  54. FILES_${PN} += "${nonarch_base_libdir}/firmware/brcm/*"
  55. RDEPENDS_${PN} += "${PN}-license"
  56. # Make broadcom-bt-firmware depend on all of the split-out packages.
  57. python populate_packages_prepend () {
  58. firmware_pkgs = oe.utils.packages_filter_out_system(d)
  59. d.appendVar('RDEPENDS_broadcom-bt-firmware', ' ' + ' '.join(firmware_pkgs))
  60. }