redis_6.0.9.bb 2.3 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667
  1. SUMMARY = "Redis key-value store"
  2. DESCRIPTION = "Redis is an open source, advanced key-value store."
  3. HOMEPAGE = "http://redis.io"
  4. SECTION = "libs"
  5. LICENSE = "BSD-3-Clause"
  6. LIC_FILES_CHKSUM = "file://COPYING;md5=8ffdd6c926faaece928cf9d9640132d2"
  7. DEPENDS = "readline lua ncurses"
  8. SRC_URI = "http://download.redis.io/releases/${BP}.tar.gz \
  9. file://redis.conf \
  10. file://init-redis-server \
  11. file://redis.service \
  12. file://hiredis-use-default-CC-if-it-is-set.patch \
  13. file://lua-update-Makefile-to-use-environment-build-setting.patch \
  14. file://oe-use-libc-malloc.patch \
  15. file://0001-src-Do-not-reset-FINAL_LIBS.patch \
  16. file://GNU_SOURCE.patch \
  17. file://riscv32.patch \
  18. file://ilp32.patch \
  19. "
  20. SRC_URI[sha256sum] = "dc2bdcf81c620e9f09cfd12e85d3bc631c897b2db7a55218fd8a65eaa37f86dd"
  21. inherit autotools-brokensep update-rc.d systemd useradd
  22. FINAL_LIBS_x86_toolchain-clang = "-latomic"
  23. FINAL_LIBS_riscv32_toolchain-clang = "-latomic"
  24. FINAL_LIBS_mips = "-latomic"
  25. FINAL_LIBS_arm = "-latomic"
  26. FINAL_LIBS_powerpc = "-latomic"
  27. export FINAL_LIBS
  28. USERADD_PACKAGES = "${PN}"
  29. USERADD_PARAM_${PN} = "--system --home-dir /var/lib/redis -g redis --shell /bin/false redis"
  30. GROUPADD_PARAM_${PN} = "--system redis"
  31. REDIS_ON_SYSTEMD = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}"
  32. do_compile_prepend() {
  33. (cd deps && oe_runmake hiredis lua linenoise)
  34. }
  35. do_install() {
  36. export PREFIX=${D}/${prefix}
  37. oe_runmake install
  38. install -d ${D}/${sysconfdir}/redis
  39. install -m 0644 ${WORKDIR}/redis.conf ${D}/${sysconfdir}/redis/redis.conf
  40. install -d ${D}/${sysconfdir}/init.d
  41. install -m 0755 ${WORKDIR}/init-redis-server ${D}/${sysconfdir}/init.d/redis-server
  42. install -d ${D}/var/lib/redis/
  43. chown redis.redis ${D}/var/lib/redis/
  44. install -d ${D}${systemd_system_unitdir}
  45. install -m 0644 ${WORKDIR}/redis.service ${D}${systemd_system_unitdir}
  46. sed -i 's!/usr/sbin/!${sbindir}/!g' ${D}${systemd_system_unitdir}/redis.service
  47. if [ "${REDIS_ON_SYSTEMD}" = true ]; then
  48. sed -i 's!daemonize yes!# daemonize yes!' ${D}/${sysconfdir}/redis/redis.conf
  49. fi
  50. }
  51. CONFFILES_${PN} = "${sysconfdir}/redis/redis.conf"
  52. INITSCRIPT_NAME = "redis-server"
  53. INITSCRIPT_PARAMS = "defaults 87"
  54. SYSTEMD_SERVICE_${PN} = "redis.service"