fbida_2.14.bb 2.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778
  1. SUMMARY = "Framebuffer image and doc viewer tools"
  2. DESCRIPTION = "The fbida project contains a few applications for viewing and editing images, \
  3. with the main focus being photos."
  4. HOMEPAGE = "http://linux.bytesex.org/fbida/"
  5. AUTHOR = "Gerd Hoffmann"
  6. SECTION = "utils"
  7. LICENSE = "GPLv2"
  8. LIC_FILES_CHKSUM = "file://COPYING;md5=e8feb78a32950a909621bbb51f634b39"
  9. DEPENDS = "virtual/libiconv jpeg fontconfig freetype libexif libdrm pixman poppler libepoxy cairo"
  10. SRC_URI = "https://www.kraxel.org/releases/fbida/fbida-${PV}.tar.gz \
  11. file://0001-Avoid-using-host-path.patch \
  12. file://fix-preprocessor.patch \
  13. file://support-jpeg-turbo.patch \
  14. file://cairo-weak-detect.patch \
  15. file://fbida-gcc10.patch \
  16. "
  17. SRC_URI[sha256sum] = "95b7c01556cb6ef9819f358b314ddfeb8a4cbe862b521a3ed62f03d163154438"
  18. inherit pkgconfig features_check
  19. # Depends on libepoxy
  20. REQUIRED_DISTRO_FEATURES = "opengl"
  21. EXTRA_OEMAKE = "STRIP= 'srcdir=${S}' -f ${S}/GNUmakefile"
  22. PACKAGECONFIG ??= "gif png curl"
  23. PACKAGECONFIG[curl] = ",,curl"
  24. PACKAGECONFIG[gif] = ",,giflib"
  25. PACKAGECONFIG[png] = ",,libpng"
  26. PACKAGECONFIG[tiff] = ",,tiff"
  27. PACKAGECONFIG[motif] = ",,libx11 libxext libxpm libxt openmotif"
  28. PACKAGECONFIG[webp] = ",,libwebp"
  29. PACKAGECONFIG[lirc] = ",,lirc"
  30. # This can only be enabled when cairo has egl enabled in its packageconfig support too
  31. PACKAGECONFIG[egl] = ",,"
  32. EXTRA_OEMAKE += ""${@bb.utils.contains('PACKAGECONFIG', 'egl', 'HAVE_CAIRO_GL=yes', 'HAVE_CAIRO_GL=no', d)}""
  33. do_compile() {
  34. sed -i -e 's# fbgs# \$(srcdir)/fbgs#; s#-Ijpeg#-I\$(srcdir)/jpeg#; s# jpeg/# \$(srcdir)/jpeg/#' ${S}/GNUmakefile
  35. sed -i -e 's:/sbin/ldconfig:echo x:' ${S}/mk/Autoconf.mk
  36. sed -i -e 's: cpp: ${CPP}:' ${S}/GNUmakefile
  37. # Be sure to respect preferences (force to "no")
  38. # Also avoid issues when ${BUILD_ARCH} == ${HOST_ARCH}
  39. if [ -z "${@bb.utils.filter('PACKAGECONFIG', 'curl', d)}" ]; then
  40. sed -i -e '/^HAVE_LIBCURL/s/:=.*$/:= no/' ${S}/GNUmakefile
  41. fi
  42. if [ -z "${@bb.utils.filter('PACKAGECONFIG', 'gif', d)}" ]; then
  43. sed -i -e '/^HAVE_LIBGIF/s/:=.*$/:= no/' ${S}/GNUmakefile
  44. fi
  45. if [ -z "${@bb.utils.filter('PACKAGECONFIG', 'png', d)}" ]; then
  46. sed -i -e '/^HAVE_LIBPNG/s/:=.*$/:= no/' ${S}/GNUmakefile
  47. fi
  48. if [ -z "${@bb.utils.filter('PACKAGECONFIG', 'tiff', d)}" ]; then
  49. sed -i -e '/^HAVE_LIBTIFF/s/:=.*$/:= no/' ${S}/GNUmakefile
  50. fi
  51. if [ -z "${@bb.utils.filter('PACKAGECONFIG', 'motif', d)}" ]; then
  52. sed -i -e '/^HAVE_MOTIF/s/:=.*$/:= no/' ${S}/GNUmakefile
  53. fi
  54. if [ -z "${@bb.utils.filter('PACKAGECONFIG', 'webp', d)}" ]; then
  55. sed -i -e '/^HAVE_LIBWEBP/s/:=.*$/:= no/' ${S}/GNUmakefile
  56. fi
  57. if [ -z "${@bb.utils.filter('PACKAGECONFIG', 'lirc', d)}" ]; then
  58. sed -i -e '/^HAVE_LIBLIRC/s/:=.*$/:= no/' ${S}/GNUmakefile
  59. fi
  60. oe_runmake
  61. }
  62. do_install() {
  63. oe_runmake 'DESTDIR=${D}' install
  64. }
  65. RDEPENDS_${PN} = "ttf-dejavu-sans-mono bash"