accountsservice_0.6.55.bb 1.0 KB

123456789101112131415161718192021222324252627282930313233
  1. DESCRIPTION = "D-Bus interfaces for querying and manipulating user account information"
  2. HOMEPAGE = "https://www.freedesktop.org/wiki/Software/AccountsService/"
  3. LICENSE = "GPLv3"
  4. LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
  5. DEPENDS = " \
  6. dbus \
  7. polkit \
  8. "
  9. inherit meson gobject-introspection gtk-doc features_check systemd
  10. REQUIRED_DISTRO_FEATURES = "polkit"
  11. SRC_URI = "https://www.freedesktop.org/software/${BPN}/${BPN}-${PV}.tar.xz"
  12. SRC_URI_append_libc-musl = " \
  13. file://0001-musl-Hack-to-fix-build.patch \
  14. file://0002-musl-add-missing-fgetspent_r.patch \
  15. "
  16. SRC_URI[md5sum] = "6e4c6fbd490260cfe17de2e76f5d803a"
  17. SRC_URI[sha256sum] = "ff2b2419a7e06bd9cb335ffe391c7409b49a0f0130b890bd54692a3986699c9b"
  18. GTKDOC_MESON_OPTION = "gtk_doc"
  19. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
  20. PACKAGECONFIG[systemd] = "-Dsystemd=true, -Dsystemd=false -Dsystemdsystemunitdir='no', systemd"
  21. SYSTEMD_SERVICE_${PN} = "accounts-daemon.service"
  22. FILES_${PN} += " \
  23. ${datadir}/dbus-1 \
  24. ${datadir}/polkit-1 \
  25. "