gdm_2.32.2.bb 3.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105
  1. SUMMARY = "Graphical login manager"
  2. LICENSE = "GPLv2"
  3. LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
  4. DEPENDS = "xinput gnome-panel tcp-wrappers libcanberra libxklavier grep consolekit libpam gnome-doc-utils gtk+ xrdb"
  5. PR = "r18"
  6. inherit gnome update-rc.d systemd useradd
  7. SRC_URI += " \
  8. file://cross-xdetection.diff \
  9. file://0001-Remove-user-switch-applet.patch \
  10. file://0002-gdm-user-manager.c-avoid-displaying-system-users-in-.patch \
  11. file://sysrooted-pkg-config.patch \
  12. file://%gconf-tree.xml \
  13. file://gdm \
  14. file://gdm.conf \
  15. file://gdm-pam \
  16. file://Default \
  17. file://gdm.service.in \
  18. "
  19. SRC_URI[archive.md5sum] = "dbe5187a2e17881cc454e313e0ae8d1e"
  20. SRC_URI[archive.sha256sum] = "034d23af0ea18d86e5543e707212d9297ec7d83f221808968af266dbebc0e703"
  21. GNOME_COMPRESS_TYPE="bz2"
  22. EXTRA_OECONF = " \
  23. --enable-authentication-scheme=shadow \
  24. --enable-debug=yes \
  25. --with-console-kit \
  26. --disable-scrollkeeper \
  27. "
  28. do_configure_prepend() {
  29. sed -i -e "s:\bdocs::g" ${S}/Makefile.am
  30. }
  31. do_install_prepend() {
  32. install -d ${D}/${localstatedir}/lib/gdm/.gconf.mandatory
  33. install ${WORKDIR}/%gconf-tree.xml ${D}/${localstatedir}/lib/gdm/.gconf.mandatory/
  34. }
  35. do_install_append() {
  36. install -d ${D}/${sysconfdir}/init.d
  37. install -m 0755 ${WORKDIR}/gdm ${D}/${sysconfdir}/init.d/
  38. install -d ${D}/${sysconfdir}/gdm
  39. install -m 0644 ${WORKDIR}/gdm.conf ${D}/${sysconfdir}/gdm/
  40. install -d ${D}/${sysconfdir}/pam.d
  41. install -m 0755 ${WORKDIR}/gdm-pam ${D}/${sysconfdir}/pam.d/gdm
  42. rm -f ${D}/${sysconfdir}/pam.d/gdm-autologin
  43. install -d ${D}/${sysconfdir}/gdm/Init
  44. install -m 0755 ${WORKDIR}/Default ${D}/${sysconfdir}/gdm/Init
  45. install -d ${D}${systemd_unitdir}/system
  46. sed -e 's,%sbindir%,${sbindir},g' \
  47. < ${WORKDIR}/gdm.service.in \
  48. > ${D}${systemd_unitdir}/system/gdm.service
  49. chown -R gdm:gdm ${D}${localstatedir}/lib/gdm
  50. chmod 0750 ${D}${localstatedir}/lib/gdm
  51. rm -rf "${D}${localstatedir}/run"
  52. rmdir --ignore-fail-on-non-empty "${D}${localstatedir}"
  53. rm -f ${D}${datadir}/gdm/autostart/LoginWindow/at-spi-registryd-wrapper.desktop
  54. rm -f ${D}${datadir}/gdm/autostart/LoginWindow/orca-screen-reader.desktop
  55. rm -f ${D}${datadir}/gdm/autostart/LoginWindow/gnome-mag.desktop
  56. rm -f ${D}${datadir}/gdm/autostart/LoginWindow/gok.desktop
  57. rm -f ${D}${datadir}/gdm/autostart/LoginWindow/metacity.desktop
  58. }
  59. FILES_${PN} += "${datadir}/icon* \
  60. ${datadir}/xsession* \
  61. "
  62. RDEPENDS_${PN} += "grep dbus-x11 shadow"
  63. # "libpam-base-files"
  64. CONFFILES_${PN} += "${sysconfdir}/gdm/gdm.conf ${sysconfdir}/init.d/gdm"
  65. RRECOMMENDS_${PN} += "openssh-misc desktop-file-utils glib-2.0-utils metacity gnome-session polkit-gnome consolekit"
  66. RREPLACES_${PN} += "${PN}-systemd"
  67. RCONFLICTS_${PN} += "${PN}-systemd"
  68. SYSTEMD_SERVICE_${PN} = "gdm.service"
  69. INITSCRIPT_NAME = "gdm"
  70. INITSCRIPT_PARAMS = "start 99 5 . stop 20 0 1 2 3 6 ."
  71. USERADD_PACKAGES = "${PN}"
  72. USERADD_PARAM_${PN} = "--system --no-create-home --home ${localstatedir}/lib/gdm --user-group gdm"
  73. pkg_postinst_${PN} () {
  74. # Register up as default dm
  75. mkdir -p $D${sysconfdir}/X11/
  76. echo "${bindir}/gdm" > $D${sysconfdir}/X11/default-display-manager
  77. }
  78. pkg_postrm_${PN} () {
  79. deluser gdm || true
  80. delgroup gdm || true
  81. sed -i /gdm/d ${sysconfdir}/X11/default-display-manager || true
  82. }