android-tools_5.1.1.r37.bb 6.4 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170
  1. DESCRIPTION = "Different utilities from Android"
  2. SECTION = "console/utils"
  3. LICENSE = "Apache-2.0 & GPL-2.0 & BSD-2-Clause & BSD-3-Clause"
  4. LIC_FILES_CHKSUM = " \
  5. file://${COMMON_LICENSE_DIR}/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10 \
  6. file://${COMMON_LICENSE_DIR}/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6 \
  7. file://${COMMON_LICENSE_DIR}/BSD-2-Clause;md5=cb641bc04cda31daea161b1bc15da69f \
  8. file://${COMMON_LICENSE_DIR}/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9 \
  9. "
  10. DEPENDS = "libbsd libpcre zlib libcap"
  11. DEPENDS_append_class-target = " openssl"
  12. ANDROID_MIRROR = "android.googlesource.com"
  13. # matches with android-5.1.1_r37
  14. SRCREV_core = "2314b110bdebdbfd2d94c502282f9e57c849897e"
  15. SRCREV_extras = "3ecbe8d841df96127d7855661293e5ab6ba6c205"
  16. SRCREV_libhardware = "be55eb1f4d840c82ffaf7c47460df17ff5bc4d9b"
  17. SRCREV_libselinux = "07e9e1339ad1ba608acfba9dce2d0f474b252feb"
  18. SRCREV_build = "16e987def3d7d8f7d30805eb95cef69e52a87dbc"
  19. SRC_URI = " \
  20. git://${ANDROID_MIRROR}/platform/system/core;name=core;protocol=https;nobranch=1;destsuffix=git/system/core \
  21. git://${ANDROID_MIRROR}/platform/system/extras;name=extras;protocol=https;nobranch=1;destsuffix=git/system/extras \
  22. git://${ANDROID_MIRROR}/platform/hardware/libhardware;name=libhardware;protocol=https;nobranch=1;destsuffix=git/hardware/libhardware \
  23. git://${ANDROID_MIRROR}/platform/external/libselinux;name=libselinux;protocol=https;nobranch=1;destsuffix=git/external/libselinux \
  24. git://${ANDROID_MIRROR}/platform/build;name=build;protocol=https;nobranch=1;destsuffix=git/build \
  25. file://core/0001-adb-remove-selinux-extensions.patch;patchdir=system/core \
  26. file://core/0002-adb-Use-local-sockets-where-appropriate.patch;patchdir=system/core \
  27. file://core/0003-adb-define-shell-command.patch;patchdir=system/core \
  28. file://core/0004-adb-Fix-build-on-big-endian-systems.patch;patchdir=system/core \
  29. file://core/0005-adb-add-base64-implementation.patch;patchdir=system/core \
  30. file://core/0006-adb-Musl-fixes.patch;patchdir=system/core \
  31. file://core/0007-adb-usb_linux.c-fix-build-with-glibc-2.28.patch;patchdir=system/core \
  32. file://core/0008-adb-Allow-adbd-to-be-ran-as-root.patch;patchdir=system/core \
  33. file://core/0009-mkbootimg-Add-dt-parameter-to-specify-DT-image.patch;patchdir=system/core \
  34. file://core/0010-Use-linux-capability.h-on-linux-systems-too.patch;patchdir=system/core \
  35. file://core/0011-Remove-bionic-specific-calls.patch;patchdir=system/core \
  36. file://core/0012-Fix-implicit-declaration-of-stlcat-strlcopy-function.patch;patchdir=system/core \
  37. file://core/adb_libssl_11.diff;patchdir=system/core \
  38. file://extras/0001-ext4_utils-remove-selinux-extensions.patch;patchdir=system/extras \
  39. file://extras/0002-ext4_utils-add-o-argument-to-preserve-ownership.patch;patchdir=system/extras \
  40. file://libselinux/0001-Remove-bionic-specific-calls.patch;patchdir=external/libselinux \
  41. file://libselinux/0001-libselinux-Do-not-define-gettid-if-glibc-2.30-is-use.patch;patchdir=external/libselinux \
  42. file://android-tools-adbd.service \
  43. file://gitignore \
  44. file://adb.mk;subdir=${BPN} \
  45. file://adbd.mk;subdir=${BPN} \
  46. file://ext4_utils.mk;subdir=${BPN} \
  47. file://fastboot.mk;subdir=${BPN} \
  48. file://mkbootimg.mk;subdir=${BPN} \
  49. "
  50. S = "${WORKDIR}/git"
  51. B = "${WORKDIR}/${BPN}"
  52. # http://errors.yoctoproject.org/Errors/Details/133881/
  53. ARM_INSTRUCTION_SET_armv4 = "arm"
  54. ARM_INSTRUCTION_SET_armv5 = "arm"
  55. COMPATIBLE_HOST_powerpc = "(null)"
  56. COMPATIBLE_HOST_powerpc64 = "(null)"
  57. COMPATIBLE_HOST_powerpc64le = "(null)"
  58. inherit systemd
  59. SYSTEMD_SERVICE_${PN} = "android-tools-adbd.service"
  60. # Find libbsd headers during native builds
  61. CC_append_class-native = " -I${STAGING_INCDIR}"
  62. CC_append_class-nativesdk = " -I${STAGING_INCDIR}"
  63. TOOLS = "adb fastboot ext4_utils mkbootimg adbd"
  64. # Adb needs sys/capability.h, which is not available for native*
  65. TOOLS_class-native = "fastboot ext4_utils mkbootimg"
  66. TOOLS_class-nativesdk = "fastboot ext4_utils mkbootimg"
  67. do_compile() {
  68. cp ${WORKDIR}/gitignore ${S}/.gitignore
  69. # Setting both variables below causing our makefiles to not work with
  70. # implicit make rules
  71. unset CFLAGS
  72. unset CPPFLAGS
  73. export SRCDIR=${S}
  74. case "${HOST_ARCH}" in
  75. arm)
  76. export android_arch=linux-arm
  77. ;;
  78. aarch64)
  79. export android_arch=linux-arm64
  80. ;;
  81. mips|mipsel)
  82. export android_arch=linux-mips
  83. ;;
  84. mips64|mips64el)
  85. export android_arch=linux-mips64
  86. ;;
  87. powerpc|powerpc64)
  88. export android_arch=linux-ppc
  89. ;;
  90. i586|i686|x86_64)
  91. export android_arch=linux-x86
  92. ;;
  93. esac
  94. for tool in ${TOOLS}; do
  95. mkdir -p ${B}/${tool}
  96. oe_runmake -f ${B}/${tool}.mk -C ${B}/${tool}
  97. done
  98. }
  99. do_install() {
  100. if echo ${TOOLS} | grep -q "ext4_utils" ; then
  101. install -D -p -m0755 ${S}/system/core/libsparse/simg_dump.py ${D}${bindir}/simg_dump
  102. install -D -p -m0755 ${S}/system/extras/ext4_utils/mkuserimg.sh ${D}${bindir}/mkuserimg
  103. install -m0755 ${B}/ext4_utils/ext2simg ${D}${bindir}
  104. install -m0755 ${B}/ext4_utils/ext4fixup ${D}${bindir}
  105. install -m0755 ${B}/ext4_utils/img2simg ${D}${bindir}
  106. install -m0755 ${B}/ext4_utils/make_ext4fs ${D}${bindir}
  107. install -m0755 ${B}/ext4_utils/simg2img ${D}${bindir}
  108. install -m0755 ${B}/ext4_utils/simg2simg ${D}${bindir}
  109. fi
  110. if echo ${TOOLS} | grep -q "adb " ; then
  111. install -d ${D}${bindir}
  112. install -m0755 ${B}/adb/adb ${D}${bindir}
  113. fi
  114. if echo ${TOOLS} | grep -q "adbd" ; then
  115. install -d ${D}${bindir}
  116. install -m0755 ${B}/adbd/adbd ${D}${bindir}
  117. fi
  118. # Outside the if statement to avoid errors during do_package
  119. install -D -p -m0644 ${WORKDIR}/android-tools-adbd.service \
  120. ${D}${systemd_unitdir}/system/android-tools-adbd.service
  121. if echo ${TOOLS} | grep -q "fastboot" ; then
  122. install -d ${D}${bindir}
  123. install -m0755 ${B}/fastboot/fastboot ${D}${bindir}
  124. fi
  125. if echo ${TOOLS} | grep -q "mkbootimg" ; then
  126. install -d ${D}${bindir}
  127. install -m0755 ${B}/mkbootimg/mkbootimg ${D}${bindir}
  128. fi
  129. }
  130. PACKAGES += "${PN}-fstools"
  131. RDEPENDS_${BPN} = "${BPN}-conf bash"
  132. FILES_${PN}-fstools = "\
  133. ${bindir}/ext2simg \
  134. ${bindir}/ext4fixup \
  135. ${bindir}/img2simg \
  136. ${bindir}/make_ext4fs \
  137. ${bindir}/simg2img \
  138. ${bindir}/simg2simg \
  139. ${bindir}/simg_dump \
  140. ${bindir}/mkuserimg \
  141. "
  142. BBCLASSEXTEND = "native"