php.inc 11 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264
  1. SUMMARY = "A server-side, HTML-embedded scripting language"
  2. HOMEPAGE = "http://www.php.net"
  3. SECTION = "console/network"
  4. LICENSE = "PHP-3.0"
  5. BBCLASSEXTEND = "native"
  6. DEPENDS = "zlib bzip2 libxml2 virtual/libiconv php-native lemon-native \
  7. openssl libmcrypt"
  8. DEPENDS_class-native = "zlib-native libxml2-native"
  9. PHP_MAJOR_VERSION = "${@d.getVar('PV', True).split('.')[0]}"
  10. SRC_URI = "http://php.net/distributions/php-${PV}.tar.bz2 \
  11. file://acinclude-xml2-config.patch \
  12. file://0001-php-don-t-use-broken-wrapper-for-mkdir.patch \
  13. file://0001-acinclude-use-pkgconfig-for-libxml2-config.patch \
  14. "
  15. SRC_URI_append_class-target = " \
  16. file://iconv.patch \
  17. file://imap-fix-autofoo.patch \
  18. file://pear-makefile.patch \
  19. file://phar-makefile.patch \
  20. file://php_exec_native.patch \
  21. file://php-fpm.conf \
  22. file://php-fpm-apache.conf \
  23. file://configure.patch \
  24. file://70_mod_php${PHP_MAJOR_VERSION}.conf \
  25. file://php-fpm.service \
  26. "
  27. S = "${WORKDIR}/php-${PV}"
  28. inherit autotools pkgconfig pythonnative gettext
  29. # phpize is not scanned for absolute paths by default (but php-config is).
  30. #
  31. SSTATE_SCAN_FILES += "phpize"
  32. SSTATE_SCAN_FILES += "build-defs.h"
  33. PHP_LIBDIR = "${libdir}/php${PHP_MAJOR_VERSION}"
  34. # Common EXTRA_OECONF
  35. COMMON_EXTRA_OECONF = "--enable-sockets \
  36. --enable-pcntl \
  37. --enable-shared \
  38. --disable-opcache \
  39. --disable-rpath \
  40. --with-pic \
  41. --libdir=${PHP_LIBDIR} \
  42. "
  43. EXTRA_OECONF = "--enable-mbstring \
  44. --enable-wddx \
  45. --enable-fpm \
  46. --enable-zip \
  47. --with-libdir=${baselib} \
  48. --with-gettext=${STAGING_LIBDIR}/.. \
  49. --with-zlib=${STAGING_LIBDIR}/.. \
  50. --with-iconv=${STAGING_LIBDIR}/.. \
  51. --with-mcrypt=${STAGING_DIR_TARGET}${exec_prefix} \
  52. --with-bz2=${STAGING_DIR_TARGET}${exec_prefix} \
  53. --with-config-file-path=${sysconfdir}/php/apache2-php${PHP_MAJOR_VERSION} \
  54. ${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', 'ac_cv_c_bigendian_php=no', 'ac_cv_c_bigendian_php=yes', d)} \
  55. ${@bb.utils.contains('PACKAGECONFIG', 'pam', '', 'ac_cv_lib_pam_pam_start=no', d)} \
  56. ${COMMON_EXTRA_OECONF} \
  57. "
  58. EXTRA_OECONF_class-native = " \
  59. --with-zlib=${STAGING_LIBDIR_NATIVE}/.. \
  60. --without-iconv \
  61. ${COMMON_EXTRA_OECONF} \
  62. "
  63. PACKAGECONFIG ??= "mysql sqlite3 imap \
  64. ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6 pam', d)} \
  65. "
  66. PACKAGECONFIG_class-native = ""
  67. PACKAGECONFIG[mysql] = "--with-mysql=${STAGING_DIR_TARGET}${prefix} \
  68. --with-mysqli=${STAGING_BINDIR_CROSS}/mysql_config \
  69. --with-pdo-mysql=${STAGING_BINDIR_CROSS}/mysql_config \
  70. ,--without-mysql --without-mysqli --without-pdo-mysql \
  71. ,mysql5"
  72. PACKAGECONFIG[sqlite3] = "--with-sqlite3=${STAGING_LIBDIR}/.. \
  73. --with-pdo-sqlite=${STAGING_LIBDIR}/.. \
  74. , \
  75. ,sqlite3"
  76. PACKAGECONFIG[pgsql] = "--with-pgsql=${STAGING_DIR_TARGET}${exec_prefix},--without-pgsql,postgresql"
  77. PACKAGECONFIG[soap] = "--enable-libxml --enable-soap, --disable-soap, libxml2"
  78. PACKAGECONFIG[apache2] = "--with-apxs2=${STAGING_BINDIR_CROSS}/apxs,,apache2-native apache2"
  79. PACKAGECONFIG[pam] = ",,libpam"
  80. PACKAGECONFIG[imap] = "--with-imap=${STAGING_DIR_HOST} \
  81. --with-imap-ssl=${STAGING_DIR_HOST} \
  82. ,--without-imap --without-imap-ssl \
  83. ,uw-imap"
  84. PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
  85. export PHP_NATIVE_DIR = "${STAGING_BINDIR_NATIVE}"
  86. export PHP_PEAR_PHP_BIN = "${STAGING_BINDIR_NATIVE}/php"
  87. CFLAGS += " -D_GNU_SOURCE -g -DPTYS_ARE_GETPT -DPTYS_ARE_SEARCHED -I${STAGING_INCDIR}/apache2"
  88. CFLAGS_append_aarch64 = " -O2"
  89. EXTRA_OEMAKE = "INSTALL_ROOT=${D}"
  90. acpaths = ""
  91. do_configure_prepend () {
  92. rm -f ${S}/build/libtool.m4 ${S}/ltmain.sh ${S}/aclocal.m4
  93. find ${S} -name config.m4 | xargs -n1 sed -i 's!APXS_HTTPD=.*!APXS_HTTPD=${STAGING_BINDIR_NATIVE}/httpd!'
  94. }
  95. do_configure_append() {
  96. # No, libtool, we really don't want rpath set...
  97. sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' ${HOST_SYS}-libtool
  98. sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' ${HOST_SYS}-libtool
  99. }
  100. do_install_append_class-native() {
  101. rm -rf ${D}/${PHP_LIBDIR}/php/.registry
  102. rm -rf ${D}/${PHP_LIBDIR}/php/.channels
  103. rm -rf ${D}/${PHP_LIBDIR}/php/.[a-z]*
  104. }
  105. do_install_prepend() {
  106. cat ${ACLOCALDIR}/libtool.m4 ${ACLOCALDIR}/lt~obsolete.m4 ${ACLOCALDIR}/ltoptions.m4 \
  107. ${ACLOCALDIR}/ltsugar.m4 ${ACLOCALDIR}/ltversion.m4 > ${S}/build/libtool.m4
  108. }
  109. do_install_prepend_class-target() {
  110. if ${@bb.utils.contains('PACKAGECONFIG', 'apache2', 'true', 'false', d)}; then
  111. # Install dummy config file so apxs doesn't fail
  112. install -d ${D}${sysconfdir}/apache2
  113. printf "\nLoadModule dummy_module modules/mod_dummy.so\n" > ${D}${sysconfdir}/apache2/httpd.conf
  114. fi
  115. }
  116. # fixme
  117. do_install_append_class-target() {
  118. install -d ${D}${sysconfdir}/
  119. if [ -d ${RECIPE_SYSROOT_NATIVE}${sysconfdir} ];then
  120. install -m 0644 ${RECIPE_SYSROOT_NATIVE}${sysconfdir}/pear.conf ${D}${sysconfdir}/
  121. fi
  122. rm -rf ${D}/${TMPDIR}
  123. rm -rf ${D}/.registry
  124. rm -rf ${D}/.channels
  125. rm -rf ${D}/.[a-z]*
  126. rm -rf ${D}/var
  127. rm -f ${D}/${sysconfdir}/php-fpm.conf.default
  128. sed -i 's:${STAGING_DIR_NATIVE}::g' ${D}${sysconfdir}/pear.conf
  129. install -m 0644 ${WORKDIR}/php-fpm.conf ${D}/${sysconfdir}/php-fpm.conf
  130. install -d ${D}/${sysconfdir}/apache2/conf.d
  131. install -m 0644 ${WORKDIR}/php-fpm-apache.conf ${D}/${sysconfdir}/apache2/conf.d/php-fpm.conf
  132. install -d ${D}${sysconfdir}/init.d
  133. sed -i 's:=/usr/sbin:=${sbindir}:g' ${B}/sapi/fpm/init.d.php-fpm
  134. sed -i 's:=/etc:=${sysconfdir}:g' ${B}/sapi/fpm/init.d.php-fpm
  135. sed -i 's:=/var:=${localstatedir}:g' ${B}/sapi/fpm/init.d.php-fpm
  136. install -m 0755 ${B}/sapi/fpm/init.d.php-fpm ${D}${sysconfdir}/init.d/php-fpm
  137. install -m 0644 ${WORKDIR}/php-fpm-apache.conf ${D}/${sysconfdir}/apache2/conf.d/php-fpm.conf
  138. if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)};then
  139. install -d ${D}${systemd_unitdir}/system
  140. install -m 0644 ${WORKDIR}/php-fpm.service ${D}${systemd_unitdir}/system/
  141. sed -i -e 's,@SYSCONFDIR@,${sysconfdir},g' \
  142. -e 's,@LOCALSTATEDIR@,${localstatedir},g' \
  143. ${D}${systemd_unitdir}/system/php-fpm.service
  144. fi
  145. TMP=`dirname ${D}/${TMPDIR}`
  146. while test ${TMP} != ${D}; do
  147. if [ -d ${TMP} ]; then
  148. rmdir ${TMP}
  149. fi
  150. TMP=`dirname ${TMP}`;
  151. done
  152. if ${@bb.utils.contains('PACKAGECONFIG', 'apache2', 'true', 'false', d)}; then
  153. install -d ${D}${libdir}/apache2/modules
  154. install -d ${D}${sysconfdir}/apache2/modules.d
  155. install -d ${D}${sysconfdir}/php/apache2-php${PHP_MAJOR_VERSION}
  156. install -m 755 libs/libphp${PHP_MAJOR_VERSION}.so ${D}${libdir}/apache2/modules
  157. install -m 644 ${WORKDIR}/70_mod_php${PHP_MAJOR_VERSION}.conf ${D}${sysconfdir}/apache2/modules.d
  158. sed -i s,lib/,${libdir}/, ${D}${sysconfdir}/apache2/modules.d/70_mod_php${PHP_MAJOR_VERSION}.conf
  159. cat ${S}/php.ini-production | \
  160. sed -e 's,extension_dir = \"\./\",extension_dir = \"/usr/lib/extensions\",' \
  161. > ${D}${sysconfdir}/php/apache2-php${PHP_MAJOR_VERSION}/php.ini
  162. rm -f ${D}${sysconfdir}/apache2/httpd.conf*
  163. fi
  164. }
  165. SYSROOT_PREPROCESS_FUNCS += "php_sysroot_preprocess"
  166. php_sysroot_preprocess () {
  167. install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  168. install -m 755 ${D}${bindir}/phpize ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  169. install -m 755 ${D}${bindir}/php-config ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  170. sed -i 's!eval echo /!eval echo ${STAGING_DIR_HOST}/!' ${SYSROOT_DESTDIR}${bindir_crossscripts}/phpize
  171. sed -i 's!^include_dir=.*!include_dir=${STAGING_INCDIR}/php!' ${SYSROOT_DESTDIR}${bindir_crossscripts}/php-config
  172. }
  173. MODPHP_PACKAGE = "${@bb.utils.contains('PACKAGECONFIG', 'apache2', '${PN}-modphp', '', d)}"
  174. PACKAGES = "${PN}-dbg ${PN}-cli ${PN}-cgi ${PN}-fpm ${PN}-fpm-apache2 ${PN}-pear ${PN}-phar ${MODPHP_PACKAGE} ${PN}-dev ${PN}-staticdev ${PN}-doc ${PN}"
  175. RDEPENDS_${PN} += "libgcc"
  176. RDEPENDS_${PN}-pear = "${PN}"
  177. RDEPENDS_${PN}-phar = "${PN}-cli"
  178. RDEPENDS_${PN}-cli = "${PN}"
  179. RDEPENDS_${PN}-modphp = "${PN} apache2"
  180. RDEPENDS_${PN}-dev = "${PN}"
  181. INITSCRIPT_PACKAGES = "${PN}-fpm"
  182. inherit update-rc.d
  183. FILES_${PN}-dbg =+ "${bindir}/.debug \
  184. ${libdir}/apache2/modules/.debug"
  185. FILES_${PN}-doc += "${PHP_LIBDIR}/php/doc"
  186. FILES_${PN}-cli = "${bindir}/php"
  187. FILES_${PN}-phar = "${bindir}/phar*"
  188. FILES_${PN}-cgi = "${bindir}/php-cgi"
  189. FILES_${PN}-fpm = "${sbindir}/php-fpm ${sysconfdir}/php-fpm.conf ${datadir}/fpm ${sysconfdir}/init.d/php-fpm ${systemd_unitdir}/system/php-fpm.service"
  190. FILES_${PN}-fpm-apache2 = "${sysconfdir}/apache2/conf.d/php-fpm.conf"
  191. CONFFILES_${PN}-fpm = "${sysconfdir}/php-fpm.conf"
  192. CONFFILES_${PN}-fpm-apache2 = "${sysconfdir}/apache2/conf.d/php-fpm.conf"
  193. INITSCRIPT_NAME_${PN}-fpm = "php-fpm"
  194. INITSCRIPT_PARAMS_${PN}-fpm = "defaults 60"
  195. FILES_${PN}-pear = "${bindir}/pear* ${bindir}/pecl ${PHP_LIBDIR}/php/PEAR \
  196. ${PHP_LIBDIR}/php/PEAR*.php ${PHP_LIBDIR}/php/System.php \
  197. ${PHP_LIBDIR}/php/peclcmd.php ${PHP_LIBDIR}/php/pearcmd.php \
  198. ${PHP_LIBDIR}/php/.channels ${PHP_LIBDIR}/php/.channels/.alias \
  199. ${PHP_LIBDIR}/php/.registry ${PHP_LIBDIR}/php/Archive/Tar.php \
  200. ${PHP_LIBDIR}/php/Console/Getopt.php ${PHP_LIBDIR}/php/OS/Guess.php \
  201. ${PHP_LIBDIR}/php/data/PEAR \
  202. ${sysconfdir}/pear.conf"
  203. FILES_${PN}-dev = "${includedir}/php ${PHP_LIBDIR}/build ${bindir}/phpize \
  204. ${bindir}/php-config ${PHP_LIBDIR}/php/.depdb \
  205. ${PHP_LIBDIR}/php/.depdblock ${PHP_LIBDIR}/php/.filemap \
  206. ${PHP_LIBDIR}/php/.lock ${PHP_LIBDIR}/php/test"
  207. FILES_${PN} = "${PHP_LIBDIR}/php"
  208. FILES_${PN} += "${bindir}"
  209. SUMMARY_${PN}-modphp = "PHP module for the Apache HTTP server"
  210. FILES_${PN}-modphp = "${libdir}/apache2 ${sysconfdir}"
  211. MODPHP_OLDPACKAGE = "${@bb.utils.contains('PACKAGECONFIG', 'apache2', 'modphp', '', d)}"
  212. RPROVIDES_${PN}-modphp = "${MODPHP_OLDPACKAGE}"
  213. RREPLACES_${PN}-modphp = "${MODPHP_OLDPACKAGE}"
  214. RCONFLICTS_${PN}-modphp = "${MODPHP_OLDPACKAGE}"
  215. do_install_append_class-native() {
  216. create_wrapper ${D}${bindir}/php \
  217. PHP_PEAR_SYSCONF_DIR=${sysconfdir}/
  218. }
  219. # Fails to build with thumb-1 (qemuarm)
  220. # | {standard input}: Assembler messages:
  221. # | {standard input}:3719: Error: selected processor does not support Thumb mode `smull r0,r2,r9,r3'
  222. # | {standard input}:3720: Error: unshifted register required -- `sub r2,r2,r0,asr#31'
  223. # | {standard input}:3796: Error: selected processor does not support Thumb mode `smull r0,r2,r3,r3'
  224. # | {standard input}:3797: Error: unshifted register required -- `sub r2,r2,r0,asr#31'
  225. # | make: *** [ext/standard/math.lo] Error 1
  226. ARM_INSTRUCTION_SET = "arm"