libhugetlbfs_git.bb 2.7 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374
  1. SUMMARY = "A library which provides easy access to huge pages of memory"
  2. HOMEPAGE = "https://github.com/libhugetlbfs/libhugetlbfs"
  3. LICENSE = "LGPLv2.1"
  4. LIC_FILES_CHKSUM = "file://LGPL-2.1;md5=2d5025d4aa3495befef8f17206a5b0a1"
  5. DEPENDS = "sysfsutils"
  6. RDEPENDS_${PN} += "bash python python-io python-lang python-subprocess python-resource"
  7. RDEPENDS_${PN}-tests += "bash python3-core"
  8. PV = "2.22"
  9. PE = "1"
  10. SRCREV = "e6499ff92b4a7dcffbd131d1f5d24933e48c3f20"
  11. SRC_URI = " \
  12. git://github.com/libhugetlbfs/libhugetlbfs.git;protocol=https \
  13. file://skip-checking-LIB32-and-LIB64-if-they-point-to-the-s.patch \
  14. file://libhugetlbfs-avoid-search-host-library-path-for-cros.patch \
  15. file://tests-Makefile-install-static-4G-edge-testcases.patch \
  16. file://0001-run_test.py-not-use-hard-coded-path-.-obj-hugeadm.patch \
  17. file://libhugetlbfs-elf_i386-avoid-search-host-library-path.patch \
  18. file://0001-include-stddef.h-for-ptrdiff_t.patch \
  19. file://0002-Mark-glibc-specific-code-so.patch \
  20. file://0003-alloc.c-Avoid-sysconf-_SC_LEVEL2_CACHE_LINESIZE-on-l.patch \
  21. file://0004-shm.c-Mark-glibc-specific-changes-so.patch \
  22. file://0005-Include-dirent.h-for-ino_t.patch \
  23. file://0006-include-limits.h-for-PATH_MAX.patch \
  24. file://0001-tests-add-explicit-permissions-to-open-call.patch \
  25. "
  26. UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
  27. S = "${WORKDIR}/git"
  28. COMPATIBLE_HOST = "(i.86|x86_64|powerpc|powerpc64|aarch64|arm).*-linux*"
  29. LIBARGS = "LIB32=${baselib} LIB64=${baselib}"
  30. LIBHUGETLBFS_ARCH = "${TARGET_ARCH}"
  31. LIBHUGETLBFS_ARCH_powerpc = "ppc"
  32. LIBHUGETLBFS_ARCH_powerpc64 = "ppc64"
  33. LIBHUGETLBFS_ARCH_powerpc64le = "ppc64"
  34. EXTRA_OEMAKE = "'ARCH=${LIBHUGETLBFS_ARCH}' 'OPT=${CFLAGS}' 'CC=${CC}' ${LIBARGS} BUILDTYPE=NATIVEONLY V=2"
  35. PARALLEL_MAKE = ""
  36. CFLAGS += "-fexpensive-optimizations -frename-registers -fomit-frame-pointer -g0"
  37. export HUGETLB_LDSCRIPT_PATH="${S}/ldscripts"
  38. TARGET_CC_ARCH += "${LDFLAGS}"
  39. #The CUSTOM_LDSCRIPTS doesn't work with the gold linker
  40. inherit cpan-base
  41. do_configure() {
  42. if [ "${@bb.utils.filter('DISTRO_FEATURES', 'ld-is-gold', d)}" ]; then
  43. sed -i 's/CUSTOM_LDSCRIPTS = yes/CUSTOM_LDSCRIPTS = no/' Makefile
  44. fi
  45. }
  46. do_install() {
  47. oe_runmake PREFIX=${prefix} DESTDIR=${D} \
  48. INST_TESTSDIR32=${libdir}/libhugetlbfs/tests \
  49. INST_TESTSDIR64=${libdir}/libhugetlbfs/tests \
  50. install-tests
  51. }
  52. PACKAGES =+ "${PN}-tests "
  53. FILES_${PN} += "${libdir}/*.so"
  54. FILES_${PN}-dev = "${includedir}"
  55. FILES_${PN}-dbg += "${libdir}/libhugetlbfs/tests/obj32/.debug ${libdir}/libhugetlbfs/tests/obj64/.debug"
  56. FILES_${PN}-tests += "${libdir}/libhugetlbfs/tests"
  57. INSANE_SKIP_${PN} = "dev-so"
  58. INHIBIT_PACKAGE_STRIP = "1"
  59. INHIBIT_PACKAGE_DEBUG_SPLIT = "1"