irda-utils_0.9.18.bb 1.9 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364
  1. SUMMARY = "Common files for IrDA"
  2. DESCRIPTION = "Provides common files needed to use IrDA. \
  3. IrDA allows communication over Infrared with other devices \
  4. such as phones and laptops."
  5. HOMEPAGE = "http://irda.sourceforge.net/"
  6. BUGTRACKER = "http://sourceforge.net/p/irda/bugs/"
  7. SECTION = "base"
  8. LICENSE = "GPLv2+"
  9. LIC_FILES_CHKSUM = "file://irdadump/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
  10. file://smcinit/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
  11. file://man/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
  12. file://irdadump/irdadump.c;beginline=1;endline=24;md5=d78b9dce3cd78c2220250c9c7a2be178"
  13. SRC_URI = "${SOURCEFORGE_MIRROR}/irda/irda-utils-${PV}.tar.gz \
  14. file://ldflags.patch \
  15. file://musl.patch \
  16. file://init"
  17. SRC_URI[md5sum] = "84dc12aa4c3f61fccb8d8919bf4079bb"
  18. SRC_URI[sha256sum] = "61980551e46b2eaa9e17ad31cbc1a638074611fc33bff34163d10c7a67a9fdc6"
  19. inherit update-rc.d
  20. RRECOMMENDS_${PN} = "\
  21. kernel-module-pxaficp-ir \
  22. kernel-module-irda \
  23. kernel-module-ircomm \
  24. kernel-module-ircomm-tty \
  25. kernel-module-irlan \
  26. ${@bb.utils.contains('DISTRO_FEATURES', 'ppp', 'kernel-module-irnet', '',d)} \
  27. kernel-module-irport \
  28. kernel-module-irtty \
  29. kernel-module-irtty-sir \
  30. kernel-module-sir-dev \
  31. ${@bb.utils.contains('COMBINED_FEATURES', 'usbhost', 'kernel-module-ir-usb', '',d)} "
  32. EXTRA_OEMAKE = "\
  33. 'CC=${CC}' \
  34. 'LD=${LD}' \
  35. 'CFLAGS=${CFLAGS}' \
  36. 'LDFLAGS=${LDFLAGS}' \
  37. 'SYS_INCLUDES=' \
  38. 'V=1' \
  39. "
  40. INITSCRIPT_NAME = "irattach"
  41. INITSCRIPT_PARAMS = "defaults 20"
  42. TARGETS ??= "irattach irdaping"
  43. do_compile () {
  44. for t in ${TARGETS}; do
  45. oe_runmake -C $t
  46. done
  47. }
  48. do_install () {
  49. install -d ${D}${sbindir}
  50. for t in ${TARGETS}; do
  51. oe_runmake -C $t ROOT="${D}" install
  52. done
  53. install -d ${D}${sysconfdir}/init.d
  54. install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
  55. }