upm_git.bb 2.4 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061
  1. SUMMARY = "Sensor/Actuator repository for Mraa"
  2. HOMEPAGE = "https://github.com/intel-iot-devkit/upm"
  3. SECTION = "libs"
  4. LICENSE = "MIT"
  5. LIC_FILES_CHKSUM = "file://LICENSE;md5=66493d54e65bfc12c7983ff2e884f37f"
  6. DEPENDS = "libjpeg-turbo mraa"
  7. SRCREV = "5cf20df96c6b35c19d5b871ba4e319e96b4df72d"
  8. PV = "2.0.0+git${SRCPV}"
  9. SRC_URI = "git://github.com/eclipse/${BPN}.git;protocol=http \
  10. file://0001-CMakeLists.txt-Use-SWIG_SUPPORT_FILES-to-find-the-li.patch \
  11. file://0001-Use-stdint-types.patch \
  12. file://0001-initialize-local-variables-before-use.patch \
  13. file://0001-cmake-Disable-Wno-misleading-indentation-with-clang-.patch \
  14. file://0001-cmake-Disable-using-Wno-maybe-uninitialized.patch \
  15. "
  16. SRC_URI_append_toolchain-clang_x86 = " file://0001-nmea_gps-Link-with-latomic.patch "
  17. S = "${WORKDIR}/git"
  18. # Depends on mraa which only supports x86 and ARM for now
  19. COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
  20. inherit distutils3-base cmake pkgconfig
  21. EXTRA_OECMAKE += "-UPYTHON_EXECUTABLE -DWERROR=off"
  22. # override this in local.conf to get needed bindings.
  23. # BINDINGS_pn-upm="python"
  24. # will result in only the python bindings being built/packaged.
  25. # Note: 'nodejs' is disabled by default because the bindings
  26. # generation currently fails with nodejs (>v7.x).
  27. BINDINGS ??= "python"
  28. # nodejs isn't available for armv4/armv5 architectures
  29. BINDINGS_armv4 ??= "python"
  30. BINDINGS_armv5 ??= "python"
  31. PACKAGECONFIG ??= "${@bb.utils.contains('PACKAGES', 'node-${PN}', 'nodejs', '', d)} \
  32. ${@bb.utils.contains('PACKAGES', '${PYTHON_PN}-${PN}', 'python', '', d)}"
  33. PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON -DPYTHON_LIBRARY=${STAGING_LIBDIR}/lib${PYTHON_DIR}${PYTHON_ABI}.so -DPYTHON_INCLUDE_DIR=${STAGING_INCDIR}/${PYTHON_DIR}${PYTHON_ABI}, -DBUILDSWIGPYTHON=OFF, swig-native ${PYTHON_PN},"
  34. PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs-native,"
  35. do_configure_prepend() {
  36. sed -i s:\"lib/${_packages_path}:\"${baselib}/${_packages_path}:g ${S}/cmake/modules/OpenCVDetectPython.cmake
  37. }
  38. FILES_${PYTHON_PN}-${PN} = "${PYTHON_SITEPACKAGES_DIR}"
  39. RDEPENDS_${PYTHON_PN}-${PN} += "${PYTHON_PN}"
  40. FILES_node-${PN} = "${prefix}/lib/node_modules/"
  41. RDEPENDS_node-${PN} += "nodejs"
  42. ### Include desired language bindings ###
  43. PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'nodejs', 'node-${PN}', '', d)}"
  44. PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'python', '${PYTHON_PN}-${PN}', '', d)}"