dvb-apps_1.1.1.bb 3.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101
  1. SUMMARY = "Linux DVB API applications and utilities"
  2. HOMEPAGE = "http://www.linuxtv.org"
  3. LICENSE = "GPLv2"
  4. LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
  5. SRCREV = "3d43b280298c39a67d1d889e01e173f52c12da35"
  6. SRC_URI = "hg://linuxtv.org/hg;module=dvb-apps;protocol=http \
  7. file://dvb-scan-table \
  8. file://0001-Fix-generate-keynames.patch \
  9. file://0003-handle-static-shared-only-build.patch \
  10. file://0004-Makefile-remove-test.patch \
  11. file://0005-libucsi-optimization-removal.patch \
  12. file://0006-CA_SET_PID.patch \
  13. file://0001-dvbdate-Remove-Obsoleted-stime-API-calls.patch \
  14. "
  15. S = "${WORKDIR}/${BPN}"
  16. inherit perlnative
  17. export enable_static="no"
  18. do_configure() {
  19. sed -i -e s:/usr/include:${STAGING_INCDIR}:g util/av7110_loadkeys/generate-keynames.sh
  20. }
  21. do_install() {
  22. make DESTDIR=${D} install
  23. install -d ${D}/${bindir}
  24. install -d ${D}/${docdir}/dvb-apps
  25. install -d ${D}/${docdir}/dvb-apps/scan
  26. install -d ${D}/${docdir}/dvb-apps/szap
  27. chmod a+rx ${D}/${libdir}/*.so*
  28. cp -R --no-dereference --preserve=mode,links ${S}/util/szap/channels-conf* ${D}/${docdir}/dvb-apps/szap/
  29. cp -R --no-dereference --preserve=mode,links ${S}/util/szap/README ${D}/${docdir}/dvb-apps/szap/
  30. cp -R --no-dereference --preserve=mode,links ${WORKDIR}/dvb-scan-table/* ${D}/usr/share/dvb
  31. }
  32. PACKAGES =+ "dvb-evtest dvb-evtest-dbg \
  33. dvbapp-tests dvbapp-tests-dbg \
  34. dvbdate dvbdate-dbg \
  35. dvbtraffic dvbtraffic-dbg \
  36. dvbnet dvbnet-dbg \
  37. dvb-scan dvb-scan-dbg dvb-scan-data \
  38. dvb-azap dvb-azap-dbg \
  39. dvb-czap dvb-czap-dbg \
  40. dvb-szap dvb-szap-dbg \
  41. dvb-tzap dvb-tzap-dbg \
  42. dvb-femon dvb-femon-dbg \
  43. dvb-zap-data"
  44. PACKAGES =+ "libdvbapi libdvbcfg libdvben50221 \
  45. libesg libucsi libdvbsec"
  46. RDEPENDS_dvbdate =+ "libdvbapi libucsi"
  47. RDEPENDS_dvbtraffic =+ "libdvbapi"
  48. RDEPENDS_dvb-scan =+ "libdvbapi libdvbcfg libdvbsec"
  49. RDEPENDS_dvb-apps =+ "libdvbapi libdvbcfg libdvbsec libdvben50221 libucsi"
  50. RDEPENDS_dvb-femon =+ "libdvbapi"
  51. RDEPENDS_dvbnet =+ "libdvbapi"
  52. RCONFLICTS_dvb-evtest = "evtest"
  53. FILES_${PN} = "${bindir} ${datadir}/dvb"
  54. FILES_${PN}-doc = ""
  55. FILES_${PN}-dev = "${includedir}"
  56. FILES_dvb-evtest = "${bindir}/evtest"
  57. FILES_dvb-evtest-dbg = "${bindir}/.debug/evtest"
  58. FILES_dvbapp-tests = "${bindir}/*test* "
  59. FILES_dvbapp-tests-dbg = "${bindir}/.debug/*test*"
  60. FILES_dvbdate = "${bindir}/dvbdate"
  61. FILES_dvbdate-dbg = "${bindir}/.debug/dvbdate"
  62. FILES_dvbtraffic = "${bindir}/dvbtraffic"
  63. FILES_dvbtraffic-dbg = "${bindir}/.debug/dvbtraffic"
  64. FILES_dvbnet = "${bindir}/dvbnet"
  65. FILES_dvbnet-dbg = "${bindir}/.debug/dvbnet"
  66. FILES_dvb-scan = "${bindir}/*scan "
  67. FILES_dvb-scan-dbg = "${bindir}/.debug/*scan"
  68. FILES_dvb-scan-data = "${docdir}/dvb-apps/scan"
  69. FILES_dvb-azap = "${bindir}/azap"
  70. FILES_dvb-azap-dbg = "${bindir}/.debug/azap"
  71. FILES_dvb-czap = "${bindir}/czap"
  72. FILES_dvb-czap-dbg = "${bindir}/.debug/czap"
  73. FILES_dvb-szap = "${bindir}/szap"
  74. FILES_dvb-szap-dbg = "${bindir}/.debug/szap"
  75. FILES_dvb-tzap = "${bindir}/tzap"
  76. FILES_dvb-tzap-dbg = "${bindir}/.debug/tzap"
  77. FILES_dvb-femon = "${bindir}/femon"
  78. FILES_dvb-femon-dbg = "${bindir}/.debug/femon"
  79. FILES_dvb-zap-data = "${docdir}/dvb-apps/szap"
  80. python populate_packages_prepend () {
  81. dvb_libdir = bb.data.expand('${libdir}', d)
  82. do_split_packages(d, dvb_libdir, '^lib(.*)\.so$', 'lib%s', 'DVB %s package', extra_depends='', allow_links=True)
  83. do_split_packages(d, dvb_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'DVB %s development package', extra_depends='${PN}-dev')
  84. do_split_packages(d, dvb_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'DVB %s development package', extra_depends='${PN}-dev')
  85. do_split_packages(d, dvb_libdir, '^lib(.*)\.so\.*', 'lib%s', 'DVB %s library', extra_depends='', allow_links=True)
  86. }
  87. INSANE_SKIP_${PN} = "ldflags"
  88. INSANE_SKIP_${PN}-dev = "ldflags"
  89. TARGET_CC_ARCH += "${LDFLAGS}"